When Computer get IDLE

[autoitxp]

Hi

How to do some task when computer goes to idle state like call function when system goes idle how to achive this Kinda stuff

Help !

[Richard Robertson]

That depends on your concept of idle. Do you perhaps mean "so long since user input" or "almost 0% processor usage" or what?

[autoitxp]

"so long since user input"

Ya how to detect that when user inputs at Idle state

[MrCreatoR]

Try this:

expandcollapse popup

#include <Date.au3>

HotKeySet("{ESC}", "_Quit")

$IdleMinimum = 50

While 1
    $iIdle = _IdleWaitStart($IdleMinimum)
    ConsoleWrite(_Now() & ' ' & @UserName & ' not active ' & _TickToTimeString($iIdle) & @CRLF)
    $iIdle = _IdleWaitCommit($IdleMinimum)
    ConsoleWrite(_Now() & ' ' & @UserName & ' was inactive ' & _TickToTimeString($iIdle) & @CRLF)
WEnd

Func _IdleWaitStart($idlesec)
    Local $aRet, $iSave, $iTick, $LastInputInfo = DllStructCreate("uint;dword")
    DllStructSetData($LastInputInfo, 1, DllStructGetSize($LastInputInfo))
    DllCall("user32.dll", "int", "GetLastInputInfo", "ptr", DllStructGetPtr($LastInputInfo))
    
    Do
        Sleep(200)
        $iSave = DllStructGetData($LastInputInfo, 2)
        DllCall("user32.dll", "int", "GetLastInputInfo", "ptr", DllStructGetPtr($LastInputInfo))
        $aRet = DllCall("kernel32.dll", "long", "GetTickCount")
    Until ($aRet[0] - DllStructGetData($LastInputInfo, 2)) > $idlesec

    Return $aRet[0] - DllStructGetData($LastInputInfo, 2)
EndFunc   ;==>_IdleWaitStart

Func _IdleWaitCommit($idlesec)
    Local $iSave, $LastInputInfo = DllStructCreate("uint;dword")
    DllStructSetData($LastInputInfo, 1, DllStructGetSize($LastInputInfo))
    DllCall("user32.dll", "int", "GetLastInputInfo", "ptr", DllStructGetPtr($LastInputInfo))
    
    Do
        $iSave = DllStructGetData($LastInputInfo, 2)
        Sleep(200)
        DllCall("user32.dll", "int", "GetLastInputInfo", "ptr", DllStructGetPtr($LastInputInfo))
    Until (DllStructGetData($LastInputInfo, 2) - $iSave) > $idlesec
    
    Return DllStructGetData($LastInputInfo, 2) - $iSave
EndFunc   ;==>_IdleWaitCommit

Func _TickToTimeString($iTicks)
    Local $iHours, $iMins, $iSecs, $sText = ''
    _TicksToTime($iTicks, $iHours, $iMins, $iSecs)
    
    If $iHours Then $sText = $iHours & ' hours '
    If $iMins Then $sText &= $iMins & ' minutes '
    If $iSecs Then $sText &= $iSecs & ' seconds'
    If $sText = '' Then $sText = 'less than a second'
    
    Return $sText
EndFunc   ;==>_TickToTimeString

Func _Quit()
    Exit
EndFunc   ;==>_Quit

[autoitxp]

Nice!

[cwem]

I'm trying to retrieve stock information based on clients' portfolio (a text file with rows of numbers). However, I find that if I don't click the IE that's used for information retrieval sometimes, autoit won't proceed and will only do for, say, every 6-7 records. Is the "idle" solution provided here can solve my problem? Thanks.

[PsaltyDS]

Try this:

CODE

#include <Date.au3>

HotKeySet("{ESC}", "_Quit")

$IdleMinimum = 50

While 1

$iIdle = _IdleWaitStart($IdleMinimum)

ConsoleWrite(_Now() & ' ' & @UserName & ' not active ' & _TickToTimeString($iIdle) & @CRLF)

$iIdle = _IdleWaitCommit($IdleMinimum)

ConsoleWrite(_Now() & ' ' & @UserName & ' was inactive ' & _TickToTimeString($iIdle) & @CRLF)

WEnd

Func _IdleWaitStart($idlesec)

Local $aRet, $iSave, $iTick, $LastInputInfo = DllStructCreate("uint;dword")

DllStructSetData($LastInputInfo, 1, DllStructGetSize($LastInputInfo))

DllCall("user32.dll", "int", "GetLastInputInfo", "ptr", DllStructGetPtr($LastInputInfo))

Do

Sleep(200)

$iSave = DllStructGetData($LastInputInfo, 2)

DllCall("user32.dll", "int", "GetLastInputInfo", "ptr", DllStructGetPtr($LastInputInfo))

$aRet = DllCall("kernel32.dll", "long", "GetTickCount")

Until ($aRet[0] - DllStructGetData($LastInputInfo, 2)) > $idlesec

Return $aRet[0] - DllStructGetData($LastInputInfo, 2)

EndFunc ;==>_IdleWaitStart

Func _IdleWaitCommit($idlesec)

Local $iSave, $LastInputInfo = DllStructCreate("uint;dword")

DllStructSetData($LastInputInfo, 1, DllStructGetSize($LastInputInfo))

DllCall("user32.dll", "int", "GetLastInputInfo", "ptr", DllStructGetPtr($LastInputInfo))

Do

$iSave = DllStructGetData($LastInputInfo, 2)

Sleep(200)

DllCall("user32.dll", "int", "GetLastInputInfo", "ptr", DllStructGetPtr($LastInputInfo))

Until (DllStructGetData($LastInputInfo, 2) - $iSave) > $idlesec

Return DllStructGetData($LastInputInfo, 2) - $iSave

EndFunc ;==>_IdleWaitCommit

Func _TickToTimeString($iTicks)

Local $iHours, $iMins, $iSecs, $sText = ''

_TicksToTime($iTicks, $iHours, $iMins, $iSecs)

If $iHours Then $sText = $iHours & ' hours '

If $iMins Then $sText &= $iMins & ' minutes '

If $iSecs Then $sText &= $iSecs & ' seconds'

If $sText = '' Then $sText = 'less than a second'

Return $sText

EndFunc ;==>_TickToTimeString

Func _Quit()

Exit

EndFunc ;==>_Quit

There is already a stock UDF function _Timer_GetIdleTime() in Timers.au3. So that could just be:

#include <Timers.au3>

HotKeySet("{ESC}", "_Quit")

$IdleMinimum = 15000; Idle time in milliseconds

While 1
    If _Timer_GetIdleTime() >= $IdleMinimum Then
        ConsoleWrite("User inputs idle longer than " & $IdleMinimum & "ms = GO!" & @LF)
        Do 
            Sleep(20)
        Until _Timer_GetIdleTime() < $IdleMinimum
    EndIf
    Sleep(20)
WEnd

Func _Quit()
    Exit
EndFunc  ;==>_Quit

I'm trying to retrieve stock information based on clients' portfolio (a text file with rows of numbers). However, I find that if I don't click the IE that's used for information retrieval sometimes, autoit won't proceed and will only do for, say, every 6-7 records. Is the "idle" solution provided here can solve my problem? Thanks.

Nowhere near enough information to answer. AutoIt doesn't "proceed" based on if you clicked IE or not, unless you coded it to do so. So you will have to say much more about what the script is doing or post the code. This is not really on topic here, so go ahead and start a new topic with more information for your issue.

Edited April 9, 2009 by PsaltyDS