Contextmenu on a Edit Control

[zerobazar]

It works like a charm, but I must admit that I do not fully understand everything involved there...

Would there be a way to achieve the same result by using Auto3Lib? (and that, maybe, would be easier to understand by me?).

Regards.

[MrCreatoR]

Would there be a way to achieve the same result by using Auto3Lib?

Maybe, but what is really matter if it works? DllCallBack will be usefull to you in many other tasks (if you will learn to like/use it ).

[zerobazar]

Fair enough!

I will try to learn!

In fact I was asking about Auto3Lib because I am a bit lost there also! I tried a few test with Auto3Lib to replicate this context menu on an edit control, without success so far. Well I guess that's an other area where I need to learn...

Thanks.

[wraithdu]

Updated version of this (I was looking for something like this a while ago). Granted, there's a more complete example in the helpfile under _WinAPI_CallWindowProc(), but I digress.

expandcollapse popup

#include <GuiConstantsEx.au3>
#include <Constants.au3>
#include <WinAPI.au3>
#include <GuiMenu.au3>

Global Const $WM_CONTEXTMENU = 0x007B

$Gui = GUICreate("Disable Context Menu Demo")

$Edit = GUICtrlCreateEdit("", 20, 20)

$DummyMenu    = GUICtrlCreateDummy()
$ContextMenu    = GUICtrlCreateContextMenu($DummyMenu)
$CommonMenuItem = GUICtrlCreateMenuItem("Common", $ContextMenu)
$FileMenuItem   = GUICtrlCreateMenuItem("File", $ContextMenu)
GUICtrlCreateMenuItem("", $ContextMenu)
$ExitMenuItem   = GUICtrlCreateMenuItem("Exit", $ContextMenu)

GUISetState()

$hProc = DllCallBackRegister("_WindowProc", "int", "hwnd;uint;wparam;lparam")
$OriginalWindowProc = _WinSubclass(GUICtrlGetHandle($Edit), DllCallbackGetPtr($hProc))

While 1
    $Msg = GUIGetMsg()
    Select
        Case $Msg = -3
            GUIDelete()
            DllCallBackFree($hProc)
            Exit
    EndSelect
WEnd

; Show a menu in a given GUI window which belongs to a given GUI ctrl
Func ShowMenu($hWnd, $nContextID)
    _GUICtrlMenu_TrackPopupMenu(GUICtrlGetHandle($nContextID), $hWnd)
EndFunc

Func _WindowProc($hWnd, $uiMsg, $wParam, $lParam)
   ; Disable the context menu and show your own menu
    Switch $uiMsg
        Case $WM_CONTEXTMENU
            ShowMenu($Gui, $ContextMenu)
            Return 0
    EndSwitch
   
    Return _WinAPI_CallWindowProc($OriginalWindowProc, $hWnd, $uiMsg, $wParam, $lParam)
EndFunc

Func _WinSubclass($hWnd, $lpNewWindowProc)
    Return _WinAPI_SetWindowLong($hWnd, $GWL_WNDPROC, $lpNewWindowProc)
EndFunc

[rasim]

wraithdu

Full version

[wraithdu]

Nice

My original need was a custom Desktop / Explorer context menu. But the mouse click trapping was troublesome at best. In the end I went with a hotkey activated menu. However looking at these scripts the last few days, I've learned a lot about the DllCallback, subclassing, and a better mental picture of how a GUI is constructed (all controls are windows). It's been a good learning experience!