Random Numbers and Characters

[onestcoder]

I haven't worked with arrays or randoms much, but what I'm working on is a script that will generate a code 8 digits long with numbers and capital letters. 0-9 and A-Z

Example: A342D2E4

or: BN234J23

I just need a point in the right direction.

[weaponx]

sgBox(0,"", genPassword(8))

Func genPassword($length)
Dim $array[36] = ['A','B','C','D','E','F','G','H','I','J','K','L','M','N','O','P','Q','R','S','T','U','V','W','X','Y','Z','0','1','2','3','4','5','6','7','8','9']

$newPassword = ""
For $X = 1 to $length
    $newPassword &= $array[Random (0, 35, 1)]
Next

return $newPassword

EndFunc

[onestcoder]

O that is GREAT!!!!

Thank you

[weaponx]

An even better version:

MsgBox(0,"", genPassword(8))

Func genPassword($length)
    $array = StringSplit("ABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789","")

    $newPassword = ""
    For $X = 1 to $length
        $newPassword &= $array[Random (1, $array[0], 1)]
    Next

    return $newPassword

EndFunc

[onestcoder]

Yea I like that, Thanks!!! Works Great

[Guest]

An even better version:

MsgBox(0,"", genPassword(8))

Func genPassword($length)
    $array = StringSplit("ABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789","")

    $newPassword = ""
    For $X = 1 to $length
        $newPassword &= $array[Random (1, $array[0], 1)]
    Next

    return $newPassword

EndFunc

An even better better version, I hope

Func genChars($length)
$array = StringSplit("ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz012345678901234567890123456789", "")
$num = Random(200, 1000, 1)
Dim $array2[$num + 1]
For $i = 1 To $num
$array2[$i] = $array[Random(1, $array[0], 1)]
Next

$newPassword = ""
For $X = 1 To $length
$newPassword &= $array2[Random(1, 200, 1)]
Next
Return $newPassword
EndFunc ;==>genChars

[kylomas]

onestcoder,

Yet another way (not sure if any are better than the others, only different)

;
;
;
consolewrite("New Random String = " & _rstr(15) & @lf)
func _rstr($string_length)
 local $str
 for $i = 1 to $string_length
  if random(0,1,1) then
   $str &= chr(random(65,90,1))
  Else
   $str &= chr(random(48,57,1))
  EndIf
 next
 return $str
endfunc

kylomas

[guinness]

What's wrong with what's in the AutoIt Snippets section?

ConsoleWrite(_RandomText() & @CRLF)

Func _RandomText($iLength = 10)
    Local $sData = '', $sRandom
    For $i = 1 To $iLength
        $sRandom = Random(55, 116, 1)
        $sData &= Chr($sRandom + 6 * ($sRandom > 90) - 7 * ($sRandom < 65))
    Next
    Return $sData
EndFunc   ;==>_RandomText

[Spiff59]

An even more betterer version!

MsgBox(0, "", Generate_Code(8))

Func Generate_Code($iLen)
    Local $str
    For $x = 1 to $iLen
        $i = Random(48, 83, 1)
        $str &= Chr($i + ($i > 57) * 7)
    Next
    Return $str
EndFunc

It is at least more fun

[kylomas]

@spiff59,

That is exactly what I was going for but could'nt figure it out. So I would up with a stupid boolean switch to differentiate letter from number.

kylomas

[MvGulik]

... Random generates 4 bytes. Tossing 3 of those out the window seem like a real waist. ...

[JohnQSmith]

You're all a bunch of necrophiliacs. Thread was dead for 5 years until resurrected yesterday.

[FireFox]

You're all a bunch of necrophiliacs. Thread was dead for 5 years until resurrected yesterday.

AND like guinness said, there is a thread for snippets

[JLogan3o13]

You're all a bunch of necrophiliacs.

You know what they say, "Once you go cold, it never gets old"