Detect double-click on edit box

[JonnyThunder]

Hello,

As per the title - is there a way to detect a double-click on a text box?? Or even, create a context menu for a text box??

Thanks,

JT

[Kiti]

Look in the helpfile for _Timer_Init() and Ispressed().

You should check if the mouse clicks two times, measure the time between the clicks, and if the time is smaller than x miliseconds, then that's a double click.

[JonnyThunder]

Is this really the only way it can be done? Are there no event handlers or anything for double clicks on a form field?

[rasim]

JonnyThunder

Is this really the only way it can be done?

Example with subclassing control:

expandcollapse popup

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>
#include <WinAPI.au3>

Global Const $WM_LBUTTONDBLCLK = 0x203

$hGUI = GUICreate("Test GUI", 300, 200)

$edit = GUICtrlCreateEdit("", 10, 10, 280, 180)

$wProcHandle = DllCallbackRegister("_WindowProc", "ptr", "hwnd;uint;wparam;lparam")

$wProcOld = _WinAPI_SetWindowLong(GUICtrlGetHandle($edit), $GWL_WNDPROC, DllCallbackGetPtr($wProcHandle))

GUISetState()

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

GUIDelete($hGui)
DllCallbackFree($wProcHandle)

Func _WindowProc($hWnd, $Msg, $wParam, $lParam)
    Switch $hWnd
        Case GUICtrlGetHandle($edit)
            Switch $Msg
                Case $WM_LBUTTONDBLCLK
                    ConsoleWrite("-> Left mouse double click" & @LF)
                    Return 0
            EndSwitch
    EndSwitch
    
    Local $aRet = DllCall("user32.dll", "int", "CallWindowProc", "ptr", $wProcOld, _
                          "hwnd", $hWnd, "uint", $Msg, "wparam", $wParam, "lparam", $lParam)
    Return $aRet[0]
EndFunc

[JonnyThunder]

Wow - thats just the example im looking for!

Many thanks for your post.

[martin]

Wow - thats just the example im looking for!

Many thanks for your post.

It might be worth considering commenting out the Return 0 line after detecting the double click so that the user can select a word that way and you can detect the double click as well.