How to save selected text to string?

[Tapeworm]

Im trying to make a program that imitates copy/paste, but i cant seem to figure out how i can save the selected text to a string. Does anyone have any ideas? thanks

[Andreik]

Im trying to make a program that imitates copy/paste, but i cant seem to figure out how i can save the selected text to a string. Does anyone have any ideas? thanks

If you want something like copy/paste you can use ClipBoard functions. Read more in help file.

[Tapeworm]

no, don't want it to go through the clipboard. I want to be able to copy something without overwriting the stuff in the clipboard. I want to be able to select some text (for example this sentence) with my mouse, and then save it to a string.

[Andreik]

no, don't want it to go through the clipboard. I want to be able to copy something without overwriting the stuff in the clipboard. I want to be able to select some text (for example this sentence) with my mouse, and then save it to a string.

If you want to do that in an edit control is very easy with _GUICtrlEdit_GetSel().

[Tapeworm]

_GUICtrlEdit_GetSel() does not do what I want it to. I want to be able to select any text, in any situation just like with ctrl+c, and convert it to a string.

[Andreik]

_GUICtrlEdit_GetSel() does not do what I want it to. I want to be able to select any text, in any situation just like with ctrl+c, and convert it to a string.

For example how can select text from a label?

[SmOke_N]

expandcollapse popup

HotKeySet("{ESC}", "_Mouse_Exit_App")

Global $f_mouse_is_down = False
Global $i_mouse_primary = 0x01 ; 0x01 = left for primary, 0x02 = right
Global $h_mouse_mod, $h_mouse_timer
$h_mouse_timer = _Mouse_StartWatch($h_mouse_mod, "_Mouse_GetHighlight_ToClipboard", "int", "", 0, 10003, 10)

While 1
    Sleep(100000)
WEnd

Func _Mouse_GetHighlight_ToClipboard()
    If Not $f_mouse_is_down Then
        Local $a_getasync = DllCall("User32.dll", "int", "GetAsyncKeyState", "int", $i_mouse_primary)
        If Not @error And BitAND($a_getasync[0], 0x8000) = 0x8000 Then
            $f_mouse_is_down = True
            While Not @error And BitAND($a_getasync[0], 0x8000) = 0x8000
                Sleep(50)
                $a_getasync = DllCall("User32.dll", "int", "GetAsyncKeyState", "int", $i_mouse_primary)
            WEnd
            Send("^c")
            Sleep(100)
            $f_mouse_is_down = False
        EndIf
    EndIf
    Return
EndFunc

Func _Mouse_StartWatch(ByRef $h_mod, $s_func, $v_ret_type, $v_params, $h_wnd, $i_event_id, $i_event_time)
    $h_mod = DllCallbackRegister($s_func, $v_ret_type, $v_params)
    If @error Then Return SetError(@error, 1, 0)
    Local $h_timer = DllCall("User32.dll", "int", "SetTimer", _
                        "hwnd", $h_wnd, _
                        "uint", $i_event_id, _
                        "uint", $i_event_time, _
                        "ptr", DllCallbackGetPtr($h_mod))
    If @error Then Return SetError(@error, 2, 0)
    Return $h_timer[0]
EndFunc

Func _Mouse_StopWatch($h_mod, $h_timer, $h_wnd = 0)
    DllCallbackFree($h_mod)
    DllCall("User32.dll", "int", "KillTimer", "hwnd", $h_wnd, "int", $h_timer)
    If @error Then Return SetError(@error, 0, 0)
    Return 1
EndFunc

Func _Mouse_Exit_App()
    If IsDeclared("h_mouse_mod") Then _Mouse_StopWatch($h_mouse_mod, $h_mouse_timer)
    Exit
EndFunc

Edited October 14, 2008 by SmOke_N
Had to fix the IsDeclared statement

[Tapeworm]

uhm, wow... thanks

[rasim]

SmOke_N

Nice example! Thank you!

[MrCreatoR]

@SmOke_N

