Using GUICtrlCreateMenu as a MenuItem

[Particle]

Is it possible to have something like this:

$MenuItem = GUICtrlCreateMenu("Send to Tray")

be used as if it were a MenuItem without having any menu items under it? So far trying it using GuiGetMsg and a Switch didn't work...

[enaiman]

Guess you are after something like this:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Opt("GUIOnEventMode", 1)
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 151, 97, 192, 124)
GUISetOnEvent($GUI_EVENT_CLOSE, "Form1Close")
GUICtrlCreateMenu("")
$HelpM = GUICtrlCreateMenuItem("Click Me", -1)
GUICtrlSetOnEvent(-1, "ClickMe")
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    Sleep(100)
WEnd

Func Form1Close()
    Exit
EndFunc
Func ClickMe()
    MsgBox(0, "?", "Your wish is my command :D")
EndFunc

Pay attention to GUICtrlCreateMenuItem with the menu ID -1

[Particle]

That's pretty good. I was trying to look for one where I didn't have to use Opt("GUIOnEventMode", 1). There's an empty menubox to the left of it though, is there a way without having that either?

[Authenticity]

#include <WindowsConstants.au3>

GUIRegisterMsg($WM_INITMENUPOPUP, "_WM_INITMENUPOPUP")

Dim $hGUI = GUICreate("Test", 100, 100)
Dim $hMenu1, $hMenu2

$hMenu1 = GUICtrlGetHandle(GUICtrlCreateMenu("Menu1"))
$hMenu2 = GUICtrlGetHandle(GUICtrlCreateMenu("Menu2"))

GUISetState()

Do
Until GUIGetMsg() = -3

GUIDelete()
Exit

Func _WM_INITMENUPOPUP($hwnd, $iMsg, $iwParam, $ilParam)

    Switch $iwParam
        Case $hMenu1
            MsgBox(0x40, "Menu1", "Menu1")
        Case $hMenu2
            MsgBox(0x40, "Menu2", "Menu2")
    EndSwitch

    Return "GUI_RUNDEFMSG"
EndFunc

Edited June 19, 2009 by Authenticity

[Particle]

thanks

[GEOSoft]

You can also place a MenuItem on the main menu bar by not specifying a Menu

$Mnu_Item = GUICtrlCreateMenuItem("My Item","")

[Will66]

You can also place a MenuItem on the main menu bar by not specifying a Menu

$Mnu_Item = GUICtrlCreateMenuItem("My Item","")

doesn't work for me?

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiButton.au3>

Dim $guiTitle="Lets Talk"
Dim $sHTML

$hGUI = GUICreate($guiTitle, 800, 600,-1,-1,$WS_OVERLAPPEDWINDOW)
GUISetOnEvent($GUI_EVENT_CLOSE,"_CLOSEClicked")
GUISetFont (8,-1,"Arial")
Opt("GUIOnEventMode",1)
Opt("GUIResizeMode", 1)

;$btn = _GUICtrlButton_Create($hGUI, "Browse", 10, 10, 50, 20)
;GUICtrlSetOnEvent(-1, "_browsePressed")

;GUICtrlCreateMenu("")
;$HelpM = GUICtrlCreateMenuItem("Click Me", -1)
;GUICtrlSetOnEvent(-1, "_browsePressed")

;GUICtrlCreateMenu("")
;$HelpM2 = GUICtrlCreateMenuItem("Click Me", -1)
;GUICtrlSetOnEvent(-1, "_browsePressed")
$Mnu_Item = GUICtrlCreateMenuItem("My Item","")


GUISetState ()

While 1
    Sleep(100)
WEnd


    Func _CLOSEClicked()
            GUIDelete($hGUI)
            Exit
    EndFunc

[GEOSoft]

I'll have another look at it. I just did it a few days ago so I'll look up that code snippet.

[GEOSoft]

Now I remember. It requires that at lease one primary menu be there so I set a blank

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiButton.au3>

Dim $guiTitle="Lets Talk"
Dim $sHTML

$hGUI = GUICreate($guiTitle, 800, 600,-1,-1,$WS_OVERLAPPEDWINDOW)
GUISetOnEvent($GUI_EVENT_CLOSE,"_CLOSEClicked")
GUISetFont (8,-1,"Arial")
Opt("GUIOnEventMode",1)
Opt("GUIResizeMode", 1)

;$btn = _GUICtrlButton_Create($hGUI, "Browse", 10, 10, 50, 20)
;GUICtrlSetOnEvent(-1, "_browsePressed")

GUICtrlCreateMenu("")
$HelpM = GUICtrlCreateMenuItem("Click Me", -1)
GUICtrlSetOnEvent(-1, "_browsePressed")

GUISetState ()

While 1
    Sleep(100)
WEnd


    Func _CLOSEClicked()
            GUIDelete($hGUI)
            Exit
    EndFunc

Func _browsePressed()
     Msgbox(0, "Result", "Menu Clicked")
EndFunc

It works for me using a message loop instead of that antique OnEvent code that is still around only because people can't shake the habit.

[Will66]

thanx, I can live with that.

One more thing would make it complete is getting the checkbox to display...doable?

$browse=GUICtrlCreateMenu ("")
        GUICtrlCreateMenuitem ("Browse",-1)
       ;GUICtrlSetOnEvent(-1, "TablesMenu_clicked")
        $x=GUICtrlCreateMenuitem ("Browse2",-1)
    GUICtrlSetState(-1, $GUI_CHECKED);check submenu item

[GEOSoft]

thanx, I can live with that.

One more thing would make it complete is getting the checkbox to display...doable?

$browse=GUICtrlCreateMenu ("")
        GUICtrlCreateMenuitem ("Browse",-1)
      ;GUICtrlSetOnEvent(-1, "TablesMenu_clicked")
        $x=GUICtrlCreateMenuitem ("Browse2",-1)
    GUICtrlSetState(-1, $GUI_CHECKED);check submenu item

I don't think that's possible when the menuItem is in the top level but perhaps someone else will have that answer.