USB Drive Backup & FileCopy()

[Eru]

I have a USB drive that I carry around in a little pouch in my wallet with a lot of information I'd hate to lose, namely my homework. I'm trying to make a script that will detect the drive, then copy my homework from it to my documents folder. (I usually do my homework at school and keep the info on the jump drive, but I want it backed up at home just in case.)

I found a nice function that detects the drive but my copying isn't working. I want it to copy my .txt and .doc files to my documents.

Local $FileType[2]
$FileType[0] = "*.txt"
$FileType[1] = "*.doc"
$End = Ubound($FileType) - 1
        FT=0
    For $FT=0 to $End Step 1
           $file = FileFindFirstFile($FileType[$FT])
           Backup()
           $file = FileFindNextFile($FileType[$FT])
           Backup()
        Next
               MsgBox(1, "Done", "All Copied!")

$FileType is an array for the types of files I want to backup. Right now, I'm just working with .txt and .doc files, but if I start having to make spreadsheets in my class, I want to be able to add that functionality easily.

The Backup() function is just a one line function:

FileCopy ($file, "My Documents Path", 1)

Problem is, nothing's copying. I get the "All Copied!" message, but the first part doesn't work.

Possible Problems I've Thought of:

*The FileFindFirstFile and FileFindNextFile don't know what directory I'm looking in and I need to tell it to look in the USB drive. (but how?)

*Syntax error (but where?)

*The $FileType array is set up wrong... (I do need the quotes right?)

*I have a potato for a brain (Very likely.)

Thanks for the input. I'll be back on later to check for replies.

Edited April 1, 2007 by Eru

[martin]

You should read the help for FileFindFirst! You shouldn't post problem code which you haven't even checked yourself. It doesn't return a file as you think in your script but a handle to be used for FileFindNext. FileFindNext uses the handle as a paramater not a file name.

If you have problems with a script then try adding some lines to find out what's wrong. Maybe like this-

MsgBox(0,"$file returned by FileFindFirst is",$file)

Then you would see something was going wrong without needing to ask.

Also, you might need to include the path to your usb drive unless you have already changed directory to it.

For Example

$sr = FileFindFirst('F:\' & Filetype[0])

[MrCreatoR]

Hi, try this one:

#include <Array.au3>

$Extensions = "*.doc|*.txt"
$UsbDrive = "I:"
$DestDir = @MyDocumentsDir

$ReturnedVal = _BackupFiles($Extensions, $UsbDrive, $DestDir, 0) ; If last parameter is 1, then files that exists will be replaced.

If $ReturnedVal = 1 Then MsgBox(64, "Finish!", "All Files was seccesefull copied")
If IsArray($ReturnedVal) Then _ArrayDisplay($ReturnedVal, "These files was not copied:")

Func _BackupFiles($PaternStr, $Drive, $DestBackupDir, $Replace=0)
    If Not FileExists($Drive) Then Return SetError(1, 0, -1)
    Local $ExtArray = StringSplit($PaternStr, "|")
    Local $NotBackupedFilesArr[1], $FileFind, $CurrentFile, $CopyErr
    For $i = 1 To UBound($ExtArray)-1
        $FileFind = FileFindFirstFile($Drive & "\" & $ExtArray[$i])
        While $FileFind <> -1
            $CurrentFile = FileFindNextFile($FileFind)
            If @error Then ExitLoop
            $CopyErr = FileCopy($Drive & "\" & $CurrentFile, $DestBackupDir & "\" & $CurrentFile, $Replace)
            If $CopyErr = 0 Then
                ReDim $NotBackupedFilesArr[UBound($NotBackupedFilesArr)+1]
                $NotBackupedFilesArr[UBound($NotBackupedFilesArr)-1] = $CurrentFile
            EndIf
        WEnd
        FileClose($FileFind)
    Next
    If UBound($NotBackupedFilesArr) > 1 Then Return $NotBackupedFilesArr
    Return 1
EndFunc

Syntax error (but where?)

FT=0 - The variable must start with $

[Doppio]

This script doesn't look for the sub folders on the c: drive. How can I change it so that it looks for the whole drive?