BASS Function Library (Sound and Music Functions)

[eukalyptus]

Change line 28 to this: Global $hBrush = _GDIPlus_BrushCreateSolid(0xFF00FF00)

and line 48 to this: _GDIPlus_GraphicsClear($hGfx_Buffer, 0xFFFF0000)

what do you get now?

[wakillon]

I have updated the bass udf in the BetaIncludes dir ( instead of release includes dir ) and it works fine now ! 

Thanks.

[timmy2]

 

using latest Bass-UDF and lastest AutoIt Beta (v3.3.9.22):

expandcollapse popup

#AutoIt3Wrapper_Autoit3Dir=c:\Program Files (x86)\AutoIt3\Beta
#AutoIt3Wrapper_UseX64=n

#include "Bass.au3"
#include "BassExt.au3"
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Opt("MustDeclareVars", 1)
Opt("GUIOnEventMode", 1)

Global $sFile = FileOpenDialog("Open...", "..\audiofiles", "playable formats (*.MP3;*.MP2;*.MP1;*.OGG;*.WAV;*.AIFF;*.AIF)")
If @error Or Not FileExists($sFile) Then Exit


Global $iWidth = 522
Global $iHeight = 170

Global $hGui = GUICreate("FFT", $iWidth, $iHeight, -1, -1, BitOR($WS_SYSMENU, $WS_POPUP))
GUISetOnEvent($GUI_EVENT_CLOSE, "_EXIT")
_GDIPlus_Startup()
Global $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGui)
Global $hBmp_Buffer = _GDIPlus_BitmapCreateFromScan0($iWidth, $iHeight)
Global $hGfx_Buffer = _GDIPlus_ImageGetGraphicsContext($hBmp_Buffer)
_GDIPlus_GraphicsSetSmoothingMode($hGfx_Buffer, 2)

Global $hBrush = _CreateFFTBrush(5, 5, $iWidth - 10, $iHeight - 10)

GUIRegisterMsg($WM_PAINT, "WM_PAINT")
GUISetState()

_BASS_Startup()
_BASS_EXT_Startup()
_BASS_Init(0, -1, 44100, 0, "")

Global $hStream = _BASS_StreamCreateFile(False, $sFile, 0, 0, $BASS_SAMPLE_FLOAT)
Global $aFFT = _BASS_EXT_CreateFFT(128, 5, 5, $iWidth - 10, $iHeight - 10, 1, True)

_BASS_ChannelPlay($hStream, True)



Global $iTimer = TimerInit()
While _BASS_ChannelIsActive($hStream)
    If TimerDiff($iTimer) > 20 Then
        $iTimer = TimerInit()
        _GDIPlus_GraphicsClear($hGfx_Buffer, 0xFF110022)

        _BASS_EXT_ChannelGetFFT($hStream, $aFFT, 2)
        If Not @error Then DllCall($ghGDIPDll, "int", "GdipFillPolygon", "handle", $hGfx_Buffer, "handle", $hBrush, "ptr", $aFFT[0], "int", $aFFT[1], "int", "FillModeAlternate")

        _GDIPlus_GraphicsDrawImage($hGraphics, $hBmp_Buffer, 0, 0)
    EndIf
WEnd
_Exit()



