determine the name of a file's directory or folder

[MattH]

I can confirm the presence of a file using filefind but how can i determine which directory or folder it's in?

[blademonkey]

I can confirm the presence of a file using filefind but how can i determine which directory or folder it's in?

FileGetLongName ()

Returns the long path+name of the path+name passed.

[MattH]

Thanks, but I can't figure out how to use that to accomplish what I need. I'm trying to find the path to a file somewhere on the c drive. Is there a function or macro already built that will do that? Ideally, it would be something like FileFindPath("file name",[flag]) and the return would be an array containing all the directories in which that file was found.

FileFindPath("test.txt")

0|3

1|c:\temp\

2|c:\program files\gadget\

3|c:\windows\

Like that.

[therks]

You'll need to write your own function to do that. Something that will search every folder looking for the file, which won't be quick. Have fun.

[MrCreatoR]

I can confirm the presence of a file using filefind but how can i determine which directory or folder it's in?

You just do some regexp...

$File = "c:\some dir\some file.txt"

$ParentDir = StringRegExpReplace($File, "\\[^\\]*$", "")
MsgBox(0, "", $ParentDir)

Or i am just missunderstood what you mean by «determine which directory or folder it's in».

[MrCreatoR]

@MattH

O sorry, i didn't see your second post here, check this function, i wrote it a long time ago, but i changed it a little now so it will return only parent paths (if $iRet = 1)...

expandcollapse popup

#include <Array.au3> ;Only for _ArrayDisplay()

$sPath = @MyDocumentsDir

$Results = _FileFind($sPath, "*.txt", 1, 1)
If @error = 3 Then
    MsgBox(48, "Attention", "No files found.")
Else
    _ArrayDisplay($Results)
EndIf

;Flag = 1 search with recurse
;Flag <> 1 search without recurse
;
;$iRet = 1 return parent directory of the file path
;$iRet <> 1 return full file path


;On Failure set @error as following:
;   1 - $sPath is not a dir or it not exists (in this case returned -1).
;   2 - $sPath is empty dir.
;   3 - No files found in $sPath dir.
;
;On Seccess return array with founded files.
Func _FileFind($sPath, $Mask, $Flag=0, $iRet=0)
    If Not StringInStr(FileGetAttrib($sPath), "D") Then Return SetError(1, 0, -1)
    
    Local $RetPathArr[1], $FindNextFile, $CurrentPath, $SubDirFindArr, $Ubound = 0
    If StringInStr($Mask, "*") Then $Mask = StringReplace($Mask, "*.", "")
    
    $sPath = StringRegExpReplace($sPath, '\\+ *$', '\')
    
    Local $FindFirstFile = FileFindFirstFile($sPath & "\*.*")
    If @error = 1 Then Return SetError(2, 0, 0)
    If $FindFirstFile = -1 Then Return SetError(3, 0, 0)
    
    While 1
        $FindNextFile = FileFindNextFile($FindFirstFile)
        If @error = 1 Then ExitLoop
        $CurrentPath = $sPath & "\" & $FindNextFile
        If $Flag = 1 And StringInStr(FileGetAttrib($CurrentPath), "D") Then
            $SubDirFindArr = _FileFind($CurrentPath, $Mask, $Flag)
            If IsArray($SubDirFindArr) Then
                For $i = 1 To UBound($SubDirFindArr)-1
                    $Ubound = UBound($RetPathArr)
                    ReDim $RetPathArr[$Ubound+1]
                    $RetPathArr[$Ubound] = $SubDirFindArr[$i]
                    If $iRet = 1 Then $RetPathArr[$Ubound] = StringRegExpReplace($RetPathArr[$Ubound], "\\[^\\]*$", "")
                Next
            EndIf
        Else
            If $Mask = "*" Or $FindNextFile = $Mask Or StringRegExpReplace($CurrentPath, '^.*\.', '') = $Mask Then
                $Ubound = UBound($RetPathArr)
                ReDim $RetPathArr[$Ubound+1]
                $RetPathArr[$Ubound] = $CurrentPath
                If $iRet = 1 Then $RetPathArr[$Ubound] = $sPath
            EndIf
        EndIf
    WEnd
    
    FileClose($FindFirstFile)
    
    If $Ubound = 0 Then Return SetError(3, 0, 0)
    $RetPathArr[0] = $Ubound
    Return $RetPathArr
EndFunc

[MattH]

THanks. I'll give that code a try and let you know.

[MattH]

It works great. Thank you so much for your help.