Networking lags the script

[er453r]

Hi. So I'm using INet functions in my script, but during INet requests the GUI becomes useless. There's no multi-threading in AutoIt, so one possible solution is to start 2 programs (one for GUI, one for the script) sharing information with each other.

Maybe someone knows a better solution?

Big thanks in advance

[PsaltyDS]

  er453r said:

Hi. So I'm using INet functions in my script, but during INet requests the GUI becomes useless. There's no multi-threading in AutoIt, so one possible solution is to start 2 programs (one for GUI, one for the script) sharing information with each other.

Maybe someone knows a better solution?

Big thanks in advance

You just need to use the "background" option of INetGet():

#include <guiconstants.au3>

Opt("GuiOnEventMode", 1)

Global $InetBytes = 0

$hGUI = GUICreate("Test", 300, 200)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Quit")
GUICtrlCreateButton("QUIT", 100, 160, 100, 30)
GUICtrlSetOnEvent(-1, "_Quit")
$Label = GUICtrlCreateLabel("", 10, 10, 280, 20, $SS_CENTER)
GUISetState()

InetGet("http://www.google.com", "C:\Temp\google.html", 1, 1)
$Timer = TimerInit()

While 1
    Sleep(20)
    If @InetGetActive Then
        If @InetGetBytesRead <> $InetBytes Then
            $InetBytes = @InetGetBytesRead
            GUICtrlSetData($Label, "Downloaded: " & $InetBytes & " bytes")
        EndIf
    Else
        If $Timer Then
            $InetBytes = @InetGetBytesRead
            GUICtrlSetData($Label, "Finished: " & $InetBytes & " bytes in " & Round(TimerDiff($Timer) / 1000, 3) & " secs")
            $Timer = 0
        EndIf
    EndIf
WEnd

Func _Quit()
    Exit
EndFunc   ;==>_Quit

[er453r]

Wow. It seems that I just have to read the manual more carefully

Thank you very much