Func _CreateFFTBrush($iX, $iY, $iWidth, $iHeight)
    Local $hBitmap = _GDIPlus_BitmapCreateFromScan0($iWidth, $iHeight)
    Local $hContext = _GDIPlus_ImageGetGraphicsContext($hBitmap)

    Local $hBrush_FFT = _GDIPlus_LineBrushCreate(0, 0, 0, $iHeight, 0, 0, 3)
    Local $aColors[5][2] = [[4]]
    $aColors[1][0] = 0xFFFF0000
    $aColors[1][1] = 0
    $aColors[2][0] = 0xFFFFAA00
    $aColors[2][1] = 0.25
    $aColors[3][0] = 0xFF00AAFF
    $aColors[3][1] = 0.5
    $aColors[4][0] = 0xFF00AAFF
    $aColors[4][1] = 1
    _GDIPlus_LineBrushSetPresetBlend($hBrush_FFT, $aColors)

    Local $hBrush_LED = _GDIPlus_LineBrushCreate(0, 0, 0, 4, 0xAA000000, 0x00000000, 0)

    _GDIPlus_GraphicsFillRect($hContext, 0, 0, $iWidth, $iHeight, $hBrush_FFT)
    _GDIPlus_GraphicsFillRect($hContext, 0, 0, $iWidth, $iHeight, $hBrush_LED)
    _GDIPlus_BrushDispose($hBrush_LED)
    _GDIPlus_BrushDispose($hBrush_FFT)
    _GDIPlus_GraphicsDispose($hContext)

    Local $hBrush = _GDIPlus_TextureCreate($hBitmap)
    _GDIPlus_BitmapDispose($hBitmap)

    DllCall($ghGDIPDll, "uint", "GdipTranslateTextureTransform", "hwnd", $hBrush, "float", $iX, "float", $iY, "int", 0)

    Return $hBrush
EndFunc   ;==>_CreateFFTBrush



Func WM_PAINT($hWnd, $uMsgm, $wParam, $lParam)
    _GDIPlus_GraphicsDrawImage($hGraphics, $hBmp_Buffer, 0, 0)
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_PAINT


Func _Exit()
    _BASS_StreamFree($hStream)
    _BASS_Free()

    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGfx_Buffer)
    _GDIPlus_BitmapDispose($hBmp_Buffer)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_Shutdown()
    Exit
EndFunc   ;==>_Exit

 

Thank you, eucalyptus. Many differences from >UEZ's script of November 6th.  Are these differences the result of coding using Autoit Beta v3.3.9.22 instead of release 3.3.8.1? If not, would you mind posting your version that is compatible with 3.3.8.1?

[eukalyptus]

to be compatible with 3.3.8.1, add these functions to the script:

expandcollapse popup

; #FUNCTION# ====================================================================================================================
; Author ........: Authenticity
; Modified.......: UEZ
; ===============================================================================================================================
Func _GDIPlus_BitmapCreateFromScan0($iWidth, $iHeight, $iPixelFormat = $GDIP_PXF32ARGB, $iStride = 0, $pScan0 = 0)
    Local $aResult = DllCall($ghGDIPDll, "uint", "GdipCreateBitmapFromScan0", "int", $iWidth, "int", $iHeight, "int", $iStride, "int", $iPixelFormat, "ptr", $pScan0, "handle*", 0)
    If @error Then Return SetError(@error, @extended, 0)
    If $aResult[0] Then Return SetError(10, $aResult[0], 0)

    Return $aResult[6]
EndFunc   ;==>_GDIPlus_BitmapCreateFromScan0


; #FUNCTION# ====================================================================================================================
; Author ........: Authenticity
; Modified.......: UEZ
; ===============================================================================================================================
Func _GDIPlus_LineBrushCreate($nX1, $nY1, $nX2, $nY2, $iARGBClr1, $iARGBClr2, $iWrapMode = 0)
    Local $tPointF1, $tPointF2, $aResult
    $tPointF1 = DllStructCreate("float;float")
    $tPointF2 = DllStructCreate("float;float")
    DllStructSetData($tPointF1, 1, $nX1)
    DllStructSetData($tPointF1, 2, $nY1)
    DllStructSetData($tPointF2, 1, $nX2)
    DllStructSetData($tPointF2, 2, $nY2)
    $aResult = DllCall($ghGDIPDll, "int", "GdipCreateLineBrush", "struct*", $tPointF1, "struct*", $tPointF2, "uint", $iARGBClr1, "uint", $iARGBClr2, "int", $iWrapMode, "handle*", 0)
    If @error Then Return SetError(@error, @extended, 0)
    If $aResult[0] Then Return SetError(10, $aResult[0], 0)

    Return $aResult[6]
EndFunc   ;==>_GDIPlus_LineBrushCreate


