Timers

[MrCreatoR]

Only problem with this is it eliminates the ability to reuse a timer

I am not sure if i understand correct, but in what case we will need to reuse a timer?

[GaryFrost]

I am not sure if i understand correct, but in what case we will need to reuse a timer?

Not sure it's just a functionality of the SetTimer

From MSDN

nIDEvent

[in] Specifies a nonzero timer identifier. If the hWnd parameter is NULL, and the nIDEvent does not match an existing timer then it is ignored and a new timer ID is generated. If the hWnd parameter is not NULL and the window specified by hWnd already has a timer with the value nIDEvent, then the existing timer is replaced by the new timer. When SetTimer replaces a timer, the timer is reset. Therefore, a message will be sent after the current time-out value elapses, but the previously set time-out value is ignored. If the call is not intended to replace an existing timer, nIDEvent should be 0 if the hWnd is NULL

[GaryFrost]

Edit: see 1st post

Edited January 10, 2008 by GaryFrost

[GaryFrost]

Edit: see 1st post

Edited January 10, 2008 by GaryFrost

[GaryFrost]

Updated: see 1st post for examples and include file, callback is handle and ptr is handled in the UDFs.

Just need to make sure the function that the callback is going to use takes 4 variables: "Func FunctionNamePassedToUDF($hWnd, $Msg, $iIDTimer, $dwTime)"

[GaryFrost]

Another Example updating statusbar every second:

expandcollapse popup

#include <WindowsConstants.au3>
#include <GuiConstantsEx.au3>
#include <Timers.au3>
#include <GuiStatusBar.au3>

Global $iMemo, $hStatusBar

_Example_CallBack()

Func _Example_CallBack()
    Local $hGUI, $iTimer1, $iTimer2, $btn_change, $iWait = 3000
    Local $aParts[3] = [75, 150, -1]

    $hGUI = GUICreate("My Timers Using CallBack Function(s)", 400, 320)
    $iMemo = GUICtrlCreateEdit("", 2, 32, 396, 226, BitOR($WS_HSCROLL, $WS_VSCROLL))
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    $btn_change = GUICtrlCreateButton("Change", 155, 275, 90, 20)
    $hStatusBar = _GUICtrlStatusBar_Create($hGUI, $aParts)
    _GUICtrlStatusBar_SetText($hStatusBar, @TAB & @TAB & StringFormat("%02d:%02d:%02d", @HOUR, @MIN, @SEC), 2)
    GUISetState()

    $iTimer1 = _Timer_SetTimer($hGUI, 1000, "_UpdateStatusBarClock") ; create timer
    $iTimer2 = _Timer_SetTimer($hGUI, 3000, "_TimerCallBackFunc2") ; create timer

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $btn_change
                If $iWait = 3000 Then
                    $iWait = 250
                Else
                    $iWait = 3000
                EndIf
                $iTimer2 = _Timer_SetTimer($hGUI, $iWait, "_TimerCallBackFunc2", $iTimer2) ; reuse timer with different interval
        EndSwitch
    WEnd
    ConsoleWrite("Killed Timer? " & _Timer_KillTimer($hGUI, $iTimer1) & @LF)
    ConsoleWrite("Killed Timer? " & _Timer_KillTimer($hGUI, $iTimer2) & @LF)
    GUIDelete()
EndFunc   ;==>_Example_CallBack

Func _UpdateStatusBarClock($hWnd, $Msg, $iIDTimer, $dwTime)
    _GUICtrlStatusBar_SetText($hStatusBar, @TAB & @TAB & StringFormat("%02d:%02d:%02d", @HOUR, @MIN, @SEC), 2)
EndFunc   ;==>_UpdateStatusBarClock

Func _TimerCallBackFunc2($hWnd, $Msg, $iIDTimer, $dwTime)
    MemoWrite("_TimerCallBackFunc2 Timer " & $iIDTimer & " Fired")
EndFunc   ;==>_TimerCallBackFunc2

; Write a line to the memo control
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite

[therks]

Well I guess I don't need to make it anymore.

Any chance this will get official include status?

[GEOSoft]

Well I guess I don't need to make it anymore.

Any chance this will get official include status?

I would suspect that the first thing that will have to happen is a new UDF will have to be created and tested. That process can take a while.

[GaryFrost]

I would suspect that the first thing that will have to happen is a new UDF will have to be created and tested. That process can take a while.

Actually I cleaned up the code, re-did the examples and created a few new examples.

Committed the code.

Should be in the next beta.

[therks]

Awesome sauce! Thanks Gary.

[Thatsgreat2345]

I mean I see the possibilities, but if you have a function with an endless while loop then it will just get stuck in the loop and not execute any of the other timers :-/ I mean I guess you don't need a while loop since it is called every x number of seconds but still.

[GaryFrost]

I mean I see the possibilities, but if you have a function with an endless while loop then it will just get stuck in the loop and not execute any of the other timers :-/ I mean I guess you don't need a while loop since it is called every x number of seconds but still.

That's called poor scripting and can happen easy enough with-out timers.

[Thatsgreat2345]

That's called poor scripting and can happen easy enough with-out timers.

Well I mean I was hoping for a small type of multithreading I guess I was wrong.

[GaryFrost]

Well I mean I was hoping for a small type of multithreading I guess I was wrong.

Well it doesn't matter if you have some other loop other than in the callback function it should work.

For example the main loop doesn't stop the callbacks from happening. WM_TIMER events shouldn't rely on whether you have a loop someplace else.

And you know better than multi-threading, not going to happen in the current version of AutoIt.

