name of month udf

[steveR]

I needed this but didn't find anything in a search.

Returns the name of the current month in long or short format.

Please tell me if there are any problems.

expandcollapse popup

;
;===============================================================================
;
; Function name: _MonName()
; Description: Return name of current month in short or long format
; Parameter(s): $format [optional] - 0 = long name (default); 1 = short name
; Return Value(s):  On Success - name of month; On error - sets @ERROR = 1, returns empty string
;
;===============================================================================
Func _MonName($format = 0)
    If Not StringIsInt($format) Or $format < 0 Or $format > 1 Then
        SetError(1)
        Return ""
    EndIf
    Local $monName
    If @MON = 1 Then $monName = "January"
    If @MON = 2 Then $monName = "February"
    If @MON = 3 Then $monName = "March"
    If @MON = 4 Then $monName = "April"
    If @MON = 5 Then $monName = "May"
    If @MON = 6 Then $monName = "June"
    If @MON = 7 Then $monName = "July"
    If @MON = 8 Then $monName = "August"
    If @MON = 9 Then $monName = "September"
    If @MON = 10 Then $monName = "October"
    If @MON = 11 Then $monName = "November"
    If @MON = 12 Then $monName = "December"
    If $format = 0 Then
        Return $monName
    ElseIf $format = 1 Then
        Return StringLeft($monName, 3)
    Else
        SetError(1)
        Return ""
    EndIf
EndFunc  ;==>_MonName
;

EDIT: Ran Tidy

Edited March 6, 2005 by steveR

[Insolence]

Run Tidy on that and you got yourself a nice UDF

[CyberSlug]