; #FUNCTION# ====================================================================================================================
; Author ........: Authenticity
; Modified.......: UEZ
; ===============================================================================================================================
Func _GDIPlus_LineBrushSetPresetBlend($hLineGradientBrush, $aInterpolations)
    Local $iI, $iCount, $tColors, $tPositions, $aResult
    $iCount = $aInterpolations[0][0]
    $tColors = DllStructCreate("uint[" & $iCount & "]")
    $tPositions = DllStructCreate("float[" & $iCount & "]")
    For $iI = 1 To $iCount
        DllStructSetData($tColors, 1, $aInterpolations[$iI][0], $iI)
        DllStructSetData($tPositions, 1, $aInterpolations[$iI][1], $iI)
    Next
    $aResult = DllCall($ghGDIPDll, "int", "GdipSetLinePresetBlend", "handle", $hLineGradientBrush, "struct*", $tColors, "struct*", $tPositions, "int", $iCount)
    If @error Then Return SetError(@error, @extended, False)
    If $aResult[0] Then Return SetError(10, $aResult[0], False)

    Return True
EndFunc   ;==>_GDIPlus_LineBrushSetPresetBlend


; #FUNCTION# ====================================================================================================================
; Author ........: Authenticity
; Modified.......: UEZ
; ===============================================================================================================================
Func _GDIPlus_TextureCreate($hImage, $iWrapMode = 0)
    Local $aResult = DllCall($ghGDIPDll, "int", "GdipCreateTexture", "handle", $hImage, "int", $iWrapMode, "handle*", 0)
    If @error Then Return SetError(@error, @extended, 0)
    If $aResult[0] Then Return SetError(10, $aResult[0], 0)

    Return $aResult[3]
EndFunc   ;==>_GDIPlus_TextureCreate

[timmy2]

Thank you, eucalyptus.  I added the functions and it compiles without errors. But when I run it I get a blank bluish-black rectangle. When I run it from SciTE I get the following error, which must be erroneous because I have only the 32-bit AutoIt installed.

 

>"C:\Program Files (x86)\AutoIt3\SciTE\AutoIt3Wrapper\AutoIt3Wrapper.exe" /run /prod /ErrorStdOut /in "D:Documents!Current ProjectssjecoattrainingSound visualizerEuk-approved FFT.au3" /UserParams   
+>21:19:30 Starting AutoIt3Wrapper v.2.1.2.9    Environment(Language:0409  Keyboard:00000409  OS:WIN_8/  CPU:X64 OS:X64)
>Running AU3Check (1.54.22.0)  from:C:Program Files (x86)AutoIt3
+>21:19:30 AU3Check ended.rc:0
>Running:(3.3.8.1):C:Program Files (x86)AutoIt3autoit3.exe "D:Documents!Current ProjectssjecoattrainingSound visualizerEuk-approved FFT.au3"   
--> Press Ctrl+Alt+F5 to Restart or Ctrl+Break to Stop

!Bass.dll is for 32bit only!
Run/compile Script at 32bit
+>21:19:33 AutoIt3.exe ended.rc:0
>Exit code: 0    Time: 3.742

 

I may not have Bass UDF v10.  Most of the files in my Bass UDF folder are dated Dec. 2011. When I click on your "Bass UDF v10 download" link the browser eventually says it can't load the page. "http://www.autoit.de/" is also dead, at least from here in the USA.

EDIT: Thank you, Wakillon.  The link you provided got me v10, and now the script changes provided by Eukalyptus works great!

Edited November 11, 2013 by timmy2

[wakillon]

autoit.de seems to be temporarily unreachable.

Try Bass UDF v10

[timmy2]

For the sake of closure here's Eukalyptus' FTT Visualizer script that's compatible with AutoIt v3.3.8.1. 

Anyone willing to tell me how to modify it so it'll display audio played by another AutoIt script using SoundPlay? In other words, I need it to display the FFT of audio being played by another script.

