Navigating Tab Control

[Shuresh]

How to Navgate in different Tab Controls.. please check the attachement for clarification I need to open the next tab automatically...

Thanks

Shuresh

[tlokz]

How to Navgate in different Tab Controls.. please check the attachement for clarification I need to open the next tab automatically...

Thanks

Shuresh

what do u need to do now?

If im geussing right u want it to show a differnt tab on startup or wenever jus us this:

GUICtrlSetState($TabVar , $GUI_SHOW)

Edited July 4, 2008 by tlokz

[enaiman]

The easiest way is to send a "RIGHT" key and that will open your next tab.

[TehWhale]

The easiest way is to send a "RIGHT" key and that will open your next tab.

What if your focused on an input box? It won't work. The post before yours will.

[enaiman]

What if your focused on an input box? It won't work. The post before yours will.

Take a close look at the picture attached and you will see that the tab IS highlighted ... and it will work always (even when you can't get the tab handle).

The previous post assumed that either you can get the tab handle either the GUI was created by AutoIt ...

[MrCreatoR]

Look at _GUICtrlTab_GetCurSel() / _GUICtrlTab_SetCurSel()...

expandcollapse popup

#include <GuiConstantsEx.au3>
#include <GuiTab.au3>

$GUI = GUICreate("Test Script", 300, 200)

$hTab = GUICtrlCreateTab(20, 10, 260, 150)

$Tab1 = GUICtrlCreateTabItem("Tab1")
$Tab2 = GUICtrlCreateTabItem("Tab2")
$Tab3 = GUICtrlCreateTabItem("Tab3")

;GUICtrlSetState($Tab2, $GUI_SHOW)

GUICtrlCreateTabItem("")

$Switch_Button = GUICtrlCreateButton("Switch Next", 20, 170, 80, 20)

GUISetState(@SW_SHOW, $GUI)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Switch_Button
            $iCurrent_TabIndex = _GUICtrlTab_GetCurSel($hTab)
            $iNext_TabIndex = $iCurrent_TabIndex
            
            Switch $iCurrent_TabIndex
                Case 0, 1
                    $iNext_TabIndex += 1
                Case 2
                    $iNext_TabIndex = 0
            EndSwitch
            
            _GUICtrlTab_SetCurSel($hTab, $iNext_TabIndex)
    EndSwitch
WEnd

[MrCreatoR]

And for the external usage:

expandcollapse popup

#include <GuiConstantsEx.au3>
#include <GuiTab.au3>

$GUI = GUICreate("Test Script", 300, 200)

$hTab = GUICtrlCreateTab(20, 10, 260, 150)

$Tab1 = GUICtrlCreateTabItem("Tab1")
$Tab2 = GUICtrlCreateTabItem("Tab2")
$Tab3 = GUICtrlCreateTabItem("Tab3")

GUICtrlCreateTabItem("")

$Switch_Button = GUICtrlCreateButton("Switch Next", 20, 170, 80, 20)

GUISetState(@SW_SHOW, $GUI)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Switch_Button
            ;This handle can by taken from any window that have standard SysTabControl
            $hWnd_Tab = ControlGetHandle("Test Script", "", "SysTabControl321")
            _GUICtrlTab_SwitchNext($hWnd_Tab)
    EndSwitch
WEnd

Func _GUICtrlTab_SwitchNext($hWnd)
    Local $iItems_Count = _GUICtrlTab_GetItemCount($hWnd)
    Local $iCurrent_TabIndex = _GUICtrlTab_GetCurSel($hWnd)
    Local $iNext_TabIndex = $iCurrent_TabIndex
    
    Switch $iCurrent_TabIndex
        Case 0 To $iItems_Count-2
            $iNext_TabIndex += 1
        Case Else
            $iNext_TabIndex = 0
    EndSwitch
    
    _GUICtrlTab_SetCurSel($hWnd, $iNext_TabIndex)
EndFunc

[Shuresh]

That is not created using Autoit GUI, and its thrid party software, I want to automate to move to next tab to set the parameter to display in screen.

So using Autoit I dono how to go next tab... becoz in Visible information I am not able to find any handle to control the swtiching of Tabs.. Since I am a starter pls help me out in this regards...

Thanks in Advance

Shuresh

what do u need to do now?

If im geussing right u want it to show a differnt tab on startup or wenever jus us this:

GUICtrlSetState($TabVar , $GUI_SHOW)

[enaiman]

Have you read all the posts? I already gave you a simple solution for that:

Get your tab control highlited (as it is shown in the image you posted) and send a "RIGHT" key to that application.

[AdmiralAlkex]

Have you tried Send() or ControlSend() with ctrl+tab?

Edited July 8, 2008 by AdmiralAlkex

[MrCreatoR]

Have you tried what i posted? replace "My Title" with your window title, and try it:

#include <GuiTab.au3>

$hWnd_Tab = ControlGetHandle("My Title", "", "SysTabControl321")
_GUICtrlTab_SwitchNext($hWnd_Tab)

Func _GUICtrlTab_SwitchNext($hWnd)
    Local $iItems_Count = _GUICtrlTab_GetItemCount($hWnd)
    Local $iCurrent_TabIndex = _GUICtrlTab_GetCurSel($hWnd)
    Local $iNext_TabIndex = $iCurrent_TabIndex
    
    Switch $iCurrent_TabIndex
        Case 0 To $iItems_Count-2
            $iNext_TabIndex += 1
        Case Else
            $iNext_TabIndex = 0
    EndSwitch
    
    _GUICtrlTab_SetCurSel($hWnd, $iNext_TabIndex)
EndFunc

[ph0tix]

Hi all, I've implemented the following code in one of my scripts. It successfully selects the tab itself - but the contents of the tab do not actually update. In other words - if I start on Tab 1, and then change to Tab2, Tab2 will appear selected but the contents of Tab1 stay visible. I've tried _WinAPI_RedrawWindow to see if that would help, but it appears not to.

Any thoughts?

Thanks!

Have you tried what i posted? replace "My Title" with your window title, and try it:

#include <GuiTab.au3>

$hWnd_Tab = ControlGetHandle("My Title", "", "SysTabControl321")
_GUICtrlTab_SwitchNext($hWnd_Tab)

Func _GUICtrlTab_SwitchNext($hWnd)
    Local $iItems_Count = _GUICtrlTab_GetItemCount($hWnd)
    Local $iCurrent_TabIndex = _GUICtrlTab_GetCurSel($hWnd)
    Local $iNext_TabIndex = $iCurrent_TabIndex
    
    Switch $iCurrent_TabIndex
        Case 0 To $iItems_Count-2
            $iNext_TabIndex += 1
        Case Else
            $iNext_TabIndex = 0
    EndSwitch
    
    _GUICtrlTab_SetCurSel($hWnd, $iNext_TabIndex)
EndFunc