Inputbox: tecting Changes

[Eigensheep]

Does anyone know how you can detect when the user changes the value of an inputbox? For example is the value is "Open" and the user drags and drops the value "Close" into it, how can I handle this event? Thanks for any help.

[d4rk]

While 1
if $input<>"Open" then
mgbox(64,"","you changed it ...")
endif
Wend

[martin]

Does anyone know how you can detect when the user changes the value of an inputbox? For example is the value is "Open" and the user drags and drops the value "Close" into it, how can I handle this event? Thanks for any help.

This will tell you what is in the inputbox all the time it is displayed.

Global $handle, $SetTimer
Dim $Folder

$handle = DllCallbackRegister("_ReadIPBox", "int", "")
$SetTimer = DllCall("User32.dll", "int", "SetTimer", "hwnd", 0, "int", 0, "int", 500, "ptr", DllCallbackGetPtr($handle))
$SetTimer = $SetTimer[0]


$answer = InputBox("Question", "Where were you born?", "Planet Earth", "", _
    -1, -1, 0, 0)
    
    
     DllCallbackFree($handle)
        DllCall("user32.dll", "int", "KillTimer", "hwnd", 0, "int", $SetTimer)
        
Func _ReadIPBox()
    If WinExists("Question") Then
        ConsoleWrite(ControlCommand("Question","Where were you born?","Edit1","GetLine", 1) & @CRLF)
    EndIf
EndFunc

Edited May 12, 2008 by martin

[danielkza]

Using EN_CHANGE notification:

#include <GUIConstantsEx.au3>
#include <EditConstants.au3>
#include <WIndowsConstants.au3>
#include <WinAPI.au3>

$GUI = GuiCreate("Input change test",200,60)
$Input = GUICtrlCreateInput("Type Here",10,15,180,30)

GuiRegisterMsg($WM_COMMAND,"WM_COMMAND")

GuiSetState()

Do
Until GUiGetMsg() = $GUI_EVENT_CLOSE

Func WM_COMMAND($hWnd,$msgID,$wParam,$lParam)
    If _WinAPI_HiWord($wParam) = $EN_CHANGE Then
        MsgBox(0,"Text Changed","New Text :" & GUICtrlRead($Input))
    EndIf
EndFunc

[martin]

@ d4rk, danielkza

The op asked for inputbox not GuiCtrlCreateInput. If NumberDaemon meant GuiCtrlCreateInput then I think danielkza's solution is correct and mine in incorrect.

@ d4rk

To read the contents of an input you need GuiCtrlRead($input).

Edited May 13, 2008 by martin

[Eigensheep]

Thanks for the help guys, I've managed to get it working fine now.