The reason? I want to change the audio level at specific times in my main script and SoundSetWaveVolume only changes the volume for the script that's playing the audio file. It's either that or I'll need to use IPC to send volume changes to this script, and that's way beyond my skill level.

expandcollapse popup

#AutoIt3Wrapper_UseX64=n

#include "Bass.au3"
#include "BassExt.au3"
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Opt("MustDeclareVars", 1)
Opt("GUIOnEventMode", 1)

Global $sFile = FileOpenDialog("Open...", "..\audiofiles", "playable formats (*.MP3;*.MP2;*.MP1;*.OGG;*.WAV;*.AIFF;*.AIF)")
If @error Or Not FileExists($sFile) Then Exit


Global $iWidth = 522
Global $iHeight = 170

Global $hGui = GUICreate("FFT", $iWidth, $iHeight, -1, -1, BitOR($WS_SYSMENU, $WS_POPUP))
GUISetOnEvent($GUI_EVENT_CLOSE, "_EXIT")
_GDIPlus_Startup()
Global $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGui)
Global $hBmp_Buffer = _GDIPlus_BitmapCreateFromScan0($iWidth, $iHeight)
Global $hGfx_Buffer = _GDIPlus_ImageGetGraphicsContext($hBmp_Buffer)
_GDIPlus_GraphicsSetSmoothingMode($hGfx_Buffer, 2)

Global $hBrush = _CreateFFTBrush(5, 5, $iWidth - 10, $iHeight - 10)

GUIRegisterMsg($WM_PAINT, "WM_PAINT")
GUISetState()

_BASS_Startup()
_BASS_EXT_Startup()
_BASS_Init(0, -1, 44100, 0, "")

Global $hStream = _BASS_StreamCreateFile(False, $sFile, 0, 0, $BASS_SAMPLE_FLOAT)
Global $aFFT = _BASS_EXT_CreateFFT(128, 5, 5, $iWidth - 10, $iHeight - 10, 1, True)

_BASS_ChannelPlay($hStream, True)



Global $iTimer = TimerInit()
While _BASS_ChannelIsActive($hStream)
    If TimerDiff($iTimer) > 20 Then
        $iTimer = TimerInit()
        _GDIPlus_GraphicsClear($hGfx_Buffer, 0xFF110022)

        _BASS_EXT_ChannelGetFFT($hStream, $aFFT, 2)
        If Not @error Then DllCall($ghGDIPDll, "int", "GdipFillPolygon", "handle", $hGfx_Buffer, "handle", $hBrush, "ptr", $aFFT[0], "int", $aFFT[1], "int", "FillModeAlternate")

        _GDIPlus_GraphicsDrawImage($hGraphics, $hBmp_Buffer, 0, 0)
    EndIf
WEnd
_Exit()



Func _CreateFFTBrush($iX, $iY, $iWidth, $iHeight)
    Local $hBitmap = _GDIPlus_BitmapCreateFromScan0($iWidth, $iHeight)
    Local $hContext = _GDIPlus_ImageGetGraphicsContext($hBitmap)

    Local $hBrush_FFT = _GDIPlus_LineBrushCreate(0, 0, 0, $iHeight, 0, 0, 3)
    Local $aColors[5][2] = [[4]]
    $aColors[1][0] = 0xFFFF0000
    $aColors[1][1] = 0
    $aColors[2][0] = 0xFFFFAA00
    $aColors[2][1] = 0.25
    $aColors[3][0] = 0xFF00AAFF
    $aColors[3][1] = 0.5
    $aColors[4][0] = 0xFF00AAFF
    $aColors[4][1] = 1
    _GDIPlus_LineBrushSetPresetBlend($hBrush_FFT, $aColors)

    Local $hBrush_LED = _GDIPlus_LineBrushCreate(0, 0, 0, 4, 0xAA000000, 0x00000000, 0)

    _GDIPlus_GraphicsFillRect($hContext, 0, 0, $iWidth, $iHeight, $hBrush_FFT)
    _GDIPlus_GraphicsFillRect($hContext, 0, 0, $iWidth, $iHeight, $hBrush_LED)
    _GDIPlus_BrushDispose($hBrush_LED)
    _GDIPlus_BrushDispose($hBrush_FFT)
    _GDIPlus_GraphicsDispose($hContext)

    Local $hBrush = _GDIPlus_TextureCreate($hBitmap)
    _GDIPlus_BitmapDispose($hBitmap)

    DllCall($ghGDIPDll, "uint", "GdipTranslateTextureTransform", "hwnd", $hBrush, "float", $iX, "float", $iY, "int", 0)

    Return $hBrush
