Callback - no external library (dll) required

[ValeryVal]

You must to replace that cr & lf to lf, I think.

[ValeryVal]

And after all try this URL

ftp://ftp.kiarchive.ru/pub/0index-r.zip

I have the same error for binary file.

File size of source and dest have different values.

[piccaso]

ok i forgot to set mode for crt...

put that after 'fopen' and it will work (at least for binary files):

$fnOutput = DllCall("msvcrt.dll", "int:cdecl", "_fileno", "ptr", $fpOutput)
$fnOutput = $fnOutput[0]
DllCall("msvcrt.dll","int:cdecl","_setmode","int",$fnOutput,"int",0x8000); Binary/Raw - Input and output is not translated.

Edited August 24, 2007 by piccaso

[ValeryVal]

Yes, at least for binary files difference in file sizes have decreased. It is now just two (2) bytes.

[piccaso]

Last test i made was successful. But i didn't use a ftp client, just a browser (firefox).

Anyway i've changed the libcurl example to use CURLOPT_WRITEDATA as documented and used autoit's internal i/o functions.

So data is downloaded to memory and saved to disk in chunks...

And for the update:

I've replaced the numeric options by constants and added a way to modify the parameters passed to the callback function.

[ValeryVal]

Strange event, but I can't reproduce bug with

ftp://ftp.kiarchive.ru/pub/0index-r.zip.

I've tested libcurl.au3 many times with other ftps.

Yes. Now it works fine.

Thanx.

It's really working tool - callback for AutoIt.

[MrCreatoR]

Subclassing - Subclassing an edit box

It solves the problem here

Is it possible to use CallBack to do some stuff while i am draging the main GUI window? (please see this my bug(?) report).

For example, i would like that the label continue to move while user is draging the main window (or call menus/pressing on List View area etc.).

#include <GUIConstants.au3>
Opt("GuiOnEventMode", 1)

$hWnd = GUICreate("Test")
GUISetOnEvent(-3, "Quit")

$Left = -50
$Label = GUICtrlCreateLabel("Runing Text", $Left, 350, 600)

GUISetState()
AdlibEnable("MoveLabel", 40)

While 1
    Sleep(10)
Wend

Func MoveLabel()
    $Left += 2
    If $Left >= 400 Then $Left = -50
    ControlMove($hWnd, "", $Label, $Left, 350)
EndFunc

Func Quit()
    Exit
EndFunc

Is it possible do it via CallBack? but without using Dlls

[piccaso]

subclassing the main window might be a solution, but this would mean that the callback function gets called for every message.

Which isn't necessary so i'd rather recommend using a timer:

#include <GUIConstants.au3>
#include "DllCallBack.au3"
Opt("GuiOnEventMode", 1)

$hWnd = GUICreate("Test")
GUISetOnEvent(-3, "Quit")

$Left = -50
$Label = GUICtrlCreateLabel("Runing Text", $Left, 350, 600)
GUISetState()

$nTimer = TimerInit()
$pTimerProc = _DllCallBack ("_TimerProc", "hwnd;uint;uint;dword")
$uiTimer = DllCall("user32.dll", "uint", "SetTimer", "hwnd", 0, "uint", 0, "int", 50, "ptr", $pTimerProc)
$uiTimer = $uiTimer[0]

While 1
    Sleep(10)
WEnd

Func _TimerProc($hWnd, $uiMsg, $idEvent, $dwTime)
    MoveLabel()
EndFunc

Func MoveLabel()
    $Left += 1
    If $Left >= 400 Then $Left = -50
    ControlMove($hWnd, "", $Label, $Left, 350)
EndFunc

Func Quit()
    _DllCallBack_Free ($pTimerProc)
    DllCall("user32.dll", "int", "KillTimer", "hwnd", 0, "uint", $uiTimer)
    Exit
EndFunc

[MrCreatoR]

Wow!

Thanks piccaso! it works!!!

Just few questions:

* Why needed $nTimer = TimerInit()? it not used in any place in your example.

