disable close button

[baldak]

How can I disable the close button ('X') in a window?

[monoceres]

How can I disable the close button ('X') in a window?

I'm not sure you can but you don't have to handle the event that is passed down when the user presses the button, or you could define another style to the window like this: GUICreate("Title",300,300,-1,-1,$WS_POPUPWINDOW)

[smashly]

If your referring to an AutoIt Gui window then there's a couple of ways..

You could use OnEvent mode 1 , then just not add an exit function on Gui Event close.

Or

Use Gui register message to catch the X button being clicked.

Example catching the X button being clicked using GuiRegisterMsg() and not sending the msg onto the Gui..

#include <GUIConstants.au3>

Global Const $WM_NCLBUTTONDOWN = 0xA1

GuiCreate("Catch the X Click", 300, 100)
GUISetState()

GUIRegisterMsg ($WM_NCLBUTTONDOWN, "WM_NCLBUTTONDOWN_FUNC")

While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            Exit
    EndSelect
WEnd
   
Func WM_NCLBUTTONDOWN_FUNC($hWnd, $Msg, $WParam, $LParam)
    $nID = BitAnd($wParam, 0x0000FFFF)
    If $nID = 20 Then
        Return 0
    Else
        Return $GUI_RUNDEFMSG
    EndIf   
EndFunc

If you mean any type of Non-AutoIt window then it's another story...

Cheers

[Zedna]

Be careful! There is no standard way to close application therefore HotKeySet with F1 to close

#include <GUIConstants.au3>

Const $SC_CLOSE = 0xF060
Const $MF_BYCOMMAND = 0x0
Const $MF_GRAYED = 0x1
Const $WM_SYSCOMMAND = 0x0112

HotKeySet("{F1}", "OnF1")

$gui = GuiCreate("Catch the X Click", 300, 100)
GUISetState()

GUIRegisterMsg($WM_SYSCOMMAND, "On_WM_SYSCOMMAND")

$hMenu = DllCall("user32.dll", "hwnd", "GetSystemMenu", "hwnd", $gui, "int", 0)
;~ DllCall("user32.dll","hwnd","DeleteMenu", "hwnd", $hMenu[0], "int",$SC_CLOSE, "int", $MF_BYCOMMAND)
DllCall("user32.dll","hwnd","EnableMenuItem", "hwnd", $hMenu[0], "int",$SC_CLOSE, "int", BitOr($MF_BYCOMMAND,$MF_GRAYED))

While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            Exit
    EndSelect
WEnd

; to disable Alt+F4
Func On_WM_SYSCOMMAND($hWnd, $Msg, $wParam, $lParam)
    If BitAND($wParam, 0xFFF0) = $SC_CLOSE Then Return
EndFunc

Func OnF1()
    Exit
EndFunc

Edited October 24, 2007 by Zedna

[Elzie]

How about

##include <GUIConstants.au3>
#include <WindowsConstants.au3>
Const $SC_CLOSE = 0xF060
HotKeySet("{F1}", "OnF1")

$gui = GUICreate("Click The X ", 269, 48, 2734, 529, -1, BitOR($WS_EX_TOOLWINDOW,$WS_EX_WINDOWEDGE))
$Label1 = GUICtrlCreateLabel("Press F1 to close", 0, 0, 266, 41)
GUICtrlSetFont(-1, 24, 800, 0, "MS Sans Serif")
GUICtrlSetColor(-1, 0x0000FF)
GUISetState(@SW_SHOW)

While 1

WEnd

Func OnF1()
    Exit
EndFunc

[Jos]

Not sure our friend Baldak will see this as he hasn't been onlibe sinds oct 2007.

Jos

[Melba23]

Elzie,

You are beginning >to make a habit of necroing very old threads - please stop it.

M23