Daily Comics - 5x faster loading!

[uteotw]

Neat script, I remember trying it a while back, and I just gave shot at the updated version but it fails.

I've completly deleted my previous install of AutoIt and I've just installed AutoIt 3.2.10.0 and the latest SciTE.

I ran the your script... Calvin and Hobbes and Dilbert comics got downloaded to @HomeDrive

But then the script failed on line 291

DailyComics.au3 (291) : ==> Subscript used with non-Array variable.:

Return $ImageLink[0]

[Achilles]

Neat script, I remember trying it a while back, and I just gave shot at the updated version but it fails.

I've completly deleted my previous install of AutoIt and I've just installed AutoIt 3.2.10.0 and the latest SciTE.

I ran the your script... Calvin and Hobbes and Dilbert comics got downloaded to @HomeDrive

But then the script failed on line 291

DailyComics.au3 (291) : ==> Subscript used with non-Array variable.:

Return $ImageLink[0]

I got that error when I turned on my computer five minutes ago.

Check the original topic for a slightly improved version that will work.. it doesn't crash, but it can't download that comic... If anyone has a better idea (like why's $ImageLink isn't an array for today) let me know...

[theguy0000]

I got that error when I turned on my computer five minutes ago.

Check the original topic for a slightly improved version that will work.. it doesn't crash, but it can't download that comic... If anyone has a better idea (like why's $ImageLink isn't an array for today) let me know...

for some reason, the comic link is on line 90 today instead of 98...

changing

$sourcelines[98]

to

$sourcelines[90]

seems to fix it, but I'm not sure if it will be like this permanently, or if it's just a random quirk today...

[theguy0000]

If you don't mind, here's a better _GetExplosmLink...mostly the same, but searches lines 80 and on for the link, just be safe, and it starts at 80 just to speed things up.

Func _GetExplosmLink()
    $RSS = "http://feeds.feedburner.com/Explosm"
    $RSSSource = _INetGetSource($RSS)
    $Items = StringRegExp($RSSSource, "(?i)(?s)<item>.*?</item>",3)
    $Count = UBound($Items)
    Dim $Date[$Count], $Link[$Count], $Category[$Count]
    For $i = 0 to $Count-1
    $Dummy = _StringBetween($Items[$i], "<title>", "</title>")
    $Date[$i] = $Dummy[0]
    $Dummy = _StringBetween($Items[$i], "<link>", "</link>")
    $Link[$i] = $Dummy[0]
    $Dummy = _StringBetween($Items[$i], "<category>", "</category>")
    $Category[$i] = $Dummy[0]
    Next
    $Start = 0
    Do
    If Not $Category[$Start]="Comics" then $Start+=1
    Until $Category[$Start]="Comics" or $start >= $Count
    $ItemNum= $Start
    $PageSource = _INetGetSource($Link[$ItemNum])
    $sourcelines = StringSplit($PageSource, @CRLF)
    $urlpos = _ArraySearch ($sourcelines, "Copy this comic into your blog, LiveJournal, Xanga, or MySpace", 80, 0, 1, True)
    If $urlpos = -1 Then
        MsgBox (0, "Daily Comics", "Retrieving Explosm Comic failed - could not find URL.")
        Return False
    EndIf
    $ImageLink = _StringBetween($sourcelines[$urlpos], 'src="', '" border=0')
    Return $ImageLink[0]
EndFunc

[JustinReno]

It all works fine for me, but I needed to change the source code line from 98 to 90.

Heres what showed up when I left the source code line at 98:

[Achilles]

It all works fine for me, but I needed to change the source code line from 98 to 90.

Heres what showed up when I left the source code line at 98:

What to do you mean when you say "change the source code line from 98 to 90. According to what I have line 98 is blank...

EDIT: Guessed on a problem I just fixed I guess you mean 298 and 290. Check the OP, it should be fixed...

Edited December 13, 2007 by Piano_Man

[theguy0000]

My code should account for any changes similar to yesterday's, if it ever happens again... Instead of leaving it at one line, it actually searches for the url.

[Paulie]

I was worried that leaving it searching at line 98 only would cause a problem. I took a shortcut :">. Oh well, theguy0000's script fixes it.

[JustinReno]

@Piano_Man: I meant that when it gets the Explosm comic link, the variable $SourceLink (Or whatever it is) was at $SourceLink[98], I had to change it to $SourceLink[90].

