Delete column from 2d array

[blenkhn]

I have searched and searched and there doesn't seem to be a method for deleting a column from a 2 dimensional array,

Is this possible? Please help.

[rasim]

I have searched and searched and there doesn't seem to be a method for deleting a column from a 2 dimensional array,

Is this possible? Please help.

Can you make a small example to duplicate your problem?

[PsaltyDS]

I have searched and searched and there doesn't seem to be a method for deleting a column from a 2 dimensional array,

Is this possible? Please help.

Sounded useful, so I gave it a shot:

#include <Array.au3>

Global $avArray[4][4]

For $r = 0 To UBound($avArray) - 1
    For $c = 0 To UBound($avArray, 2) - 1
        $avArray[$r][$c] = $r & " - " & $c
    Next
Next

_ArrayDisplay($avArray, "Before")
_ArrayDeleteCol($avArray, UBound($avArray, 2) - 2)
_ArrayDisplay($avArray, "After")


Func _ArrayDeleteCol(ByRef $avWork, $iCol)
    If Not IsArray($avWork) Then Return SetError(1, 0, 0); Not an array
    If UBound($avWork, 0) <> 2 Then Return SetError(1, 1, 0); Not a 2D array
    If ($iCol < 0) Or ($iCol > (UBound($avWork, 2) - 1)) Then Return SetError(1, 2, 0); $iCol out of range
    If $iCol < UBound($avWork, 2) - 1 Then 
        For $c = $iCol To UBound($avWork, 2) - 2 
            For $r = 0 To UBound($avWork) - 1
                $avWork[$r][$c] = $avWork[$r][$c + 1]
            Next
        Next
    EndIf
    ReDim $avWork[UBound($avWork)][UBound($avWork, 2) - 1]
    Return 1
EndFunc

I'll bet if you search the forum, something like this has been posted before...

Edit: Fixed bug per Malkey below.

Edited April 1, 2011 by PsaltyDS

[blenkhn]

I'll bet if you search the forum, something like this has been posted before...

I did search and all I found was people asking if it could be done. I like your solution very simple and concise

[KatoXY]

What I can do if I have to delete first column in my array?

I use _ExcelReadSheetToArray function which create array where column 0 and row 0 are empty.

I can delete row 0 _ArrayDelete, but ReDim delete only last column and I want delete the first one.

[BrewManNH]

PsaltyDS that's a nice bit to add to my array.au3 file along with an add column function that got worked out a little while back that I have referenced in my signature. Which unfortunately isn't my work, but now there's a way to do both operations.

[Malkey]

PsaltyDS

It's never too late to fix a mistake, if you change this

;ReDim $avWork[UBound($avWork)][UBound($avWork) - 1]
ReDim $avWork[UBound($avWork)][UBound($avWork, 2) - 1] ; <--- Change to this.

in a couple of years - no rush.

[PsaltyDS]

PsaltyDS

It's never too late to fix a mistake, if you change this

;ReDim $avWork[UBound($avWork)][UBound($avWork) - 1]
ReDim $avWork[UBound($avWork)][UBound($avWork, 2) - 1] ; <--- Change to this.

in a couple of years - no rush.

You're correct. The original demo only worked be cause the number of rows/cols happened to match in the example.

[KatoXY]

You discuss

but I still do not see any answer for my question

Is it possible to delete first column in array?

[BrewManNH]

Take Psalty's function, change the _ArrayDeleteCol($avArray, UBound($avArray, 2) - 2) line accordingly (here's a hint the second parameter is the column number to delete, and the columns start at zero), and use it in your script.

[PsaltyDS]

The demo was a little too cute with the parameters. Deleting the first column would just be _ArrayDeleteCol($avArray, 0).

[gcue]

thank you this was very useful

[guinness]

gcue,

You should know by now that necroing posts is a big no no here.

[water]

Wow, that was quick gcue. Just a bit more than 2 years after the last post