[Thatsgreat2345]

Well it doesn't matter if you have some other loop other than in the callback function it should work.

For example the main loop doesn't stop the callbacks from happening. WM_TIMER events shouldn't rely on whether you have a loop someplace else.

And you know better than multi-threading, not going to happen in the current version of AutoIt.

I know but I can always dream

[GaryFrost]

Removed attachment in the 1st post.

The examples I posted will still work with 3.2.11.0 see Timers Management in UDFs

[-Ultima-]

Nice work (as usual), Gary!

Just a minor note regarding the use of _Timer_ArrayDelete()... I think it probably isn't really necessary. For _Timer_KillAllTimers(), you don't really need to delete anything in the array. Simply freeing all the callbacks in the loop, then resizing the entire array outside of the loop is sufficient, like so:

Func _Timer_KillAllTimers($hWnd)
    Local $iResult, $hCallBack = 0
    For $x = 1 To $_Timers_aTimerIDs[0][0]
        If Not IsHWnd($hWnd) Then
            $iResult = DllCall("user32.dll", "int", "KillTimer", "hwnd", $hWnd, "int", $_Timers_aTimerIDs[$x][1])
        Else
            $iResult = DllCall("user32.dll", "int", "KillTimer", "hwnd", $hWnd, "int", $_Timers_aTimerIDs[$x][0])
        EndIf
        If @error Then Return SetError(-1, -1, False)
        $hCallBack = $_Timers_aTimerIDs[$x][2]
        If $hCallBack <> 0 Then DllCallbackFree($hCallBack)
    Next
    Global $_Timers_aTimerIDs[1][3]
    Return $iResult <> 0
EndFunc;==>_Timer_KillAllTimers

As for _Timer_KillTimer(), you can also get rid of the bulk of the _ArrayDelete() code, since you can make assumptions about the array, like this:

Func _Timer_KillTimer($hWnd, $iTimerID)
    Local $iResult, $hCallBack = 0, $iUBound = $_Timers_aTimerIDs[0][0]
    For $x = 1 To $iUBound
        If $_Timers_aTimerIDs[$x][0] = $iTimerID Then
            If Not IsHWnd($hWnd) Then
                $iResult = DllCall("user32.dll", "int", "KillTimer", "hwnd", $hWnd, "int", $_Timers_aTimerIDs[$x][1])
            Else
                $iResult = DllCall("user32.dll", "int", "KillTimer", "hwnd", $hWnd, "int", $_Timers_aTimerIDs[$x][0])
            EndIf
            If @error Then Return SetError(-1, -1, False)
            $hCallBack = $_Timers_aTimerIDs[$x][2]
            If $hCallBack <> 0 Then DllCallbackFree($hCallBack)

            For $i = $x To $iUBound - 1
                $_Timers_aTimerIDs[$i][0] = $_Timers_aTimerIDs[$i + 1][0]
                $_Timers_aTimerIDs[$i][1] = $_Timers_aTimerIDs[$i + 1][1]
                $_Timers_aTimerIDs[$i][2] = $_Timers_aTimerIDs[$i + 1][2]
            Next
            ReDim $_Timers_aTimerIDs[$iUBound][3]

            $_Timers_aTimerIDs[0][0] -= 1
            ExitLoop
        EndIf
    Next
    Return $iResult[0] <> 0
EndFunc;==>_Timer_KillTimer

Granted, the hard-coded nature of that for inner for loop is a bit ugly, but if you want, you can always calculate the subitem count on the first line of the function and use a for loop inside of that inner for loop. The point is that you're using $_Timers_aTimerIDs internally only, so it will be a 2D array with at least one row (that first row containing the item count). Error checking (which is the only thing borrowing the entire _ArrayDelete() function would sorta bring) would be kinda useless anyway, since the snippets throughout the UDFs assuming element [0][0] to be existent or that it is some valid integer might break too (with or without the _ArrayDelete() code checking for errors)

Edit: Uh, I'm still messing with using timers in a script I'm using, but haven't yet fully integrated it, so I can't say for sure whether I did or didn't break anything in these pieces of code. Regardless, the gist of idea is there: having the full _ArrayDelete() code included in the UDF is entirely unnecessary

Edit: Oh, by the way, the description for _Timer_SetTimer() is incorrect... unless it does destroy timers? ;D

Edit: I just noticed that in _Timer_SetTimer(), you're not handling case where a specified $iTimerID <> -1 doesn't exist in the array. In such a case, $iResult is not going to be an array, so obviously, trying to return $iResult[0] is going to cause errors. At the least, $iResult should be declared as a 1-element array at the top of the function, but ideally, if the function doesn't find a matching $iTimerID, it should go ahead and create it for the user.

Edited January 31, 2008 by -Ultima-

[Zepx]

Hi Gary,

You removed your timers.au3 function, will be available for the upcoming release of Autoit? But the latest version is still 3.2.10.0 and not 3.2.11.0 yet.

[MadBoy]

Hi Gary,

You removed your timers.au3 function, will be available for the upcoming release of Autoit? But the latest version is still 3.2.10.0 and not 3.2.11.0 yet.

Get Current beta. It's 3.2.11.0.

Beta Thread at: http://www.autoitscript.com/forum/index.php?showtopic=19717

Beta Download at http://www.autoitscript.com/autoit3/files/beta/autoit/

[Achilles]

Just a question concerning Timers.. What used to happen to Timers after they were done be used? I noticed you added _Timer_KillTimer() but that never was there with old timers. Did they get killed when the script exited? That would seem rather inefficient.