_GUICtrlListView_GetItemID - With ...InsertItem()

[MrCreatoR]

Hi,

I managed to build a little function to get LV ItemID by it's index (from other function in the last AutoIt version), but it works only on created items with native function (GUICtrlCreateListViewItem()).

I should mention right now, that i still use v3.2.8.1, and it's only because i have no time to port all my main scripts to new version

But in the example bellow i used last version, so anyone ho wants to help me will not have to change stuff for the last version.

Here is what i got:

expandcollapse popup

#include <GuiConstantsEx.au3>
#include <GuiListView.au3>

;Global Const $tagLVITEM = "int Mask;int Item;int SubItem;int State;int StateMask;ptr Text;" & _
    ;"int TextMax;int Image;int Param;int Indent;int GroupID;int Columns;ptr pColumns"

;Global Const $LVIF_PARAM   = 0x00000004
;Global Const $LVM_GETITEMW     = $LVM_FIRST + 75

GUICreate("_GUICtrlListView_GetItemID - Get ItemID by Index!", 400, 300)

$hListView = GUICtrlCreateListView("Items|IDs", 2, 2, 394, 268)

$ItemID = $hListView + 1
$iInsertItems = False ;Change it to True to see that we can not get ItemID for inserted items :(

For $i = 1 To 10
    If $iInsertItems Then
        _GUICtrlListView_InsertItem($hListView, "Index " & $i-1)
        _GUICtrlListView_SetItemText($hListView, $i-1, "ItemID " & $ItemID, 1)
    Else
        GUICtrlCreateListViewItem("Index " & $i-1 & "|ItemID " & $ItemID, $hListView)
    EndIf
    
    $ItemID += 1
Next

$GetID_Button = GUICtrlCreateButton("Get ItemID", 10, 275, 70, 20)

$Status_Label = GUICtrlCreateLabel("", 90, 278, 200, 25)
GUICtrlSetFont(-1, 9, 800, 0, "Tahoma")

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GetID_Button
            $iItemIndex = _GUICtrlListView_GetSelectedIndices($hListView)
            $iItemID = _GUICtrlListView_GetItemID($hListView, $iItemIndex)
            
            GUICtrlSetData($Status_Label, StringFormat("Index %i = ItemID %i", $iItemIndex, $iItemID))
    EndSwitch
WEnd


Func _GUICtrlListView_GetItemID($hWnd, $iIndex)
    Local $tItem, $pItem, $iResult
    
    $tItem = DllStructCreate($tagLVITEM)
    
    DllStructSetData($tItem, "Mask", $LVIF_PARAM)
    DllStructSetData($tItem, "Item", $iIndex)
    
    $pItem = DllStructGetPtr($tItem)
    
    If @AutoItUnicode Then
        $iResult = GUICtrlSendMsg($hWnd, $LVM_GETITEMW, 0, $pItem)
    Else
        $iResult = GUICtrlSendMsg($hWnd, $LVM_GETITEMA, 0, $pItem)
    EndIf
    
    Return DllStructGetData($tItem, "Param")
EndFunc

If you set $iInsertItems to True (but first try it "as is"), you will see that my function always return 0 on any selected item.

P.S

Something telling me that items that inserted by way of «_GUICtrlListView_InsertItem()» function, just don't have an ID muttley , and they are like virtual elements that can be recognized only by index... i hope i wrong here...

Edited July 17, 2008 by MrCreatoR

[GaryFrost]

param = item id

[MrCreatoR]

param = item id

That's what i use:

Func _GUICtrlListView_GetItemID($hWnd, $iIndex)
    Local $tItem, $pItem, $iResult
    
    $tItem = DllStructCreate($tagLVITEM)
    
    DllStructSetData($tItem, "Mask", $LVIF_PARAM)
    DllStructSetData($tItem, "Item", $iIndex)
    
    $pItem = DllStructGetPtr($tItem)
    
    If @AutoItUnicode Then
        $iResult = GUICtrlSendMsg($hWnd, $LVM_GETITEMW, 0, $pItem)
    Else
        $iResult = GUICtrlSendMsg($hWnd, $LVM_GETITEMA, 0, $pItem)
    EndIf
    
    Return DllStructGetData($tItem, "Param")
EndFunc

But it works only if i create the items with GUICtrlCreateListViewItem().

[GaryFrost]

I don't have v3.2.8.x anymore, but the current insert has param as last parameter.

The param is the same as the built-in control id of the listview items.

[MrCreatoR]

I don't have v3.2.8.x anymore, but the current insert has param as last parameter.

The param is the same as the built-in control id of the listview items.

Thank you very much! It's work! I'll just port this function to 3.2.8.1 environment (with slight changes) muttley .

[MrCreatoR]

Hm, now i have problems set image for the inserted item muttley

expandcollapse popup

#include <GuiConstantsEx.au3>
#include <GuiListView.au3>

;Global Const $tagLVITEM = "int Mask;int Item;int SubItem;int State;int StateMask;ptr Text;" & _
    ;"int TextMax;int Image;int Param;int Indent;int GroupID;int Columns;ptr pColumns"

;Global Const $LVIF_PARAM   = 0x00000004
;Global Const $LVM_GETITEMW     = $LVM_FIRST + 75

GUICreate("_GUICtrlListView_GetItemID - Get ItemID by Index!", 400, 300)

$hListView = GUICtrlCreateListView("Items|IDs", 2, 2, 394, 268)

$GetID_Button = GUICtrlCreateButton("Get ItemID", 10, 275, 70, 20)

$Status_Label = GUICtrlCreateLabel("", 90, 278, 200, 25)
GUICtrlSetFont(-1, 9, 800, 0, "Tahoma")

$iINSERTITEMS = True ;Change it to True to see that we can not set image for inserted items :(

$ItemID = $Status_Label + 1

For $i = 1 To 10
    If $iINSERTITEMS Then
        _GUICtrlListView_InsertItemEx($hListView, "Index " & $i-1, $i-1, $ItemID)
        _GUICtrlListView_SetItemText($hListView, $i-1, "ItemID " & $ItemID, 1)
    Else
        GUICtrlCreateListViewItem("Index " & $i-1 & "|ItemID " & $ItemID, $hListView)
    EndIf
    
    ;This not working on the inserted items :(, even if they have ID
    GUICtrlSetImage($ItemID, "shell32.dll", Random(1, 50, 1))
    
    $ItemID += 1
Next

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GetID_Button
            $iItemIndex = _GUICtrlListView_GetSelectedIndices($hListView)
            $iItemID = _GUICtrlListView_GetItemID($hListView, $iItemIndex)
            
            GUICtrlSetData($Status_Label, StringFormat("Index %i = ItemID %i", $iItemIndex, $iItemID))
    EndSwitch
WEnd

Func _GUICtrlListView_InsertItemEx($hWnd, $sText, $iIndex = -1, $iParam = 0)
    Local $iBuffer, $pBuffer, $tBuffer, $iItem, $tItem, $iMask, $iResult
    If $iIndex = -1 Then $iIndex = 999999999
    
    $tItem = DllStructCreate($tagLVITEM)
    $pItem = DllStructGetPtr($tItem)
    
    DllStructSetData($tItem, "Param", $iParam)
    
    If $sText <> -1 Then
        $iBuffer = StringLen($sText) + 1
        
        If @AutoItUnicode Then
            $tBuffer = DllStructCreate("wchar Text[" & $iBuffer & "]")
        Else
            $tBuffer = DllStructCreate("char Text[" & $iBuffer & "]")
        EndIf
        
        $pBuffer = DllStructGetPtr($tBuffer)
        
        DllStructSetData($tBuffer, "Text", $sText)
        DllStructSetData($tItem, "Text", $pBuffer)
        DllStructSetData($tItem, "TextMax", $iBuffer)
    Else
        DllStructSetData($tItem, "Text", -1)
    EndIf
    
    $iMask = BitOR($LVIF_TEXT, $LVIF_PARAM)
    
    DllStructSetData($tItem, "Mask", $iMask)
    DllStructSetData($tItem, "Item", $iIndex)
    
    If @AutoItUnicode Then
        $iResult = GUICtrlSendMsg($hWnd, $LVM_INSERTITEMW, 0, $pItem)
    Else
        $iResult = GUICtrlSendMsg($hWnd, $LVM_INSERTITEMA, 0, $pItem)
    EndIf
    
    Return $iResult
EndFunc

Func _GUICtrlListView_GetItemID($hWnd, $iIndex)
    Local $tItem, $pItem, $iResult
    
    $tItem = DllStructCreate($tagLVITEM)
    
    DllStructSetData($tItem, "Mask", $LVIF_PARAM)
    DllStructSetData($tItem, "Item", $iIndex)
    
    $pItem = DllStructGetPtr($tItem)
    
    If @AutoItUnicode Then
        $iResult = GUICtrlSendMsg($hWnd, $LVM_GETITEMW, 0, $pItem)
    Else
        $iResult = GUICtrlSendMsg($hWnd, $LVM_GETITEMA, 0, $pItem)
    EndIf
    
    Return DllStructGetData($tItem, "Param")
EndFunc

I know i can(?) port the whole stuff of «ImageList...» to the v3.2.8.1 environment also, but it will force me to change a lot of stuff in my script, i hope there is some way to set image (from file, with index) easily?

I thought that if the item have an ID, then it should act the same as item created with GUICtrlCreateListViewItem()...

[GaryFrost]

Hm, now i have problems set image for the inserted item muttley

expandcollapse popup

#include <GuiConstantsEx.au3>
#include <GuiListView.au3>

;Global Const $tagLVITEM = "int Mask;int Item;int SubItem;int State;int StateMask;ptr Text;" & _
    ;"int TextMax;int Image;int Param;int Indent;int GroupID;int Columns;ptr pColumns"

;Global Const $LVIF_PARAM   = 0x00000004
;Global Const $LVM_GETITEMW     = $LVM_FIRST + 75

GUICreate("_GUICtrlListView_GetItemID - Get ItemID by Index!", 400, 300)

$hListView = GUICtrlCreateListView("Items|IDs", 2, 2, 394, 268)

$GetID_Button = GUICtrlCreateButton("Get ItemID", 10, 275, 70, 20)

$Status_Label = GUICtrlCreateLabel("", 90, 278, 200, 25)
GUICtrlSetFont(-1, 9, 800, 0, "Tahoma")

$iINSERTITEMS = True ;Change it to True to see that we can not set image for inserted items :(

$ItemID = $Status_Label + 1

For $i = 1 To 10
    If $iINSERTITEMS Then
        _GUICtrlListView_InsertItemEx($hListView, "Index " & $i-1, $i-1, $ItemID)
        _GUICtrlListView_SetItemText($hListView, $i-1, "ItemID " & $ItemID, 1)
    Else
        GUICtrlCreateListViewItem("Index " & $i-1 & "|ItemID " & $ItemID, $hListView)
    EndIf
    
    ;This not working on the inserted items :(, even if they have ID
    GUICtrlSetImage($ItemID, "shell32.dll", Random(1, 50, 1))
    
    $ItemID += 1
Next

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GetID_Button
            $iItemIndex = _GUICtrlListView_GetSelectedIndices($hListView)
            $iItemID = _GUICtrlListView_GetItemID($hListView, $iItemIndex)
            
            GUICtrlSetData($Status_Label, StringFormat("Index %i = ItemID %i", $iItemIndex, $iItemID))
    EndSwitch
WEnd

Func _GUICtrlListView_InsertItemEx($hWnd, $sText, $iIndex = -1, $iParam = 0)
    Local $iBuffer, $pBuffer, $tBuffer, $iItem, $tItem, $iMask, $iResult
    If $iIndex = -1 Then $iIndex = 999999999
    
    $tItem = DllStructCreate($tagLVITEM)
    $pItem = DllStructGetPtr($tItem)
    
    DllStructSetData($tItem, "Param", $iParam)
    
    If $sText <> -1 Then
        $iBuffer = StringLen($sText) + 1
        
        If @AutoItUnicode Then
            $tBuffer = DllStructCreate("wchar Text[" & $iBuffer & "]")
        Else
            $tBuffer = DllStructCreate("char Text[" & $iBuffer & "]")
        EndIf
        
        $pBuffer = DllStructGetPtr($tBuffer)
        
        DllStructSetData($tBuffer, "Text", $sText)
        DllStructSetData($tItem, "Text", $pBuffer)
        DllStructSetData($tItem, "TextMax", $iBuffer)
    Else
        DllStructSetData($tItem, "Text", -1)
    EndIf
    
    $iMask = BitOR($LVIF_TEXT, $LVIF_PARAM)
    
    DllStructSetData($tItem, "Mask", $iMask)
    DllStructSetData($tItem, "Item", $iIndex)
    
    If @AutoItUnicode Then
        $iResult = GUICtrlSendMsg($hWnd, $LVM_INSERTITEMW, 0, $pItem)
    Else
        $iResult = GUICtrlSendMsg($hWnd, $LVM_INSERTITEMA, 0, $pItem)
    EndIf
    
    Return $iResult
EndFunc

Func _GUICtrlListView_GetItemID($hWnd, $iIndex)
    Local $tItem, $pItem, $iResult
    
    $tItem = DllStructCreate($tagLVITEM)
    
    DllStructSetData($tItem, "Mask", $LVIF_PARAM)
    DllStructSetData($tItem, "Item", $iIndex)
    
    $pItem = DllStructGetPtr($tItem)
    
    If @AutoItUnicode Then
        $iResult = GUICtrlSendMsg($hWnd, $LVM_GETITEMW, 0, $pItem)
    Else
        $iResult = GUICtrlSendMsg($hWnd, $LVM_GETITEMA, 0, $pItem)
    EndIf
    
    Return DllStructGetData($tItem, "Param")
EndFunc

I know i can(?) port the whole stuff of «ImageList...» to the v3.2.8.1 environment also, but it will force me to change a lot of stuff in my script, i hope there is some way to set image (from file, with index) easily?

I thought that if the item have an ID, then it should act the same as item created with GUICtrlCreateListViewItem()...

Even tho the item has an id it is not an id created by the internal function(s), therefore AutoIt can't handle it with internal function(s).

It would be quicker to install the beta and start converting scripts.

[MrCreatoR]

Even tho the item has an id it is not an id created by the internal function(s), therefore AutoIt can't handle it with internal function(s).

It would be quicker to install the beta and start converting scripts.

Thanks for the advice, but i already have 3 vesrions simultaneously installed (unpacked to be true): v3.2.8.1 (on this version based most of my scripts), 3.2.10.0, and 3.2.12.0.

And i can run any of those version at any time, i wrote a small script to switch between versions (i think i already have post it somewhere here on forum), but the main problem for me is that i have no time to rewrite all the scripts, some of them too complicate, and solutions in new environment (new AutoIt version) can take many of my "resources", and not sure that i can find those solutions that easy.