EndFunc   ;==>_CreateFFTBrush



Func WM_PAINT($hWnd, $uMsgm, $wParam, $lParam)
    _GDIPlus_GraphicsDrawImage($hGraphics, $hBmp_Buffer, 0, 0)
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_PAINT

; #FUNCTION# ====================================================================================================================
; Author ........: Authenticity
; Modified.......: UEZ
; ===============================================================================================================================
Func _GDIPlus_BitmapCreateFromScan0($iWidth, $iHeight, $iPixelFormat = $GDIP_PXF32ARGB, $iStride = 0, $pScan0 = 0)
    Local $aResult = DllCall($ghGDIPDll, "uint", "GdipCreateBitmapFromScan0", "int", $iWidth, "int", $iHeight, "int", $iStride, "int", $iPixelFormat, "ptr", $pScan0, "handle*", 0)
    If @error Then Return SetError(@error, @extended, 0)
    If $aResult[0] Then Return SetError(10, $aResult[0], 0)

    Return $aResult[6]
EndFunc   ;==>_GDIPlus_BitmapCreateFromScan0


; #FUNCTION# ====================================================================================================================
; Author ........: Authenticity
; Modified.......: UEZ
; ===============================================================================================================================
Func _GDIPlus_LineBrushCreate($nX1, $nY1, $nX2, $nY2, $iARGBClr1, $iARGBClr2, $iWrapMode = 0)
    Local $tPointF1, $tPointF2, $aResult
    $tPointF1 = DllStructCreate("float;float")
    $tPointF2 = DllStructCreate("float;float")
    DllStructSetData($tPointF1, 1, $nX1)
    DllStructSetData($tPointF1, 2, $nY1)
    DllStructSetData($tPointF2, 1, $nX2)
    DllStructSetData($tPointF2, 2, $nY2)
    $aResult = DllCall($ghGDIPDll, "int", "GdipCreateLineBrush", "struct*", $tPointF1, "struct*", $tPointF2, "uint", $iARGBClr1, "uint", $iARGBClr2, "int", $iWrapMode, "handle*", 0)
    If @error Then Return SetError(@error, @extended, 0)
    If $aResult[0] Then Return SetError(10, $aResult[0], 0)

    Return $aResult[6]
EndFunc   ;==>_GDIPlus_LineBrushCreate


; #FUNCTION# ====================================================================================================================
; Author ........: Authenticity
; Modified.......: UEZ
; ===============================================================================================================================
Func _GDIPlus_LineBrushSetPresetBlend($hLineGradientBrush, $aInterpolations)
    Local $iI, $iCount, $tColors, $tPositions, $aResult
    $iCount = $aInterpolations[0][0]
    $tColors = DllStructCreate("uint[" & $iCount & "]")
    $tPositions = DllStructCreate("float[" & $iCount & "]")
    For $iI = 1 To $iCount
        DllStructSetData($tColors, 1, $aInterpolations[$iI][0], $iI)
        DllStructSetData($tPositions, 1, $aInterpolations[$iI][1], $iI)
    Next
    $aResult = DllCall($ghGDIPDll, "int", "GdipSetLinePresetBlend", "handle", $hLineGradientBrush, "struct*", $tColors, "struct*", $tPositions, "int", $iCount)
    If @error Then Return SetError(@error, @extended, False)
    If $aResult[0] Then Return SetError(10, $aResult[0], False)

    Return True
EndFunc   ;==>_GDIPlus_LineBrushSetPresetBlend