* Why it's not working on Close/Minimize/Maximize buttons in the title bar? i mean, if you press on one of these buttons, and hold down the mouse on it, then the text is stops moving, but when you release the mose (not hovering on the button), the text continue to move.

[MrCreatoR]

And one more question:

I have GUI, and i need to call some function when button pressed, that function include many copying processes (FileCopy()) and progress displaying (Gui Progress Bar), and i need that all process in that function, will continue due draging window or all other stuff that stops the script...

This is example of what i mean:

expandcollapse popup

#include <GUIConstants.au3>

Opt("GuiOnEventMode", 1)

Global $iProgrSet = 0
Global $IsAborted = False

$Gui = GUICreate("Test")
GUISetOnEvent(-3, "Quit")

$Menu = GUICtrlCreateMenu("Menu")
GUICtrlCreateMenuItem("Some item", $Menu)

$Progress = GUICtrlCreateProgress(20, 350, 360, 20)
$StartButton = GUICtrlCreateButton("Start", 20, 310, 60, 20)
GUICtrlSetOnEvent(-1, "Start")

GUISetState()

While 1
    Sleep(10)
WEnd

Func Start()
    Opt("GuiOnEventMode", 0)
    AdlibEnable("Abort", 10)
    
    GUICtrlSetData($StartButton, "Abort")
    
    While $IsAborted = False
        $iProgrSet += 10
        If $iProgrSet > 100 Then $iProgrSet = 0
        GUICtrlSetData($Progress, $iProgrSet)
        Sleep(50)
    WEnd
    $iProgrSet = 0
    $IsAborted = False
    
    GUICtrlSetData($StartButton, "Start")
    Opt("GuiOnEventMode", 1)
EndFunc

Func Abort()
    If GUIGetMsg() = $StartButton Then
        AdlibDisable()
        GUICtrlSetData($Progress, 0)
        $IsAborted = True
    EndIf
EndFunc

Func Quit()
    Exit
EndFunc

The same here, if i press the menu, script stops, if i drag the window, script stops, etc.

I have tryed to implement the CallBack functions on this example, but without any seccess , i have no idea what to use when i DllCall...

I will realy appreciate if you can help me on this one.

P.S

Thanks again for the greate methods of CallBack and big respect from me, i know that these methods used in other languages, such as C/C++, Delphi and more, but have them on AutoIt is realy big progress! Thaks!

[RazerM]

piccaso just to say I love all the things you've added. You have great knowledge of win api

[piccaso]

Thanks for the compliments

that '$nTimer = TimerInit()' was a leftover i forgot to remove.

And i cant do anything about that Close/Minimize/Maximize buttons issue.

Thats just how windows is made, while this buttons are hold down the message queue does not process any messages...

expandcollapse popup

#include "DllCallBack.au3"
#include <GUIConstants.au3>

Global $fActive = False, $nStep
Global $Form1 = GUICreate("Timer", 170, 87, 193, 115)
Global $Button1 = GUICtrlCreateButton("Start / Stop", 0, 0, 75, 25, 0)
Global $Progress1 = GUICtrlCreateProgress(8, 40, 150, 16)
Global $MenuItem1 = GUICtrlCreateMenu("MenuItem1")
Global $MenuItem3 = GUICtrlCreateMenuItem("MenuItem3", $MenuItem1)
Global $MenuItem4 = GUICtrlCreateMenuItem("MenuItem4", $MenuItem1)
Global $MenuItem2 = GUICtrlCreateMenu("MenuItem2")
Global $pTimerProc = _DllCallBack ("_TimerProc", "hwnd;uint;uint;dword")
Global $uiTimer = DllCall("user32.dll", "uint", "SetTimer", "hwnd", 0, "uint", 0, "int", 1, "ptr", $pTimerProc)

GUISetState(@SW_SHOW)

While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
     Case $GUI_EVENT_CLOSE
         _Exit()
      Case $Button1
         If Not $fActive Then
            $fActive = True
            $nStep = 0
         Else
            $fActive = False
            GUICtrlSetData($Progress1, 0)
         EndIf
   EndSwitch
WEnd

