Toggle hidden files and folders on and off?

[Diana (Cda)]

Is there a control or command that will allow us to toggle showing or hiding files, as seen in Windows Explorer folder options where we can tick to hide or show hidden files/folders? I found again just references to doing things reglated to GUIs in the help file and got a whole bunch of other things when searching the forum. Thanks.

p.s., my internet has been down since Friday so I'll not be able to read this post and answer again until tomorrow morning when I get back to work. Thanks much!!! <g>

Edited October 2, 2007 by Diana (Cda)

[MrCreatoR]

Hi,

Check this topic.

[Nahuel]

Hi,

Check this topic.

Boo I was making one but took too long I couldn't figure out a way to refresh the explorer windows! haha, thanks for that post!

This is what I came up with:

expandcollapse popup

Func ToggleHiddenFiles($ToggleHidden=1,$ToggleSuperHidden=1,$ToggleFileExt=0)
    $RegKey="HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced"
    $Hidden=RegRead($RegKey,"Hidden")
    $HideFileExt=RegRead($RegKey,"HideFileExt")
    $ShowSuperHidden=RegRead($RegKey,"ShowSuperHidden")

    If $ToggleHidden=1 Then
        If $Hidden=1 Then
            RegWrite($RegKey,"Hidden","REG_DWORD",2);=2 hide,=1 show
        Else
            RegWrite($RegKey,"Hidden","REG_DWORD",1);=2 hide,=1 show
        EndIf
    EndIf
    If $ToggleSuperHidden=1 Then
        If $ShowSuperHidden=1 Then
            RegWrite($RegKey,"ShowSuperHidden","REG_DWORD",0);=0 hide, 1 show
        Else
            RegWrite($RegKey,"ShowSuperHidden","REG_DWORD",1);=0 hide, 1 show
        EndIf
    EndIf
    If $ToggleFileExt=1 Then
        If $HideFileExt=1 Then
            RegWrite($RegKey,"HideFileExt","REG_DWORD",0);=0 show, 1 hide
        Else
            RegWrite($RegKey,"HideFileExt","REG_DWORD",1);=0 show, 1 hide
        EndIf
    EndIf
    ;Get explorer windows:
    Opt("WinTitleMatchMode", 4)
    $WinList = WinList("classname=CabinetWClass")
    If IsArray($WinList) Then
        Local $WinListArr[$WinList[0][0]+1]
        For $iW = 1 To $WinList[0][0]
            $WinListArr[$iW] = $WinList[$iW][0]
        Next
        $WinListArr[0] = $WinList[0][0]
;~         Return $WinListArr
    Else
;~         Return ""
    EndIf
    ;Update explorers:  
    $WinExpListArr =$WinListArr
    If IsArray($WinExpListArr) Then
        For $iWin = 1 To $WinExpListArr[0]
            $GetWinState = WinGetState($WinExpListArr[$iWin])
            $Hwnd = WinGetHandle($WinExpListArr[$iWin])
            DllCall("user32.dll", "long", "SendMessage", "hwnd", $hWnd, "int", 0x111, "int", 28931, "int", 0)
        Next
    EndIf
    
    $Hwnd = WinGetHandle("classname=Progman")
    DllCall("user32.dll", "long", "SendMessage", "hwnd", $hWnd, "int", 0x111, "int", 28931, "int", 0)
    
    
    
    
EndFunc

This is how you use it:

ToggleHiddenFiles([ToggleHidden=1,[ToggleSuperHidden=1,[ToggleHideFileExtensios=0]]])

The three parameters are optional. Leaving them blank will toggle:

• *Hidden files
• *SuperHidden files

For example, let's say you just want to toggle hidden file extensions, then you just use:

ToggleHiddenFiles(0,0,1)

If you just want to toggle hidden system files (superhiddenfiles) then use:

ToggleHiddenFiles(0,1,0)

Thanks MsCreatoR

Edited October 3, 2007 by Nahuel

[GEOSoft]

Nice work Nahuel

Now can you figure out how to show the super-super-super hidden files.

I always run with super-hidden enabled but I have at least 2 files that will not show regardless.

I know they exist because I can Run or ShellExecute them an I looked in the registry to check the paths and they are right where I knew they were.

BTW it would be a good idea to make sure that the values are the same for both before you toggle.

t's no good having The value of Hidden = 0 and then the value of SuperHidden = 1

Edited October 3, 2007 by GEOSoft

[Nahuel]

Nice work Nahuel

Now can you figure out how to show the super-super-super hidden files.

I always run with super-hidden enabled but I have at least 2 files that will not show regardless.

I know they exist because I can Run or ShellExecute them an I looked in the registry to check the paths and they are right where I knew they were.

Well, if you go to folder options, then view and then Hide protected operating system files (Recommended) . You'll see that it modifies the value of ShowSuperHidden in this key:

HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced

However, there's another valuename in that key called SuperHidden. I tried modifying it but it didn't seem to do anything since I don't know where those super-super-hidden files are... maybe you can try that, cos I didn't find anything else...

BTW it would be a good idea to make sure that the values are the same for both before you toggle.

t's no good having The value of Hidden = 0 and then the value of SuperHidden = 1

I thought of that, which is why I gave the function optional parameters. If I added that to the function and your explorer has hidden=0 and SuperHidden=1 then the function wouldn't do anything... So just make sure you are using the right parameters

[GEOSoft]

Maybe this?