; #FUNCTION# ====================================================================================================================
; Author ........: Authenticity
; Modified.......: UEZ
; ===============================================================================================================================
Func _GDIPlus_TextureCreate($hImage, $iWrapMode = 0)
    Local $aResult = DllCall($ghGDIPDll, "int", "GdipCreateTexture", "handle", $hImage, "int", $iWrapMode, "handle*", 0)
    If @error Then Return SetError(@error, @extended, 0)
    If $aResult[0] Then Return SetError(10, $aResult[0], 0)

    Return $aResult[3]
EndFunc   ;==>_GDIPlus_TextureCreate



Func _Exit()
    _BASS_StreamFree($hStream)
    _BASS_Free()

    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGfx_Buffer)
    _GDIPlus_BitmapDispose($hBmp_Buffer)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_Shutdown()
    Exit
EndFunc   ;==>_Exit

[Belini]

If I understand right you want a script to communicate with another, if it can use the UDF InterProcess.au3

[nend]

Is it possible to make a equalizer with bass?

I've got a streaming radio program and I got a lot of request of a equalizer.

I'm looking already for many hours on the internet to find a good sample/sourcode but the nearest thing I kan find is the "Split-Lo_Mid_Hi-Mixer.au3" example.

So my question is, is it possible and how?

[MarcroSoft]

Hi.

I am using bass in a talking clock I make, and I just wanted to know if there is a newer version of the udf than the version 10 from the german website?

Marc

[wakillon]

Hi.

I am using bass in a talking clock I make, and I just wanted to know if there is a newer version of the udf than the version 10 from the german website?

Marc

 

No, the last version is the BASS UDF v10 from eukalyptus.

[MarcroSoft]

Thanks.

However I always try to keep bass.dll updated if it doesn't break my script.

Marc

[BrewManNH]

The latest version of the BASS.dll is 2.4.10 and was last updated in February of 2013. Although some of the add-on DLLs have been updated since then.

[MarcroSoft]

Yes, I just checked it.

I am currently thinking about replacing my vorbis files with speex, and I can confirm that the bass_spx.dll can load files in autoit.

Marc

[MarcroSoft]

How can I get the data from bass_tags_read? I can't find out how to get the pointer to Work here.

[BrewManNH]

This is a snippet of code that should get you started, it pulls the track and title info from a music file.

#include "Bass.au3"                 ; http://www.autoitscript.com/forum/index.php?showtopic=140594
#include "BassTags.au3"             ; http://www.autoitscript.com/forum/index.php?showtopic=83481
_Bass_Startup("Bass.dll") ; change path to where you have the dll, this has to be run first
_Bass_Tags_Startup("BassTags.dll")  ; then this one
_BASS_Init(0, -1, 44100, 0, "") 
$hMusic = _BASS_StreamCreateFile(False,<full path to music file>, 0, 0, $BASS_STREAM_DECODE) ; open a handle to the music file
$sTrackInfo = _Bass_Tags_Read($hMusic, "%IFV2(%TRCK,%TRCK,00)")  ; this reads the v2 track info from the file
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $sTrackInfo = ' & $sTrackInfo & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console
$sTitle = _Bass_Tags_Read($hMusic, "%IFV2(%TITL,%TITL,x)") ; find the title info from the ID3 tags
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $sTitle = ' & $sTitle & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console

[MarcroSoft]

Thanks a lot!

Bass

[MarcroSoft]

Hi Again,

This might be a stupid question, but are there some kind of better keyboard handeling in autoit than hotkeyset? i mean something like:

if key_pressed($key)...

Marc

[BrewManNH]

_IsPressed

[FlashpointBlack]

I just wanted to say thanks for the combined effort of everyone here to make this UDF into such a multifunctional gem.

I just finished writing a little script for myself that reads recipe instructions aloud using TTS and activates the next step of the recipe by detecting 3 claps/finger snaps/etc... in a row. an utterly fantastic little addition to any kitchen which wouldn't have been possible without this UDF.

You're appreciated, thank you!