real-time file name validation

[CyberSlug]

This example warns you if you try to put one of the "forbidden" \ / : * ? " < > | characters in the box

I use message-loop mode, but you could easily adapt for onevent mode.

#include <GUIConstants.au3>

$GUI = GUICreate("Enter a name for a new folder....", 320,120, @DesktopWidth/2-160, @DesktopHeight/2-45, -1, 0x00000018); WS_EX_ACCEPTFILES
$file = GUICtrlCreateInput ( "", 10,  20, 300, 20)
$btn = GUICtrlCreateButton ("Ok", 40,  95, 60, 20)
GuiSetState(@SW_SHOW)

Dim $previousText

While 1
    $msg = GUIGetMsg()
    If $msg = $btn Or $msg = $GUI_EVENT_CLOSE Then Exit
    
    $text = GuiCtrlRead($file)
    If $previousText <> $text Then ToolTip("")
    
    If StringRegExp($text, '\\|/|:|\*|\?|\"|\<|\>|\|') Then
       GuiCtrlSetData($file, StringRegExpReplace($text, '\\|/|:|\*|\?|\"|\<|\>|\|', ""))
       DllCall ("user32.dll", "int", "MessageBeep", "int", 0xFFFFFFFF)  ;Beep
       Local $tooltipPos = WinGetPos($GUI)
       ToolTip("A file name cannot contain any of the following characters:" & @LF & _
                '              \ / : * ? " < > |', $tooltipPos [0]+160, $tooltipPos [1]+60, Default, Default, 3)
       $previousText = GuiCtrlRead($file)
    Endif
Wend

[RazerM]

Good example, nice and short.

[Xenobiologist]

Hi,

nice similar to this : http://www.autoitscript.com/forum/index.ph...c=31641&hl=

So long,

Mega

[big_daddy]

Nice example!

Added to the Snippet Database.