[Solved] TCP with Redirection

[MrCreatoR]

Hi all,

My question is, how can i use TCP, to get full link to file that usualy redirected when we click on the link in the browser?

Here is my example, it work, but not with all urls:

expandcollapse popup

TCPStartup()

Global $HTTPUserAgent   = "Opera/9.25 (Windows NT 5.1; U; ru)"
Global $HTTP_TCP_Port   = 80

$sHost = "www.creator-lab.ucoz.ru"
$sPage = "/load/0-0-1-34-20" ;This should be redirected to this: http://creator-lab.ucoz.ru/AutoIt/GuiCtrlSetOnHover.zip

;Just uncomment these lines, and you will get the full redirected URL to Executable file (Opera browser).
;$sHost = "www.opera.com"
;$sPage = "/download/get.pl?id=30539"

$Response = _HTTPGetResponse($sHost, $sPage)

If StringInStr($Response, "Location:") Then
    $sLocation = StringRegExp($Response, "(?i)Location: (.*)\n", 1)
    ConsoleWrite($sLocation[0])
Else
    ConsoleWrite($Response) ;We get here the Header of www.creator-lab.ucoz.ru :(
EndIf

Func _HTTPConnect($Host)
    Local $Name_To_IP = TCPNameToIP($Host)
    Local $Socket = TCPConnect($Name_To_IP, $HTTP_TCP_Port)
    
    If $Socket = -1 Then
        TCPCloseSocket($Socket)
        Return SetError(1, 0, "")
    EndIf
    
    $LAST_SOCKET = $Socket
    Return $Socket
EndFunc

Func _HTTPGetResponse($Host, $Page)
    Local $Socket = _HTTPConnect($Host)
    If @error Then Return SetError(1, 0, "")
    
    _HTTPHead($Host, $Page, $Socket)
    
    Local $Recv = "", $CurrentRecv
    
    While 1
        $CurrentRecv = TCPRecv($Socket, 16)
        If @error <> 0 Then ExitLoop
        If $CurrentRecv <> "" Then $Recv &= $CurrentRecv
    WEnd
    
    Return $Recv
EndFunc

Func _HTTPHead($Host, $Page, $Socket)
    Local $Command = "HEAD " & $Page & " HTTP/1.1" & @CRLF
    $Command &= "Host: " & $Host & @CRLF
    $Command &= "User-Agent: " & $HTTPUserAgent & @CRLF
    $Command &= "Connection: close" & @CRLF & @CRLF
    
    Local $BytesSent = TCPSend($Socket, $Command)
    If $BytesSent = 0 Then Return SetError(2, @error, 0)
    Return $BytesSent
EndFunc

The redirection work if you just go to this url (http://creator-lab.ucoz.ru/load/0-0-1-34-20) in your browser.

Is there any chance to get it wok correctly?

Edited December 22, 2007 by MsCreatoR

[MrCreatoR]

I got it!!!

expandcollapse popup

TCPStartup()

Global $HTTPUserAgent   = "Opera/9.25 (Windows NT 5.1; U; ru)"
Global $HTTP_TCP_Port   = 80

$sHost = "www.creator-lab.ucoz.ru"
$sPage = "/load/0-0-1-34-20"

$Response = _HTTPGetResponse($sHost, $sPage)

$sLocation = StringRegExp($Response, "(?i)Location: (.*)\n", 1)
ConsoleWrite($sLocation[0])

Func _HTTPConnect($Host)
    Local $Name_To_IP = TCPNameToIP($Host)
    Local $Socket = TCPConnect($Name_To_IP, $HTTP_TCP_Port)
    
    If $Socket = -1 Then
        TCPCloseSocket($Socket)
        Return SetError(1, 0, "")
    EndIf
    
    $LAST_SOCKET = $Socket
    Return $Socket
EndFunc

Func _HTTPGetResponse($Host, $Page)
    Local $Socket = _HTTPConnect($Host)
    If @error Then Return SetError(1, 0, "")
    
    _HTTPGet($Host, $Page, $Socket)
    
    Local $Recv = "", $CurrentRecv
    
    While 1
        $CurrentRecv = TCPRecv($Socket, 16)
        If @error <> 0 Then ExitLoop
        If $CurrentRecv <> "" Then $Recv &= $CurrentRecv
    WEnd
    
    Return $Recv
EndFunc

Func _HTTPGet($Host, $Page, $Socket)
    Local $Command = "GET " & $Page & " HTTP/1.1" & @CRLF
    $Command &= "Host: " & $Host & @CRLF
    $Command &= "User-Agent: " & $HTTPUserAgent & @CRLF
    $Command &= "Connection: close" & @CRLF & @CRLF
    
    Local $BytesSent = TCPSend($Socket, $Command)
    If $BytesSent = 0 Then Return SetError(2, @error, 0)
    Return $BytesSent
EndFunc

I just used GET instead of HEAD and all works