Overall though, you did a good job.

[theguy0000]

Hmm, this morning my udf made it show something like "Download xkcd comic: -936786345792169643%" but no errors were thrown, and the xkcd comic was just blank. But the problem seems to have gone away now...

edit: today's explosm comic = gross

Edited December 14, 2007 by theguy0000

[Achilles]

@Piano_Man: I meant that when it gets the Explosm comic link, the variable $SourceLink (Or whatever it is) was at $SourceLink[98], I had to change it to $SourceLink[90].

Overall though, you did a good job.

Thanks for that... It seems to work with 90 so I'll change it to that... I don't know why it worked with 98 sometimes.

[Achilles]

If you don't mind, here's a better _GetExplosmLink...mostly the same, but searches lines 80 and on for the link, just be safe, and it starts at 80 just to speed things up.

Func _GetExplosmLink()
    $RSS = "http://feeds.feedburner.com/Explosm"
    $RSSSource = _INetGetSource($RSS)
    $Items = StringRegExp($RSSSource, "(?i)(?s)<item>.*?</item>",3)
    $Count = UBound($Items)
    Dim $Date[$Count], $Link[$Count], $Category[$Count]
    For $i = 0 to $Count-1
    $Dummy = _StringBetween($Items[$i], "<title>", "</title>")
    $Date[$i] = $Dummy[0]
    $Dummy = _StringBetween($Items[$i], "<link>", "</link>")
    $Link[$i] = $Dummy[0]
    $Dummy = _StringBetween($Items[$i], "<category>", "</category>")
    $Category[$i] = $Dummy[0]
    Next
    $Start = 0
    Do
    If Not $Category[$Start]="Comics" then $Start+=1
    Until $Category[$Start]="Comics" or $start >= $Count
    $ItemNum= $Start
    $PageSource = _INetGetSource($Link[$ItemNum])
    $sourcelines = StringSplit($PageSource, @CRLF)
    $urlpos = _ArraySearch ($sourcelines, "Copy this comic into your blog, LiveJournal, Xanga, or MySpace", 80, 0, 1, True)
    If $urlpos = -1 Then
        MsgBox (0, "Daily Comics", "Retrieving Explosm Comic failed - could not find URL.")
        Return False
    EndIf
    $ImageLink = _StringBetween($sourcelines[$urlpos], 'src="', '" border=0')
    Return $ImageLink[0]
EndFunc

I just saw this today for some reason... I must not of read a few of the posts here...

I updated the explosm comic with this script so that now it seems to work more consistently...

Thanks again theugy0000!

[Achilles]

Ughh... anybody know why the Explosm link isn't working anymore? It looks like "http://feeds.feedburner.com/Explosm" isn't working likes it's supposed to... Is that the problem?

[Thatsgreat2345]

Nope can't seem to figure that out either. But maybe add Saturday Morning Breakfast Cereal?

http://www.smbc-comics.com/#comic

[Achilles]

Nope can't seem to figure that out either. But maybe add Saturday Morning Breakfast Cereal?

http://www.smbc-comics.com/#comic

That should be easy to do... there's a nice standard naming format for it... @Year & @Month & @Day

Explosm worked today but I had no idea what was wrong with the last few days...

[Thatsgreat2345]

That should be easy to do... there's a nice standard naming format for it... @Year & @Month & @Day

Explosm worked today but I had no idea what was wrong with the last few days...

Don't bother I already added it Just modified the explosm code , you can modify it to use a regular expression if you want but I didn't find the need to.

expandcollapse popup

