Using a Socks Proxy

[piccaso]

Who sayd "AutoIt doesent support Socks proxy's" ?

expandcollapse popup

TCPStartup()
 
$hc = TCPConnect("192.168.0.100",9050)                  ; Socks4a Proxy Server
 
$sReq = Chr(0x04) _                                     ; Protocol version  4
      & Chr(0x01) _                                     ; Command Code      1 - establish a tcp/ip stream connection
      & Chr(0x00) & Chr(0x50) _                         ; Port              80
      & Chr(0x00) & Chr(0x00) & Chr(0x00) & Chr(0xFF) _ ; Ip Adress         Invalid - 0.0.0.255
      & "" & Chr(0x00) _                                ; User Id           Empty
      & "www.mamma.com" & Chr(0x00)                     ; Host Name         www.mamma.com

; Send Request to Proxy
ConsoleWrite("! Request: " & Hex(BinaryString($sReq)) & @CR)
TCPSend($hc,$sReq)

; Wait for the Reply
While 1
    $sBuff = TCPRecv($hc,1)
    If @error Then Exit @ScriptLineNumber
    If StringLen($sBuff) > 0 Then ExitLoop
    Sleep(100)
WEnd

$sBuff &= TCPRecv($hc,8)
ConsoleWrite("!   Reply: " & Hex(BinaryString($sBuff)) & @CR)

; Check for errors
Switch StringMid(Hex(BinaryString($sBuff)),3,2)
    Case "5A"
        ConsoleWrite("> request granted" & @CR)
    Case "5B"
        ConsoleWrite("> request rejected or failed" & @CR)
        Exit @ScriptLineNumber
    Case "5C"
        ConsoleWrite("> request failed because client is not running identd (or not reachable from the server)" & @CR)
        Exit @ScriptLineNumber
    Case "5D"
        ConsoleWrite("> request failed because client's identd could not confirm the user id string in the request" & @CR)
        Exit @ScriptLineNumber
EndSwitch

; Send Http Request to mamma and Search for "AutoIt"
$sReq  = "GET /Mamma?query=AutoIt HTTP/1.0" & @CRLF & @CRLF
ConsoleWrite("! Request:" & @CR & $sReq & "---------------------------------" & @CR)
TCPSend($hc,$sReq)

; Wait for the Reply
ConsoleWrite("Receiving Data ")
$sRepy = ""
While 1
    $sBuff = TCPRecv($hc,1024*5)
    If @error Then ExitLoop
    If StringLen($sBuff) > 0 Then
        $sRepy &= $sBuff
        ConsoleWrite(".")
    EndIf
    Sleep(100)
WEnd

; Parse Reply
$iHeadEnd = StringInStr($sRepy,@CRLF & @CRLF) + 2
$sRepyHead = StringMid($sRepy,1,$iHeadEnd)
$sRepyBody = StringMid($sRepy,$iHeadEnd)

ConsoleWrite(@CR & "! Reply:" & @CR & $sRepyHead & "---------------------------------" & @CR)

; Save Result to disk
$hFile = FileOpen("socks.htm",2)
FileWrite($hFile,$sRepyBody)
FileClose($hFile)

ConsoleWrite("Reply Body stored in .\socks.htm (" & Round(StringLen($sRepyBody)/1024,2) & "Kb)" & @CR)

[konan]

thank you for your example. But i want know how to use socks5 proxy! Can you have me a example?

[ptrex]

@piccaso

Great stuff man !!

Keep on going.

Btw. I am trying to get the Au3CGI running on an IIS. AuCGI

Did you have a change activating this ?

Regards,

ptrex

[piccaso]

thanks

Would you reformulate your question for me?

I dont understand it...

Good old language barrier

[ptrex]

@piccaso

kein Problem !!

In fact my question does not relate to the Proxy Socks scripts. So I can understand why I need to restart again.

I was thinking since you were able to get a Proxy running through using AU3.

That you my be able to help me get the AuCGI handler running on an IIS server.

CGI handler

It seems that it is running on APACHE and ABYSS, but no one got it running on an IIS ?

Nevertheless IIS supports CGI extentions.

I am breaking my head on this for a long time now, but no success yet.

Maybe you have a different view on the problem and are willing to give it a try.

Thanks in advance

ptrex

[piccaso]

Sorry ptrex, i never touched IIS.

I have been using unixes as server os ever since...

Wikipedia says IIS 6 is integrated in windows xp, but where?

[ptrex]

@piccaso

The IIS on XP Pro is located on c:\inetpub\wwwroot

But only on the Pro edition not on the home edition.

Thanks anyhow

Regards

ptrex

[Armand]

out-dated?

-> BinaryString(), not working...

What is the difference between normal proxies and SOCK proxies ?!

[RyGoTypE]

(13,52) : ERROR: BinaryString(): undefined function.

ConsoleWrite("! Request: " & Hex(BinaryString($sReq)

~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~^

1 error(s), 0 warning(s)

Edited May 6, 2008 by RyGoTypE

[Armand]

This has the above script translated to latest beta, however i still can't get SOCK5...

http://www.autoitscript.com/forum/index.ph...3&hl=armand

[James]

Way to bring up an old topic.

[lionfaggot]

alright, so i get that P is char 80 which is how you specify the port. via chr values. but what i dont get is how on earth would i specify for instance port 6667

[BrewManNH]

You do realize that this topic is over 6 years old right? 

BTW, the 0x0050 is the port number, not the char P, you'd need to convert 6667 to hex and set the port accordingly.

[lionfaggot]

well that makes a lot more sense, also your 6 year old topic here is the only thing anywhere ever that references this topic so of course people are going to bump it. also thanks for that. seems like kind of a coincidence the P converts to 80 though. confused me. alright thanks

[lionfaggot]

also im confused 0x50 = char P converted to string and thus chr(0x50) returns P so im still confuses where you get 0x0050 from i dont think you actually know whats going on here, that or this is fairy unicorn logic but dont take my word for it see for yourself, you arent specifying the value 0x0050 (null P) as the port value youre specifying the Chr value that the binary string converts to. see for yourself

Edited August 14, 2013 by lionfaggot

[BrewManNH]

& Chr(0x00) & Chr(0x50) _                         ; Port              80

It appears that it's taking the character 0x00 (Null), and appending the port number to that (in char form) 0x50 = 80 decimal = port 80 in the code that I'm reading.

[lionfaggot]

0x50 returns P not 80

[BrewManNH]

Hex 50 is 80 decimal, I don't really care what character it returns as it's not relevant.

[lionfaggot]

so its just a coincidence that P happens to be char value 80? i somewhat follow here. maybe im just retarded also the max value is FF which is 255 which still i am still confused as to how i output 6667 if the max range is FF

Edited August 14, 2013 by lionfaggot

[lionfaggot]

i figured it out i think, this is how you do values larger than 255, you just append each digit seperately so for 6667 you do Chr(0x00) & Chr(0x06) & Chr(0x06) & Chr(0x06) & Chr(0x07) - no i was incorrect that isnt working either

Edited August 14, 2013 by lionfaggot