How get file extension?

[ZeR0]

Hi, i need help here...

I coding something and i need get the extension of file, i check the help file, but i not have results... who can help me???

[Tomb]

_PathSplit()

[Andreik]

#include <File.au3>

$PATH = FileOpenDialog("PATH",@ScriptDir,"All (*.*)")
If Not @error Then
    Dim $szDrive, $szDir, $szFName, $szExt
    $PATH = _PathSplit($PATH,$szDrive,$szDir,$szFName,$szExt)
    MsgBox(0,"",$PATH[4])
EndIf

[FireFox]

quicker solution

$extension = StringReplace(StringRight($path,4),".","")

Cheers,FireFox.

Edited December 30, 2008 by FireFox

[Andreik]

quicker solution

$extension = StringReplace(StringRight($path,4),".","")

Cheers,FireFox.

I don't know what to say about this. Exists file extenstions with more then 4 chars.

[Pain]

That will different result for .exe, .jpeg and .xhtml etc.

[FireFox]

@Andreik

If you insist

$split = StringSplit($path, "\")
$name = StringSplit($path[$path[0]], ".")
$ext = $name[2]

Cheers, FireFox.

Edited December 30, 2008 by FireFox

[system24]

You could immediately split the path using "." as delimiter.

$split = StringSplit($path, ".")
$ext = $split[$split[0]]

[rasim]

$sFile = "c:\Program Files\AutoIt3\AutoIt3.chm"

$sExt = StringRegExpReplace($sFile, "^.*\.", "")

MsgBox(0, "Extension", $sExt)

[BrettF]

$filed = FileOpenDialog ("", "", "All (*.*)")

MsgBox (0, "", GetFileExt($filed))

Func GetFileExt($file)
    Return StringRight($file, StringLen($file) - StringInStr($file, ".", 0, -1))
EndFunc  ;==>GetFileExt

[FireFox]

Anyone esle for the competition ?

Cheers, FireFox.

[Harlequin]

Anyone esle for the competition ?

Cheers, FireFox.

$CurrentFile = "C:\Directory\Directory2\FileNameHere.AnyExtensionLength"

For $YLoop = StringLen ($CurrentFile) to 1 Step -1
    If StringMid ($CurrentFile, $YLoop, 1) == "." Then
         $fl_Ext = StringMid ($CurrentFile, $YLoop)
         $YLoop = 1
    EndIf
Next

Result: $fl_Ext = ".AnyExtensionLength"

The problem with other suggestions:

1) "."s in Directory Name: "C:\Direct.ory\Ham\Cheese\FileName.ext"

2) Multiple "."s in filename: "This.is.my.file.name.bmp"

Edited December 31, 2008 by Harlequin