#cs ----------------------------------------------------------------------------

 AutoIt Version: 3.2.6.0
 Author: Piano_Man
    Helped by...
        Marc - I modified his code for getting Dilbert comics
        i542 + JamesB - They had the Garfield one first
        PaulIA - For his great AutoItLib (it's built into AutoIt now)
        Paulie - Helped me with the Explosm comic
        theguy1000 - Helped me with the xkcd comic and getting the Explosm link
       
 Script Function:
    This script downloads comics from Calvin and Hobbes, Dilbert, Explosm,
    Garfield, and xkcd and shows them in a GUI that has tabs for each cartoon.

#ce ----------------------------------------------------------------------------

#noTrayIcon
#include <GUIConstants.au3>
#Include <GDIPlus.au3>
#include <INet.au3>
#include <Array.au3>
#include <String.au3>

Opt('GUIOnEventMode', 1)
Opt('GUICloseOnESC', 1)

Global $dilbert
Global $SMBC
Global $explosm
Global $xkcd
Global Const $MULT = 100
Global Const $NUM_OF_PICS = 5

$downloadLocation = @HomeDrive & '\'
_DownloadComics()

_GDIPlus_Startup()
$calvinHobbes = _GDIPlus_ImageLoadFromFile($downloadLocation & 'CalvinAndHobbes.gif')

$cWidth = _GDIPlus_ImageGetWidth($calvinHobbes)
$cHeight = _GDIPlus_ImageGetHeight($calvinHobbes)

_GDIPlus_ImageDispose($calvinHobbes)

$dilbertImage = _GDIPlus_ImageLoadFromFile($downloadLocation & $dilbert)

$dWidth = _GDIPlus_ImageGetWidth($dilbertImage)
$dHeight = _GDIPlus_ImageGetHeight($dilbertImage)

_GDIPlus_ImageDispose($dilbertImage)   

$SMBCImage = _GDIPlus_ImageLoadFromFile($downloadLocation & $SMBC)

$sWidth = _GDIPlus_ImageGetWidth($SMBCImage)
$sHeight = _GDIPlus_ImageGetHeight($SMBCImage)

_GDIPlus_ImageDispose($SMBCImage)   

$explosmImage = _GDIPlus_ImageLoadFromFile($downloadLocation & $explosm)

$eWidth = _GDIPlus_ImageGetWidth($explosmImage)
$eHeight = _GDIPlus_ImageGetHeight($explosmImage)

_GDIPlus_ImageDispose($explosmImage)   

$garfield = _GDIPlus_ImageLoadFromFile($downloadLocation & 'Garfield.gif')

$gWidth = _GDIPlus_ImageGetWidth($garfield)
$gHeight = _GDIPlus_ImageGetHeight($garfield)

_GDIPlus_ImageDispose($garfield)

$xkcdImage = _GDIPlus_ImageLoadFromFile($downloadLocation & $xkcd)

$xWidth = _GDIPlus_ImageGetWidth($xkcdImage)
$xHeight = _GDIPlus_ImageGetHeight($xkcdImage)

_GDIPlus_ImageDispose($xkcdImage)

_GDIPlus_Shutdown()
   
If $cHeight > $dHeight then
    $highest = $cHeight
Else
    $highest = $dHeight
EndIf

If $gHeight > $highest then
    $highest = $gHeight
EndIf

If $sHeight > $highest then
    $highest = $sHeight
EndIf

If $eHeight > $highest then
    $highest = $eHeight
EndIf

If $xHeight > $highest then
    $highest = $xHeight
EndIf

If $cWidth > $dWidth then
    $widest = $cWidth
Else
    $widest = $dWidth
EndIf

If $eWidth > $widest then
    $widest = $eWidth
EndIf

If $xWidth > $widest then
    $widest = $xWidth
EndIf

GuiCreate('Daily Comics', $widest + 27, $highest + 69, 100, 100, $WS_SYSMENU, $WS_EX_TOOLWINDOW)
    GuiSetOnEvent($GUI_EVENT_CLOSE, '_Exit')

GuiCtrlCreateTab(5, 3, $widest + 12, $highest + 38)

    GuiCtrlCreateTabItem('Calvin and Hobbes')
   
        GuiCtrlCreatePic($downloadLocation & 'CalvinAndHobbes.gif', 10 + $widest / 2 - $cWidth / 2, 35 + $highest / 2 - $cHeight / 2, $cWidth, $cHeight)
   
    GuiCtrlCreateTabItem('Dilbert')
 
        GuiCtrlCreatePic($downloadLocation & $dilbert, 10 + $widest / 2 - $dWidth / 2, 35 + $highest / 2 - $dHeight / 2, $dWidth, $dHeight)
        
    GuiCtrlCreateTabItem('SMBC')
   
        GuiCtrlCreatePic($downloadLocation & $SMBC, 10 + $widest / 2 - $sWidth / 2, 35 + $highest / 2 - $sHeight / 2, $sWidth, $sHeight)
        
    GuiCtrlCreateTabItem('Explosm')
   
        GuiCtrlCreatePic($downloadLocation & $explosm, 10 + $widest / 2 - $eWidth / 2, 35 + $highest / 2 - $eHeight / 2, $eWidth, $eHeight)

    GuiCtrlCreateTabItem('Garfield')
   
        GuiCtrlCreatePic($downloadLocation & 'Garfield.gif', 10 + $widest / 2 - $gWidth / 2, 35 + $highest / 2 - $gHeight / 2, $gWidth, $gHeight)

    GuiCtrlCreateTabItem('xkcd')
   
        GuiCtrlCreatePic($downloadLocation & $xkcd, 10 + $widest / 2 - $xWidth / 2, 35 + $highest / 2 - $xHeight / 2, $xWidth, $xHeight)
GuiSetState()

While 1
    Sleep(500)
WEnd

Func _DownloadComics()
    ProgressOn('Daily Comics', 'Downloading Images', 'Downloading Calvin and Hobbes comic', -1, -1, 18)
    _CalvinAndHobbes()
    ProgressSet(20, 'Downloading Dilbert comic')
    _Dilbert()
    ProgressSet(30,'Downloading SMBC comic')
    _SMBC()
    ProgressSet(40, 'Downloading Explosm comic')
    _Explosm()
    ProgressSet(60, 'Downloading Garfield comic')
    _Garfield()
    ProgressSet(80, 'Downloading xkcd comic')
    _xkcd()
    ProgressSet(100)
    Sleep(300)
    ProgressOff()
EndFunc

Func _CalvinAndHobbes()
    $TodayComicAddress = 'http://images.ucomics.com/comics/ch/' & @YEAR & '/ch' & StringTrimLeft(@YEAR, 2) & @MON & @MDAY & '.gif'
   
    $cSize = InetGetSize($TodayComicAddress)
    InetGet($TodayComicAddress, $downloadLocation & 'CalvinAndHobbes.gif', 0, 1)
   
    $iTemp = -1
    Do
        $iPCent = Int(@InetGetBytesRead/$cSize * $MULT)
        If $iPCent <> $iTemp Then ProgressSet($iPCent / $NUM_OF_PICS, 'Downloading Calvin and Hobbes comic - ' & $iPCent & '%')
        $iTemp = $iPCent
    Until Not @InetGetActive   
EndFunc

Func _Dilbert()
    $pass = InetGet("http://www.dilbert.com/comics/dilbert/archive/index.html", $downloadLocation & 'temp.dat')

    $file = FileOpen($downloadLocation & 'temp.dat', 0)
   
    $timer = TimerInit()
    While 1
       $line = FileReadLine($file)
       $position = StringInStr($line,"Today's Dilbert Comic")
       If $position <> 0 then ExitLoop
       If TimerDiff($timer) > (1000 * 50) then ExitLoop
    Wend
    FileClose($file)

    $position2 = StringInStr($line,'<IMG SRC="/comics/dilbert/archive/images/')
    $position2 = $position2 + 41

    $datei = StringMid ($line, $position2, ($position-$position2)-16)

    $dilbert = "di" & StringRight(@year,2) & @mon & @mday & StringMid($datei,StringLen($datei)-3,4)

    $dSize = InetGetSize("http://www.dilbert.com/comics/dilbert/archive/images/" & $datei)
    InetGet("http://www.dilbert.com/comics/dilbert/archive/images/" & $datei, $downloadLocation & $dilbert, 0, 1)
   
    $iTemp = -1
    Do
        $iPCent = Int(@InetGetBytesRead/$dSize * $MULT)
        If $iPCent <> $iTemp Then ProgressSet($iPCent / $NUM_OF_PICS + 20, 'Downloading Dilbert comic - ' & $iPCent & '%')
        $iTemp = $iPCent
    Until Not @InetGetActive   
   
    FileDelete($downloadLocation & 'temp.dat')
EndFunc
Func _SMBC()
    $TodayComicAddress = _GetSMBCLink()
    $eSize = InetGetSize($TodayComicAddress)
    $SMBC = _GetFileName($TodayComicAddress)
    InetGet($TodayComicAddress, $downloadLocation & $SMBC, 0, 1)
   
    $iTemp = -1
    Do
        $iPCent = Int(@InetGetBytesRead/$eSize * $MULT)
        If $iPCent <> $iTemp Then ProgressSet($iPCent / $NUM_OF_PICS + 40, 'Downloading Explosm comic - ' & $iPCent & '%')
        $iTemp = $iPCent
    Until Not @InetGetActive   
   
    $SMBC = _ConvertToBMP($downloadLocation & $SMBC)
EndFunc
Func _Explosm()
    $TodayComicAddress = _GetExplosmLink()

    $eSize = InetGetSize($TodayComicAddress)
    $explosm = _GetFileName($TodayComicAddress)
    InetGet($TodayComicAddress, $downloadLocation & $explosm, 0, 1)
   
    $iTemp = -1
    Do
        $iPCent = Int(@InetGetBytesRead/$eSize * $MULT)
        If $iPCent <> $iTemp Then ProgressSet($iPCent / $NUM_OF_PICS + 40, 'Downloading Explosm comic - ' & $iPCent & '%')
        $iTemp = $iPCent
    Until Not @InetGetActive   
   
    $explosm = _ConvertToBMP($downloadLocation & $explosm)
EndFunc

Func _Garfield()
    $TodayComicAddress = "http://images.ucomics.com/comics/ga/" & @YEAR & "/ga" & StringTrimLeft(String(@YEAR), 2) & @MON & @MDAY & ".gif"
   
    $gSize = InetGetSize($TodayComicAddress)
    InetGet($TodayComicAddress, $downloadLocation & 'Garfield.gif', 0, 1)
   
    $iTemp = -1
    Do
        $iPCent = Int(@InetGetBytesRead/$gSize * $MULT)
        If $iPCent <> $iTemp Then ProgressSet($iPCent / $NUM_OF_PICS + 60, 'Downloading Garfield comic - ' & $iPCent & '%')
        $iTemp = $iPCent
    Until Not @InetGetActive   
EndFunc

Func _xkcd()
    $TodayComicAddress = _GetXkcdLink()

    $xSize = InetGetSize($TodayComicAddress)
    $xkcd = _GetFileName($TodayComicAddress)
    InetGet($TodayComicAddress, $downloadLocation & $xkcd, 0, 1)
   
    $iTemp = -1
    Do
        $iPCent = Int(@InetGetBytesRead/$xSize * $MULT)
        If $iPCent <> $iTemp Then ProgressSet($iPCent / $NUM_OF_PICS + 80, 'Downloading xkcd comic - ' & $iPCent & '%')
        $iTemp = $iPCent
    Until Not @InetGetActive   
   
    $xkcd = _ConvertToBMP($downloadLocation & $xkcd)
EndFunc

Func _Exit()
    GuiDelete()
    FileDelete($downloadLocation & 'CalvinAndHobbes.gif')
    FileDelete($downloadLocation & $dilbert)
    FileDelete($downloadLocation & 'Garfield.gif')
    FileDelete($downloadLocation & $explosm)
    FileDelete($downloadLocation & $xkcd)
    Exit   
EndFunc

Func _GetXkcdLink()
    $RSS = "http://www.xkcd.com/rss.xml"
    $RSSSource = _INetGetSource($RSS)
    $Items = StringRegExp($RSSSource, "(?i)(?s)<item>.*?</item>", 3)
    $Count = UBound($Items)
    $Dummy = _StringBetween($Items[0], '<img src="', '"')
    $Link = $Dummy[0]
    Return $Link
EndFunc   ;==>_GetXkcdLink
Func _GetSMBCLink()
    $RSS = "http://www.smbc-comics.com/rss.php"
    $RSSSource = _INetGetSource($RSS)
    $Items = _StringBetween($RSSSource,'CDATA[<img src="','">')
    Return $Items[0]
EndFunc

Func _GetExplosmLink()
    $RSS = "http://feeds.feedburner.com/Explosm"
    $RSSSource = _INetGetSource($RSS)
    $Items = StringRegExp($RSSSource, "(?i)(?s)<item>.*?</item>",3)
    $Count = UBound($Items)
    Dim $Date[$Count], $Link[$Count], $Category[$Count]
    For $i = 0 to $Count-1
    $Dummy = _StringBetween($Items[$i], "<title>", "</title>")
    $Date[$i] = $Dummy[0]
    $Dummy = _StringBetween($Items[$i], "<link>", "</link>")
    $Link[$i] = $Dummy[0]
    $Dummy = _StringBetween($Items[$i], "<category>", "</category>")
    $Category[$i] = $Dummy[0]
    Next
    $Start = 0
    Do
    If Not $Category[$Start]="Comics" then $Start+=1
    Until $Category[$Start]="Comics" or $start >= $Count
    $ItemNum= $Start
    $PageSource = _INetGetSource($Link[$ItemNum])
    $sourcelines = StringSplit($PageSource, @CRLF)
    $urlpos = _ArraySearch ($sourcelines, "Copy this comic into your blog, LiveJournal, Xanga, or MySpace", 80, 0, 1, True)
    If $urlpos = -1 Then
        MsgBox (0, "Daily Comics", "Retrieving Explosm Comic failed - could not find URL.")
        Return False
    EndIf
    $ImageLink = _StringBetween($sourcelines[$urlpos], 'src="', '" border=0')
    Return $ImageLink[0]
EndFunc

Func _GetFileName($string)
    Local $temp = StringSplit($string, '/')
   
    Return $temp[$temp[0]]
EndFunc
   
   
Func _ConvertToBMP($source)
    $split = StringSplit($source, '\')
   
    $imageName = $split[$split[0]]
   
    $temp = StringSplit($imageName, '.')
   
    $imageName = ''
    For $index = 1 to $temp[0] - 1
        $imageName &= $temp[$index]
    Next
   
    _GDIPlus_Startup()
   
    $hImage = _GDIPlus_ImageLoadFromFile($source)
    $sCLSID = _GDIPlus_EncodersGetCLSID('BMP')
    $sTemp  = _Str_ChangeFileExt($source, '.bmp')
   
    _GDIPlus_ImageSaveToFile($hImage, $downloadLocation & '\' & $imageName & '.bmp')

    _GDIPlus_ImageDispose($hImage)
   
    _GDIPlus_Shutdown()
   
    FileDelete($source)
   
    Return $imageName & '.bmp'
EndFunc

Func _Str_ChangeFileExt($sFileName, $sExtension)
  Local $iIndex

  $iIndex = _Str_LastDelimiter(".\:", $sFileName)
  if ($iIndex = 0) or (StringMid($sFileName, $iIndex, 1) <> ".") then $iIndex = StringLen($sFileName) + 1
  Return StringLeft($sFileName, $iIndex - 1) & $sExtension
EndFunc

Func _Str_LastDelimiter($sDelimiters, $sString)
  Local $iI, $iN, $sDelimiter

  for $iI = 1 to StringLen($sDelimiters)
    $sDelimiter = StringMid($sDelimiters, $iI, 1)
    $iN = StringInStr($sString, $sDelimiter, 0, -1)
    if $iN > 0 then Return $iN
  next
EndFunc

Edited January 12, 2008 by Thatsgreat2345

[Achilles]

New Update

Includes Breakfast Cereal

All the comic information is now in an array that makes adding comics easier...

@Thatsgreat2345: I don't really see the need to have a function for getting the link of the Breakfast Cereal one... This works so far:

'http://www.smbc-comics.com/comics/' & @YEAR & @MON & @MDAY & '.gif'

[Thatsgreat2345]

New Update

Includes Breakfast Cereal

All the comic information is now in an array that makes adding comics easier...

@Thatsgreat2345: I don't really see the need to have a function for getting the link of the Breakfast Cereal one... This works so far:

'http://www.smbc-comics.com/comics/' & @YEAR & @MON & @MDAY & '.gif'

Good catch, I checked on just creating the link but I obviously wasn't paying very close attention shows how tired I was at 2 in the morning

[HeffeD]

I guess I'm missing something. Just updated the code from the first post that says it now includes breakfast cereal, but I don't see breakfast cereal anywhere in the script....

Plus, this line:

Global Const $NUM_OF_PICS = 5

Would lead me to believe that there aren't in fact six comics as the post suggests. Is there a download link that I missed?

[Achilles]

I guess I'm missing something. Just updated the code from the first post that says it now includes breakfast cereal, but I don't see breakfast cereal anywhere in the script....

Plus, this line:

Global Const $NUM_OF_PICS = 5

Would lead me to believe that there aren't in fact six comics as the post suggests. Is there a download link that I missed?

Thanks for noticing that... I remember changing but I guess I'm going crazy...

There should be the latest one in the OP now...