An alternative (though I didn't comment it):

Func _MonthName($format = 0)
    If $format = 0 Then
        Local $months = StringSplit("January,February,March,April,May,June,July,August,September,October,November,December", ",")
        Return $months[@MON]
    ElseIf $format = 1 Then
        $abbrev = StringSplit("Jan,Feb,Mar,Apr,June,July,Aug,Sept,Oct,Nov,Dec", ",")
        Return $abbrev[@MON] & "."
    Else
        SetError(1)
        Return ""
    EndIf
EndFunc

EDIT: As pointed out below this code has a bug!

Edited March 11, 2005 by CyberSlug

[zcoacoaz]

i made one once, i did it just like cybersulg

[SlimShady]

CyberSlug's version is 50% smaller.

Nice

Edit:

I tried to make it smaller. Not possible...

Edited March 8, 2005 by SlimShady

[Valik]

CS's short format is bugged, though. I'll let you guys figure out the bug.

[zcoacoaz]

I shall find that bug!

[buckeyexp]

I shall find that bug!

<{POST_SNAPBACK}>

Where is MAY??

[zcoacoaz]

It's "Shall", i cannot ever be wrong.

[steveR]

Doh, I dont know why I didn't use an array. I'll change mine since it's slightly faster.

[steveR]

I've forgotten whole months before, when I used to party.

[zcoacoaz]

your avatar is weird.

[therks]

An alternative (though I didn't comment it):

Func _MonthName($format = 0)
    If $format = 0 Then
        Local $months = StringSplit("January,February,March,April,May,June,July,August,September,October,November,December", ",")
        Return $months[@MON]
    ElseIf $format = 1 Then
        $abbrev = StringSplit("Jan,Feb,Mar,Apr,June,July,Aug,Sept,Oct,Nov,Dec", ",")
        Return $abbrev[@MON] & "."
    Else
        SetError(1)
        Return ""
    EndIf
EndFunc

<{POST_SNAPBACK}>

Wouldn't this be shorter?

Func _MonthName($format = 0)
    Local $months = StringSplit("January,February,March,April,May,June,July,August,September,October,November,December", ",")
    If $format = 0 Then
        Return $months[@MON]
    ElseIf $format = 1 Then
        Return StringLeft($months[@MON], 3)
    Else
        SetError(1)
        Return ""
    EndIf
EndFunc

(Plus, as buckeyexp pointed out, CS forgot to put May in the $abbrev array)

[Valik]

Wouldn't this be shorter?

Func _MonthName($format = 0)
    Local $months = StringSplit("January,February,March,April,May,June,July,August,September,October,November,December", ",")
    If $format = 0 Then
        Return $months[@MON]
    ElseIf $format = 1 Then
        Return StringLeft($months[@MON], 3)
    Else
        SetError(1)
        Return ""
    EndIf
EndFunc

(Plus, as buckeyexp pointed out, CS forgot to put May in the $abbrev array)

<{POST_SNAPBACK}>

Typically short dates spell out the full month name for June and July, so while technically shorter, it is also less conventional.

[CyberSlug]

Typically short dates spell out the full month name for June and July, so while technically shorter, it is also less conventional.

<{POST_SNAPBACK}>

You could have just posted the one-line fix, Valik

Well, it would be longer with a proper If...Else...EndIf block

Func _MonthName($format = 0)
    Local $months = StringSplit("January,February,March,April,May,June,July,August,September,October,November,December", ",")
    If $format = 0 Then
        Return $months[@MON]
    ElseIf $format = 1 Then
        If $months[@MON] <= 4 Then Return $months[@MON]
        Return StringLeft($months[@MON], 3);otherwise
    Else
        SetError(1)
        Return ""
    EndIf
EndFunc

Edit: As pointed out by Valik, this code also has a bug!

Edited March 11, 2005 by CyberSlug

[Valik]

I think you're bugged again, CS. You're going to return January, February, March, and April.

You could have just posted the one-line fix, Valik 

How about I cut the number of lines in half?

Func _MonthName($nLongName = 0)
    Local $sAll = "January,February,March,April,May,June,July,August,September,October,November,December"
    Local $sMonth = StringMid($sAll, StringInStr($sAll, ",", 0, @MON - 1) + 1, StringInStr($sAll, ",", 0, @MON) - StringInStr($sAll, ",", 0, @MON - 1) - 1)
    If $nLongName Or StringLen($sMonth) <= 4 Then Return $sMonth
    Return StringLeft($sMonth, 3)
EndFunc

Edit: Fixed typo, added quote.

Edited March 11, 2005 by Valik

[CyberSlug]

Another good catch. I should give up posting to this thread... but not before I say the following:

Ha ha, function body is only TWO lines--and I tested this time! Watch for word wrap.

Func _MonthName($nLongName = 0)
    If $nLongName Or StringLen(StringMid("January,February,March,April,May,June,July,August,September,October,November,December", StringInStr("January,February,March,April,May,June,July,August,September,October,November,December", ",", 0, @MON - 1) + 1, StringInStr("January,February,March,April,May,June,July,August,September,October,November,December", ",", 0, @MON) - StringInStr("January,February,March,April,May,June,July,August,September,October,November,December", ",", 0, @MON - 1) - 1)) <= 4 Then Return StringMid("January,February,March,April,May,June,July,August,September,October,November,December", StringInStr("January,February,March,April,May,June,July,August,September,October,November,December", ",", 0, @MON - 1) + 1, StringInStr("January,February,March,April,May,June,July,August,September,October,November,December", ",", 0, @MON) - StringInStr("January,February,March,April,May,June,July,August,September,October,November,December", ",", 0, @MON - 1) - 1)
    Return StringLeft(StringMid("January,February,March,April,May,June,July,August,September,October,November,December", StringInStr("January,February,March,April,May,June,July,August,September,October,November,December", ",", 0, @MON - 1) + 1, StringInStr("January,February,March,April,May,June,July,August,September,October,November,December", ",", 0, @MON) - StringInStr("January,February,March,April,May,June,July,August,September,October,November,December", ",", 0, @MON - 1) - 1), 3)
EndFunc

[therks]

Typically short dates spell out the full month name for June and July, so while technically shorter, it is also less conventional.

<{POST_SNAPBACK}>

I see. I did not know that.

*Edit: Question. Valik, why did you use that method with StringMid and StringInStr instead of just using an array?

Based from your example, wouldn't this be more efficient?

Func _MonthName2($nLongName = 0)
    Local $aMonths = StringSplit("January,February,March,April,May,June,July,August,September,October,November,December", ",")
    If $nLongName Or StringLen($aMonths[@MON]) <= 4 Then Return $aMonths[@MON]
    Return StringLeft($aMonths[@MON], 3)
EndFunc

I'm not going to touch CS's code with a ten foot pole.

Edited March 11, 2005 by Saunders

[CyberSlug]

I'm not going to touch CS's code with a ten foot pole.

<{POST_SNAPBACK}>

It's just Valik's code with the $sAll and $sMonth variables replaced with the literal strings.

[Valik]

Saunders, I wasn't going for efficiency, I was simply demonstrating a different way of doing it and also cutting the length of the code down significantly. I'm also not a fan of the StringSplit trick. Run-time processing of something known at compile time seems a bit silly to me.