Tell when GUICtrlCreateInput gets focus

[WhatsMyName]

Is there a way to tell when an input control created with GUICtrlCreateInput gets the focus. Either by the user tabbing into it, or clicking it? I want to know which one of a set of input controls the user has selected to enter text into so I can change the state of an option button.

I am using GUIGetMsg to capture other events such as button clicks in the same window, but an input control get focus doesn't seem to generate an event.

Thanks.

[MrCreatoR]

Hi,

Is there a way to tell when an input control created with GUICtrlCreateInput gets the focus.

Check the _GUIInputSetOnlyNumbers() UDF from my signature, there is an example of how to catch the input focus.

[WhatsMyName]

I looked at your example, but I can't figure out what I need to use to tell when a certain input control gets the focus. Can you point me to the right area of your example? Thanks.

[MrCreatoR]

what I need to use to tell when a certain input control gets the focus

I changed this example of WM_NOTIFY usage (by Gary):

expandcollapse popup

#include <GuiConstants.au3>

Global Const $WM_COMMAND = 0x0111
Global Const $EN_CHANGE = 0x300
Global Const $EN_SETFOCUS = 0x100
Global Const $EN_KILLFOCUS = 0x200

GUICreate("Input Changed Demo GUI", 300, 140)

$Input_1 = GUICtrlCreateInput("This is a test, this is only a test", 20, 40, 260, 20)
$Input_2 = GUICtrlCreateInput("This is only a test", 20, 70, 260, 20)

$Exit = GUICtrlCreateButton("Exit", 20, 100, 60, 20)

GUISetState()
GUIRegisterMsg($WM_COMMAND, "MY_WM_COMMAND")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE, $Exit
            ExitLoop
    EndSwitch
WEnd

Func _Input_Changed($ID)
    Printf("Input [" & $ID & "] Changed: " & GUICtrlRead($ID) & @LF)
EndFunc   ;==>_Input_Changed

Func _Input_GotFocus($ID)
    Printf("Input [" & $ID & "] Got Focus" & @LF)
EndFunc   ;==>_Input_GotFocus

Func _Input_LostFocus($ID)
    Printf("Input [" & $ID & "] Lost Focus" & @LF)
EndFunc   ;==>_Input_LostFocus

Func MY_WM_COMMAND($hWnd, $msg, $wParam, $lParam)
    Local $nNotifyCode = BitShift($wParam, 16)
    Local $nID = BitAND($wParam, 0xFFFF)
    Local $hCtrl = $lParam
    
    Switch $nID
        Case $Input_1, $Input_2
            Switch $nNotifyCode
                Case $EN_CHANGE
                    _Input_Changed($nID)
                Case $EN_SETFOCUS
                    _Input_GotFocus($nID)
                Case $EN_KILLFOCUS
                    _Input_LostFocus($nID)
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>MY_WM_COMMAND

Func Printf($Str, $Line=@ScriptLineNumber)
    ConsoleWrite(@LF & "+======================================================" & @LF & _
                "--> Script Line (" & $Line & "):" & @LF & "!" & @TAB & $Str & @LF & _
                "+======================================================")
EndFunc

Just run it from SciTE and look at the console while you type something into the input (or just switch the input's focus).

[WhatsMyName]

Thanks. That should do what I want.

[WhatsMyName]

Cool. It works great. Thanks again.