Func _Worker()
   $nStep += 1
   Switch $nStep
      Case 1
         ; step 1
      Case 2
         ; step 2
      Case 500
         ; step 500 (Last one)
         $nStep = 0
         $fActive = False
   EndSwitch
   GUICtrlSetData($Progress1, $nStep/5)
EndFunc

Func _TimerProc($hWnd, $uiMsg, $idEvent, $dwTime)
    If $fActive Then _Worker()
EndFunc
 
Func _Exit()
   DllCall("user32.dll", "int", "KillTimer", "hwnd", 0, "uint", $uiTimer[0])
   _DllCallBack_Free ($pTimerProc)
   Exit
EndFunc

[MrCreatoR]

i cant do anything about that Close/Minimize/Maximize buttons issue.

It's ok, it's no important - i do not think that user will hold down these buttons a long time

Thanks for the example, but the problem is, that i need to call the function just once, because all copying processes need to be seted in one loop.

Is it possible to call function in that way so while it proceeding the main script will not stops?

[piccaso]

I knew you would ask something like that

If you look at _worker() it is a loop, but not that kind of loop you would like to have...

Anyway the answer is no.

The worker function has to return from time to time or the gui wont be updated.

Ask yourself, is a closed loop really necessary?

I'm sure there is another way

btw. do you use vista? (I saw a screenshot at your site, and it looked like you do).

If yes, did you have any problems with the examples? or did they run fine?

[MrCreatoR]

I knew you would ask something like that

How?

Ask yourself, is a closed loop really necessary?

I'm sure there is another way

Yes there is, but you see, my script is tooo long (more then 4000 lines!!! maybe it's realy to mutch code, and not so smart to program like that, but this is how i started, and for now i realy do not have the time to rewrite all the program ), and the loop is called (inside the function) just after button is pressed, it can not be breaken at the midle, or it can, but only if user press Abort (then all temporary files deleted and the program is "refreshed")...

do you use vista?

Nope, but i want to install, as soon as i fix my second computer, i am gona use it , and i will check the examples - This thread is shows that i have no vista

I saw a screenshot at your site, and it looked like you do

This is a "Vista Transformer Pack" - Just the interface if you ask me .

Thanks again for all you replies and the examples!

[Zedna]

News for version 6:

since v6.4 this udf should work on Win95+ but i can only test it on WinXP and Wine 0.9.x.

If someone of you still runs 9x/Me or even dares to use Vista, Please give the example's a run and post if it worked correctly.

Here are some results on my WIN98 SE:

With version 6.4 there was problems: EnumWindows returned too little windows and script don't stopped automatically, Subclass crashed after start

but new version 6.5 seems to be OK.

Subclass is perfect!!

But some examples don't return expected results:

CopyFileEx.au3 - nothing happens

EnumChildProc.au3 - no result

Richedit.au3 - nothing happens

EDIT: I will make some tests also on WIN XP to compare results later

Edited September 2, 2007 by Zedna

[piccaso]

Thank you Zedna!

CopyFileEx didn't exist before nt

Maybe the desktop window doesn't have any children on Win98...

Not sure about richedit, i just threw together some code snips i found in the forum

but that's not that important as long as the udf works.

[jfisher]

All of the examples are working just fine on my vista.

[Jon]

piccaso, would it be worth adding this natively into AutoIt? I'm not totally sure because it is a very advanced and niche function. So it depends on what I'd need to add and how much space it would need?

Also, I'm guessing it requires some assembly - we've stil not solved the 64bit DllCall problems because of the assembly.

( Awesome work btw )

[Zedna]

piccaso, would it be worth adding this natively into AutoIt? I'm not totally sure because it is a very advanced and niche function. So it depends on what I'd need to add and how much space it would need?

Also, I'm guessing it requires some assembly - we've stil not solved the 64bit DllCall problems because of the assembly.

( Awesome work btw )

Hey Jon this would be FANTASTIC!!!

Sorry for my reaction to question asked to piccaso 

but I can't help myself to express my mind ;-)

Edited September 4, 2007 by Zedna