"AutoIt" User Agent String

[Blue_Drache]

From the changelog:

# Changed: AutoIt internet functions (e.g. InetGet()) now use "AutoIt" as a user-agent. Previously using blank

which was blocked by many websites.

Is there a way to set the user-agent to something other than "AutoIt" via an opt?

[Danny35d]

Right out of help file InetGet() remarks section.

To use a username and password when connecting simply prefix the servername with "username:password@", e.g.

"http://myuser:mypassword@www.somesite.com"

[GaryFrost]

From the changelog:

Is there a way to set the user-agent to something other than "AutoIt" via an opt?

AFAIK no

[weaponx]

This works. Looks like you can use ADODB.Stream to work with the binary result:

http://www.autoitscript.com/forum/index.ph...hl=responsebody

expandcollapse popup

#cs ----------------------------------------------------------------------------

 AutoIt Version: 3.2.12.0
 Author:         WeaponX / lod3n

 Script Function:
    Download file with header

#ce ----------------------------------------------------------------------------
$oMyError = ObjEvent("AutoIt.Error","MyErrFunc")

$oHTTP = ObjCreate('winhttp.winhttprequest.5.1')
$oHTTP.Open('GET', 'http://www.google.com/intl/en_ALL/images/logo.gif', FALSE)
$oHTTP.SetRequestHeader("User-Agent", "Mozilla/4.0 (compatible; MSIE 6.0; Windows NT 5.1; SV1; .NET CLR 1.1.4322; .NET CLR 2.0.50727; .NET CLR 3.0.04506.30; .NET CLR 3.0.04506.648; InfoPath.1)")
$oHTTP.Send()

ConsoleWrite("+<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< HEADERS" & @CRLF)
$Headers = $oHTTP.GetAllResponseHeaders() 
ConsoleWrite($Headers & @CRLF)

;ConsoleWrite("+<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< USER-AGENT" & @CRLF)
;$Agent = $oHTTP.GetResponseHeader("HTTP_USER_AGENT") 
;ConsoleWrite($Agent & @CRLF)

ConsoleWrite("+<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< Status" & @CRLF)
$Status = $oHTTP.Status
ConsoleWrite($Status & @CRLF)

ConsoleWrite("+<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< StatusText" & @CRLF)
$StatusText = $oHTTP.StatusText
ConsoleWrite($StatusText & @CRLF)

If $Status = 200 Then
    
    $oBinaryStream = ObjCreate("ADODB.Stream")  
    
    $filename = @DesktopDir & "\test.gif"
    
    $adTypeBinary = 1
    $adSaveCreateOverWrite = 2     
    FileDelete($filename)
    $oBinaryStream.Type = $adTypeBinary
    $oBinaryStream.Open
    $oBinaryStream.Write($oHttp.ResponseBody)
    $oBinaryStream.SaveToFile($filename, $adSaveCreateOverWrite)
EndIf

;--------------------------------
;COM Error Handler
;--------------------------------
Func MyErrFunc()
    Local $HexNumber
    $HexNumber=hex($oMyError.number,8)
    Msgbox(0,"COM Error ","We intercepted a COM Error !" & @CRLF & @CRLF & _
    "err.description is: " & @TAB & $oMyError.description & @CRLF & _
    "err.windescription:" & @TAB & $oMyError.windescription & @CRLF & _
    "err.number is: " & @TAB & $HexNumber & @CRLF & _
    "err.lastdllerror is: " & @TAB & $oMyError.lastdllerror & @CRLF & _
    "err.scriptline is: " & @TAB & $oMyError.scriptline & @CRLF & _
    "err.source is: " & @TAB & $oMyError.source & @CRLF & _
    "err.helpfile is: " & @TAB & $oMyError.helpfile & @CRLF & _
    "err.helpcontext is: " & @TAB & $oMyError.helpcontext _
    )
    SetError(1) ; to check for after this function returns
Endfunc

Edited July 16, 2008 by weaponx

[Blue_Drache]

Right out of help file InetGet() remarks section.

Zing! You completely MISSED it. Thank you for playing, here's your kwepie consolation prize.

AFAIK no

Hmm. Ok. Thanks.

This works. Looks like you can use ADODB.Stream to work with the binary result:

http://www.autoitscript.com/forum/index.ph...hl=responsebody

<...snip...>

Ouch. Not as simple as I'd hoped. *shrug* Thanks for the effort.

[MrCreatoR]

@Blue_Drache

You can (and should muttley ) make a feature request on this issue, imho, it's reasonable to have User Agent line as optional parameter (at least for InetGet/Size() functions), i think some pages might require a full user agent (with data such as browser, version, system, etc.).

[weaponx]

Ouch. Not as simple as I'd hoped. *shrug* Thanks for the effort.

Not really complex either. If you strip out the error checking and debug stuff the function is easy.

InetGetX('http://www.google.com/intl/en_ALL/images/logo.gif', @ScriptDir & "\google.gif")
Func InetGetX($sURL, $sFilename, $sUserAgent = "")
    
    ;If User Agent string is empty, use Firefox 3.0
    If $sUserAgent = "" Then
        $sUserAgent = "Mozilla/4.0 (compatible; MSIE 6.0; Windows NT 5.1; SV1; .NET CLR 1.1.4322; .NET CLR 2.0.50727; .NET CLR 3.0.04506.30; .NET CLR 3.0.04506.648; InfoPath.1)"
    EndIf
    
    $oHTTP = ObjCreate('winhttp.winhttprequest.5.1')
    $oHTTP.Open('GET', $sURL, FALSE)
    $oHTTP.SetRequestHeader("User-Agent", $sUserAgent)
    $oHTTP.Send()

    ;If HTTP Status OK, save file
    If $oHTTP.Status = 200 Then
        $oBinaryStream = ObjCreate("ADODB.Stream")     
        $adTypeBinary = 1
        $adSaveCreateOverWrite = 2     
        FileDelete($sFilename)
        $oBinaryStream.Type = $adTypeBinary
        $oBinaryStream.Open
        $oBinaryStream.Write($oHttp.ResponseBody)
        $oBinaryStream.SaveToFile($sFilename, $adSaveCreateOverWrite)
    EndIf
EndFunc