If $ToggleSuperHidden=1 Then
        If $ShowSuperHidden=1 Then
            RegWrite($RegKey,"ShowSuperHidden","REG_DWORD",0);=0 hide, 1 show
        Else
            If $Hidden =2 Then 
               RegWrite($RegKey,"Hidden","REG_DWORD",1)
               $Hidden = 1
            EndIf
            RegWrite($RegKey,"ShowSuperHidden","REG_DWORD",1);=0 hide, 1 show
        EndIf
    EndIf

[Nahuel]

Yeah, that seems to work great Didn't think about it.

[priZma]

@Nahuel

Nice Script , but the only way this script works for me you must add a few lines.

;in the Update explorers area:  

Local $ah_WinExpListArr2 = WinList("classname=ExploreWClass")
If $ah_WinExpListArr2[0][0] > 0 Then
    For $i = 1 To $ah_WinExpListArr2[0][0] Step 1
        DllCall("user32.dll", "long", "SendMessage", "hwnd", $ah_WinExpListArr2[$i][1], "int", 0x111, "int", 28931, "int", 0)
    Next
EndIf

Patric

Edited May 16, 2008 by priZma

[metalicaman8]

FileSetAttrib ( "file pattern", "+-RASHNOT" [, recurse] )

Parameters

file pattern File(s) to change, e.g. C:\*.au3, C:\Dir

+-RASHNOT Attribute(s) to set/clear. e.g. "+A", "+RA-SH"

recurse [optional] If this is set to 1, then directories are recursed into. Default is 0 (no recursion).

Return Value

Success: Returns 1.

Failure: Returns 0 if encountered any errors.

Remarks

The file pattern cannot contain spaces!

The attributes that can be modified with the function are + or -:

"R" = READONLY

"A" = ARCHIVE

"S" = SYSTEM

"H" = HIDDEN

"N" = NORMAL

"O" = OFFLINE

"T" = TEMPORARY

(Note that you cannot set the compressed/directory attributes with this function.)

[ShadowPuterDude]

The registry sub keys for HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced are:

Hidden

SuperHidden

ShowSuperHidden

HideFileExt

The default values are 2,0,0,1 respectively. To show everything the values would need to be set to 1,1,1,0 respectively.

A more complete function would be:

expandcollapse popup

Func ToggleHiddenFiles($ToggleHidden=1,$ToggleSuperHidden=1,$ToggleShowSuperHidden=1,$ToggleFileExt=0)
    $RegKey="HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced"
    $Hidden=RegRead($RegKey,"Hidden")
    $SuperHidden=RegRead($RegKey,"SuperHidden")
    $ShowSuperHidden=RegRead($RegKey,"ShowSuperHidden")
    $HideFileExt=RegRead($RegKey,"HideFileExt")

    If $ToggleHidden=1 Then
        If $Hidden=1 Then
            RegWrite($RegKey,"Hidden","REG_DWORD",2);=2 hide,=1 show
        Else
            RegWrite($RegKey,"Hidden","REG_DWORD",1);=2 hide,=1 show
        EndIf
    EndIf
    If $ToggleSuperHidden=1 Then
        If $SuperHidden=1 Then
            RegWrite($RegKey,"SuperHidden","REG_DWORD",0);=0 hide, 1 show
        Else
            RegWrite($RegKey,"SuperHidden","REG_DWORD",1);=0 hide, 1 show
        EndIf
    EndIf
    If $ToggleShowSuperHidden=1 Then
        If $ShowSuperHidden=1 Then
            RegWrite($RegKey,"ShowSuperHidden","REG_DWORD",0);=0 hide, 1 show
        Else
            RegWrite($RegKey,"ShowSuperHidden","REG_DWORD",1);=0 hide, 1 show
        EndIf
    EndIf
    If $ToggleFileExt=1 Then
        If $HideFileExt=1 Then
            RegWrite($RegKey,"HideFileExt","REG_DWORD",0);=0 show, 1 hide
        Else
            RegWrite($RegKey,"HideFileExt","REG_DWORD",1);=0 show, 1 hide
        EndIf
    EndIf
   ;Get explorer windows:
    Opt("WinTitleMatchMode", 4)
    $WinList = WinList("classname=CabinetWClass")
    If IsArray($WinList) Then
        Local $WinListArr[$WinList[0][0]+1]
        For $iW = 1 To $WinList[0][0]
            $WinListArr[$iW] = $WinList[$iW][0]
        Next
        $WinListArr[0] = $WinList[0][0]
;~       Return $WinListArr
    Else
;~       Return ""
    EndIf
   ;Update explorers: 
    $WinExpListArr =$WinListArr
    If IsArray($WinExpListArr) Then
        For $iWin = 1 To $WinExpListArr[0]
            $GetWinState = WinGetState($WinExpListArr[$iWin])
            $Hwnd = WinGetHandle($WinExpListArr[$iWin])
            DllCall("user32.dll", "long", "SendMessage", "hwnd", $hWnd, "int", 0x111, "int", 28931, "int", 0)
        Next
    EndIf
   
    $Hwnd = WinGetHandle("classname=Progman")
    DllCall("user32.dll", "long", "SendMessage", "hwnd", $hWnd, "int", 0x111, "int", 28931, "int", 0)   
EndFunc

Usage:

Toggle Show All:

ToggleHiddenFiles(1,1,1,0)

Toggle Hide All:

ToggleHiddenFiles(2,0,0,1)