Very good example, thanks!

Just one thing... instead of using Send("^c") it is better to use Send("^{Insert}"), because the current method will fail if i change the default language layot to some other language than English.

[SmOke_N]

@SmOke_N

Very good example, thanks!

Just one thing... instead of using Send("^c") it is better to use Send("^{Insert}"), because the current method will fail if i change the default language layot to some other language than English.

Good point... I actually ended up writing a MultiEvent.au3 file using the SetTimer/DllCallback method.

[MrCreatoR]

And also there is a bug with Exit, why the script not exit? the IsDeclared("h_mouse_mod") should be IsDeclared("$h_mouse_mod"), but it's still strange, it seems that script can not exit while the callback is not free...

[SmOke_N]

And also there is a bug with Exit, why the script not exit? the IsDeclared("h_mouse_mod") should be IsDeclared("$h_mouse_mod")

That's not correct ...

[MrCreatoR]

That's not correct ...

Oops, you are right, probably i was tired yesterday

So, the script not exits because it's trying to stop the timer? ....

[MrCreatoR]

Ok, here is a little bit changed script, now it's exit as it should (we need to set timer on more than 10 ms, otherwise it will fail):

expandcollapse popup

HotKeySet("{ESC}", "_Mouse_Exit_App")

Global $i_Mouse_Is_Down = False
Global $i_Mouse_Primary = 0x01 ; 0x01 = left for primary, 0x02 = right

Global $a_hMouseMod_hTimer = _Mouse_StartWatch("_Mouse_GetHighlight_ToClipboard", 0, 10001, 1000)

While 1
    Sleep(100)
WEnd

Func _Mouse_GetHighlight_ToClipboard()
    If Not $i_Mouse_Is_Down Then
        Local $a_GetAsync = DllCall("User32.dll", "int", "GetAsyncKeyState", "int", $i_Mouse_Primary)
        
        If Not @error And BitAND($a_GetAsync[0], 0x8000) = 0x8000 Then
            $i_Mouse_Is_Down = True
            
            While Not @error And BitAND($a_GetAsync[0], 0x8000) = 0x8000
                Sleep(50)
                $a_GetAsync = DllCall("User32.dll", "int", "GetAsyncKeyState", "int", $i_Mouse_Primary)
            WEnd
            
            Send("^{Insert}")
            Sleep(100)
            
            $i_Mouse_Is_Down = False
        EndIf
    EndIf
    
    Return 1
EndFunc

Func _Mouse_StartWatch($sCallback_Func, $hWnd, $iEvent_ID, $iEvent_Time)
    Local $h_Mouse_Mod = DllCallbackRegister($sCallback_Func, "int", "")
    If @error Then Return SetError(@error, 1, 0)
    
    Local $h_Timer = DllCall("User32.dll", "int", "SetTimer", _
                        "hwnd", $hWnd, _
                        "int", $iEvent_ID, _
                        "int", $iEvent_Time, _
                        "ptr", DllCallbackGetPtr($h_Mouse_Mod))
    
    If @error Then Return SetError(@error, 2, 0)
    
    Local $aRet[2] = [$h_Mouse_Mod, $h_Timer[0]]
    
    Return $aRet
EndFunc

Func _Mouse_StopWatch(ByRef $h_Mouse_Mod, ByRef $h_Timer, $hWnd = 0)
    If $h_Mouse_Mod > 0 Then
        DllCallbackFree($h_Mouse_Mod)
        $h_Mouse_Mod = 0
    EndIf
    
    If $h_Timer > 0 Then
        DllCall("User32.dll", "int", "KillTimer", "hwnd", $hWnd, "int", $h_Timer)
        If @error Then Return SetError(@error, 0, 0)
        
        $h_Timer = 0
    EndIf
    
    Return 1
EndFunc

Func _Mouse_Exit_App()
    _Mouse_StopWatch($a_hMouseMod_hTimer[0], $a_hMouseMod_hTimer[1])
    
    Exit
EndFunc