_DriveGetClusterSize

[monoceres]

Hi!

Needed this for a project of mine and I thought that someone else might need it.

UDF:

; #FUNCTION#;===============================================================================
;
; Name...........: _DriveGetClusterSize
; Description ...: Returns the cluster size of a drive
; Syntax.........: _DriveGetClusterSize([$sDrive=@HomeDrive])
; Parameters ....:
; Return values .: Success - Cluster size in bytes
;               .; Failure - -1 and @error=1
; Author ........: Andreas Karlsson (monoceres)
; Modified.......:
; Remarks .......:
; Related .......: 
; Link ..........;
; Example .......; No
;
;;==========================================================================================
Func _DriveGetClusterSize($sDrive = @HomeDrive)
    If StringRight($sDrive,1)<>'\' Then $sDrive&='\'
    Local $iClusterSize, $vNULL, $aArray
    $aArray = DllCall("Kernel32.dll", "int", "GetDiskFreeSpace", "str", $sDrive, "dword*", $vNULL, "dword*", $vNULL, "dword*", $vNULL, "dword*", $vNULL)
    If IsArray($aArray) Then
        $iClusterSize = $aArray[2] * $aArray[3]
        Return SetError(0,0,$iClusterSize)
    EndIf
    Return SetError(1,0,-1)
EndFunc;==>_GetClusterSize

Example:

$file=FileOpenDialog("Select file","","All files (*.*)")

$size=FileGetSize($file)
$clustersize=_DriveGetClusterSize(StringLeft($file,3))
$sizeondisc=Ceiling($size/$clustersize)*$clustersize
MsgBox(0,"Info","Filename: "&$file&@CRLF&"Filesize: "&$size&" bytes"&@CRLF&"Size on disc: "&$sizeondisc&" bytes"&@CRLF&"Wasted: "&$sizeondisc-$size&" bytes")

Edited June 26, 2008 by monoceres

[gseller]

Nice funtion, thanks for sharing..

[WeMartiansAreFriendly]

Nice Job!

Oh.. I think you forgot something

$aArray = DllCall("Kernel32.dll", "int", "GetDiskFreeSpace", "str", $sDrive, "dword*", $vNULL, "dword*", $vNULL, "dword*", $vNULL, "dword*", $vNULL)

[Andreik]

Thanks monoceres!

[monoceres]

Oh.. I think you forgot something

Thanks for noticing