_MouseHover UDF

taurus905 · July 9, 2006

JUST POSTING AN IDEA I GOT FROM TAURUS905.
And no, I hadn't got caps-lock turned on, nor was I pressing shift, I was merely using the script posted below to type this. It's a virtual keyboard, made with my two UDF's, which primarily demonstrates how they can be used to create cursors, but I just really liked it when I finished it. It began with a question I got from taurus905 about transparent buttons, but I continued it so I could post it here.

Note: the window to be typed in must be active before pressing the keyboard!

Anyway, let me know how it works (only the letters, numbers and "~[];',./" work, the rest could be added if people like it):
Alzo

marfdaman,

GOOD JOB. THIS IS GREAT. :wacko:

I will have to take a much closer look at your UDF's and this example program.

But from what I've seen, I would definitely recommend them for inclusion in AutoIt.

Thanks for your time and effort.

taurus905

marfdaman · July 9, 2006

marfdaman,
GOOD JOB. THIS IS GREAT.
I will have to take a much closer look at your UDF's and this example program.
But from what I've seen, I would definitely recommend them for inclusion in AutoIt.
Thanks for your time and effort.
taurus905

Tnx, I'm doing my best!

Paulie · July 10, 2006

Tnx, I'm doing my best!

I can tell!!

marfdaman · July 10, 2006

I'm posting a project I'm working on here as a DECOMPILABLE .exe file. I just really don't feel like creating a zip with all required images.

It shows how I've used my funcs in one of my own programs, and what a great impact they can have on the interaction with the user. The program is not finished yet, but alot is working already.

Shown implementations:

Custom created buttons responding to more than just pressing;
The creation of fully functional hyperlinks;
Various other program area's responding to the mouse.

http://marfdaman.googlepages.com/MobileCommander.exe

Hope this is useful to someone!

Edited July 10, 2006 by marfdaman

SmOke_N · July 10, 2006

Nice... wonder where you got the button idea ... (How the hell do you shut it down? need sleep)

Edit:

I didn't go through the whole thing, mainly was looking why you dind't set a way to exit the exe :wacko: (you did, but you took it off with clientedge), but this stuck out while I was looking.

This:

_HoverAddCtrl($label[1])
_HoverAddCtrl($label[2])
_HoverAddCtrl($label[3])
_HoverAddCtrl($label[4])
_HoverAddCtrl($label[5])
_HoverAddCtrl($label[6])
_HoverAddCtrl($label2[1])
_HoverAddCtrl($label2[2])
_HoverAddCtrl($label2[3])
_HoverAddCtrl($label2[4])
_HoverAddCtrl($label2[5])
_HoverAddCtrl($label2[6])

Could be:

For $iCount = 1 To 6
    _HoverAddCtrl($label[$iCount])
    _HoverAddCtrl($label2[$iCount])
Next

Edited July 10, 2006 by SmOke_N

RazerM · July 10, 2006

I closed it by choosing exit from the drop down list and clicking run function

marfdaman · July 10, 2006

Nice... wonder where you got the button idea ... (How the hell do you shut it down?

Oops, this is because of the the way I shutdown programs. I don't click anything, I simply make a "C" gesture with my mouse to exit. Removed "$WS_POPUP" and you can just click to exit now :">

As for the loop, I made this program some while ago and when I just completed these funcs, it wasn't possible yet to do it that way. Updated that too.

Tnx

RazerM · July 10, 2006

I copied part of Windows Media Player's UI with these functions:

lots of pics

taurus905 · July 10, 2006

http://marfdaman.googlepages.com/MobileCommander.exe
Hope this is useful to someone!

marfdaman,

Thanks for the great mouseover ideas.

I like the potential of your 'Mobile Commander' project.

I'm looking forward to following its development.

taurus905

marfdaman · July 10, 2006

I copied part of Windows Media Player's UI with these functions:

lots of pics

This is very nice indeed

It might be good to know for other people that such slick looking GUI's can be now easily be made with nothing but autoit and pictures:

marfdaman,
Thanks for the great mouseover ideas.
I like the potential of your 'Mobile Commander' project.
I'm looking forward to following its development.
taurus905

Well, I still need to get alot of the standard autoit functions working, then I'll release it. I'll let you know when it's finished

Tnx to all

marfdaman · July 11, 2006

Here is yet another example of the two funcs combined, it shows how you can use them to create custom buttons, checkboxes, tabs and radio-buttons.

Images: http://marfdaman.googlepages.com/example_images.zip

Screenshot:

exscreenshot.bmp

#include <GUIConstants.au3>
#include <_MouseHover.au3>
#include <_PressDetect.au3>

; == GUI generated with Koda ==
$Form1 = GUICreate("_MouseHover and PressDetect Example", 313, 285, -1, -1)
$bkgrnd = GUICtrlCreatePic(@ScriptDir & "\Images\bkgrnd.gif", -10, 21, 335, 265)
GUICtrlSetState(-1, $GUI_DISABLE)
$Label1 = GUICtrlCreateLabel("I'm a trans-label", 24, 16+22, 50, 34)
GUICtrlSetColor(-1, 0xff0000)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
$Label2 = GUICtrlCreateLabel("My website!", 6, 244+22)
GUICtrlSetColor(-1, 0x0000ff)
GUICtrlSetFont(-1, 8, 400, 0, "")
GUICtrlSetCursor(-1, 0)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
$Input1 = GUICtrlCreateInput("AInput1", 88, 16+22, 83, 21, -1, $WS_EX_CLIENTEDGE)
$Button1 = GUICtrlCreatePic(@ScriptDir & "\Images\free1.gif", 24, 102+22, 157, 41)
$Button2 = GUICtrlCreatePic(@ScriptDir & "\Images\images1.gif", 24, 200+22, 227, 41)
$Checkbox1 = GUICtrlCreatePic(@ScriptDir & "\Images\chkbx21.gif", 25, 55+22, 90, 18)
GUICtrlSetCursor(-1, 0)
$chkbxstate = 1
Dim $Radio[4]
Dim $state_radio[4]
$Radio[1] = GUICtrlCreatePic(@ScriptDir & "\Images\ar121.gif", 200, 16+22, 80, 26)
GUICtrlSetCursor(-1, 0)
$state_radio[1] = 1
$Radio[2] = GUICtrlCreatePic(@ScriptDir & "\Images\ar211.gif", 200, 72+22, 80, 26)
GUICtrlSetCursor(-1, 0)
$state_radio[2] = 0
$Radio[3] = GUICtrlCreatePic(@ScriptDir & "\Images\ar311.gif", 200, 128+22, 80, 26)
GUICtrlSetCursor(-1, 0)
$state_radio[3] = 0
$tab1 = GUICtrlCreatePic(@ScriptDir & "\Images\tab13.gif", 0, 0, 71, 21)
$tab2 = GUICtrlCreatePic(@ScriptDir & "\Images\tab21.gif", 71, 0, 71, 21)
$state_tab = 1
GUISetState(@SW_SHOW)

AdlibEnable("_CheckHoverAndPressed", 50)

_HoverAddCtrl($Input1)
_HoverAddCtrl($Button1)
_HoverAddCtrl($Button2)
_HoverAddCtrl($Checkbox1)
For $i = 1 To 3
    _HoverAddCtrl($Radio[$i])
    _PressDetectAddCtrl($Radio[$i])
Next
_HoverAddCtrl($Label1)
_HoverAddCtrl($Label2)
_HoverAddCtrl($tab1)
_HoverAddCtrl($tab2)

_PressDetectAddCtrl($Button1)
_PressDetectAddCtrl($Button2)
_PressDetectAddCtrl($tab1)
_PressDetectAddCtrl($tab2)
_PressDetectAddCtrl($Checkbox1)

While 1
    $msg = GuiGetMsg()
    Select
    Case $msg = $GUI_EVENT_CLOSE
        ExitLoop
    Case $msg = $Label2
        Run(@ComSpec & " /C " & "start http://www.autoitscript.com/forum/index.php?showtopic=28714", "", @SW_HIDE)
    EndSelect
WEnd
Exit


Func _CheckHoverAndPressed()
    $ctrlid = _HoverCheck()
    If IsArray($ctrlid) Then
        If $ctrlid[0] = "AcquiredHover" Then
            _HoverFound($ctrlid[1])
        Else
            _HoverLost($ctrlid[1])
        EndIf
    EndIf
    $ctrlid = _PressDetect()
    If IsArray($ctrlid) Then
        If $ctrlid[0] = "ButtonDePressed" Then
            _CtrlDePressed($ctrlid[1])
        Else
            _CtrlReleased($ctrlid[1])
        EndIf
    EndIf
EndFunc

Func _HoverFound($ControlID)
    For $i = 1 to 3
        If $ControlID = $Radio[$i] Then
            If $state_radio[$i] = 0 Then
                GUICtrlSetImage($ControlID, @ScriptDir & "\Images\ar" & $i & "12.gif")
            Else
                GUICtrlSetImage($ControlID, @ScriptDir & "\Images\ar" & $i & "22.gif")
            EndIf
        EndIf
    Next
    Switch $ControlID
        Case $Input1
            GUICtrlSetData($ControlID, "Hovered over!")
        Case $Button1
            GUICtrlSetImage($ControlID, @ScriptDir & "\Images\free2.gif")
        Case $Button2
            GUICtrlSetImage($ControlID, @ScriptDir & "\Images\images2.gif")
        Case $Checkbox1
            If $chkbxstate = 0 Then
                GUICtrlSetImage($ControlID, @ScriptDir & "\Images\chkbx12.gif")
            Else
                GUICtrlSetImage($ControlID, @ScriptDir & "\Images\chkbx22.gif")
            EndIf
        Case $Label1
            For $i = 255 To 1 Step -8
                WinSetTrans($Form1, '', $i)
            Next
        Case $Label2
            GUICtrlSetFont($ControlID, 8, 400, 4)
        Case $tab1
            If $state_tab = 1 Then
                GUICtrlSetImage($ControlID, @ScriptDir & "\Images\tab13.gif")
            Else
                GUICtrlSetImage($ControlID, @ScriptDir & "\Images\tab12.gif")
            EndIf
        Case $tab2
            If $state_tab = 2 Then
                GUICtrlSetImage($ControlID, @ScriptDir & "\Images\tab23.gif")
            Else
                GUICtrlSetImage($ControlID, @ScriptDir & "\Images\tab22.gif")
            EndIf
    EndSwitch
EndFunc

Func _HoverLost($ControlID)
    For $i = 1 to 3
        If $ControlID = $Radio[$i] Then
            If $state_radio[$i] = 0 Then
                GUICtrlSetImage($ControlID, @ScriptDir & "\Images\ar" & $i & "11.gif")
            Else
                GUICtrlSetImage($ControlID, @ScriptDir & "\Images\ar" & $i & "21.gif")
            EndIf
        EndIf
    Next
    Switch $ControlID
        Case $Input1
            GUICtrlSetData($ControlID, "Not anymore!")
        Case $Button1
            GUICtrlSetImage($ControlID, @ScriptDir & "\Images\free1.gif")
        Case $Button2
            GUICtrlSetImage($ControlID, @ScriptDir & "\Images\images1.gif")
        Case $Label1
            For $i = 1 To 255 Step 8
                WinSetTrans($Form1, '', $i)
            Next
        Case $Label2
            GUICtrlSetFont($ControlID, 8, 400, 0, '')
        Case $tab1
            If $state_tab = 2 Then GUICtrlSetImage($ControlID, @ScriptDir & "\Images\tab11.gif")
        Case $tab2
            If $state_tab = 1 Then GUICtrlSetImage($ControlID, @ScriptDir & "\Images\tab21.gif")
        Case $Checkbox1
            If $chkbxstate = 0 Then
                GUICtrlSetImage($ControlID, @ScriptDir & "\Images\chkbx11.gif")
            Else
                GUICtrlSetImage($ControlID, @ScriptDir & "\Images\chkbx21.gif")
            EndIf
    EndSwitch
EndFunc

Func _CtrlDePressed($ControlID)
    For $i = 1 to 3
        If $ControlID = $Radio[$i] Then
            If $state_radio[$i] = 0 Then
                GUICtrlSetImage($ControlID, @ScriptDir & "\Images\ar" & $i & "13.gif")
            Else
                GUICtrlSetImage($ControlID, @ScriptDir & "\Images\ar" & $i & "23.gif")
            EndIf
        EndIf
    Next
    Switch $ControlID
        Case $Button1
            GUICtrlSetImage($ControlID, @ScriptDir & "\Images\free3.gif")
        Case $Button2
            GUICtrlSetImage($ControlID, @ScriptDir & "\Images\images3.gif")
        Case $tab1
            If $state_tab = 2 Then GUICtrlSetImage($ControlID, @ScriptDir & "\Images\tab13.gif")
        Case $tab2
            If $state_tab = 1 Then GUICtrlSetImage($ControlID, @ScriptDir & "\Images\tab23.gif")
        Case $Checkbox1
            If $chkbxstate = 0 Then
                GUICtrlSetImage($ControlID, @ScriptDir & "\Images\chkbx13.gif")
            Else
                GUICtrlSetImage($ControlID, @ScriptDir & "\Images\chkbx23.gif")
            EndIf
    EndSwitch
EndFunc

Func _CtrlReleased($ControlID)
    For $i = 1 to 3
        If $ControlID = $Radio[$i] Then
            If $state_radio[$i] = 0 Then
                GUICtrlSetImage($ControlID, @ScriptDir & "\Images\ar" & $i & "22.gif")
                For $j = 1 To 3
                    If $state_radio[$j] = 1 Then 
                        $state_radio[$j] = 0
                        GUICtrlSetImage($Radio[$j], @ScriptDir & "\Images\ar" & $j & "11.gif")
                    EndIf
                Next
                $state_radio[$i] = 1
            Else
                GUICtrlSetImage($ControlID, @ScriptDir & "\Images\ar" & $i & "22.gif")
            EndIf
        EndIf
    Next
    Switch $ControlID
        Case $Button1
            GUICtrlSetImage($ControlID, @ScriptDir & "\Images\free2.gif")
        Case $Button2
            GUICtrlSetImage($ControlID, @ScriptDir & "\Images\images2.gif")
        Case $tab1
            If $state_tab = 2 Then
                GUICtrlSetImage($ControlID, @ScriptDir & "\Images\tab13.gif")
                GUICtrlSetImage($tab2, @ScriptDir & "\Images\tab21.gif")
                $state_tab = 1
                GUICtrlSetState($Button1, $GUI_SHOW)
                GUICtrlSetState($Button2, $GUI_SHOW)
                GUICtrlSetState($Checkbox1, $GUI_SHOW)
                GUICtrlSetState($Input1, $GUI_SHOW)
                GUICtrlSetState($Radio[1], $GUI_SHOW)
                GUICtrlSetState($Radio[2], $GUI_SHOW)
                GUICtrlSetState($Radio[3], $GUI_SHOW)
                GUICtrlSetState($Label1, $GUI_SHOW)
                GUICtrlSetState($Label2, $GUI_SHOW)
            EndIf
        Case $tab2
            If $state_tab = 1 Then 
                GUICtrlSetImage($ControlID, @ScriptDir & "\Images\tab23.gif")
                GUICtrlSetImage($tab1, @ScriptDir & "\Images\tab11.gif")
                $state_tab = 2
                GUICtrlSetState($Button1, $GUI_HIDE)
                GUICtrlSetState($Button2, $GUI_HIDE)
                GUICtrlSetState($Checkbox1, $GUI_HIDE)
                GUICtrlSetState($Input1, $GUI_HIDE)
                GUICtrlSetState($Radio[1], $GUI_HIDE)
                GUICtrlSetState($Radio[2], $GUI_HIDE)
                GUICtrlSetState($Radio[3], $GUI_HIDE)
                GUICtrlSetState($Label1, $GUI_HIDE)
                GUICtrlSetState($Label2, $GUI_HIDE)
            EndIf
        Case $Checkbox1
            If $chkbxstate = 0 Then
                GUICtrlSetImage($ControlID, @ScriptDir & "\Images\chkbx22.gif")
                $chkbxstate = 1
            Else
                GUICtrlSetImage($ControlID, @ScriptDir & "\Images\chkbx12.gif")
                $chkbxstate = 0
            EndIf
    EndSwitch
EndFunc

Alzo

Shinies · July 15, 2006

Just stumbled across your UDF here and it looks wonderful.. iv always wanted a way to get rid of the ugly ass buttons windows has.. you have done a really good job with this i think i will use it in my script. good work!

marfdaman · July 16, 2006

Tnx, hope you make something nice with it

Paulie · July 16, 2006

I simply make a "C" gesture with my mouse to exit.
Tnx

what did you do to do that?

marfdaman · July 16, 2006

An extremely nice program called "StrokeIt" (don't mind the name :wacko: ), it's perfect for lazy people like me who don't want to have to use the keyboard or click something. You just hold down a mousebutton of your choice and make for example a "C" to close any program, rather than going to the upperright corner or pressing alt+f4. Check it out, there's really nothing you can't do

Paulie · July 16, 2006

"StrokeIt"

lol what were you searching for when you came across this?

:wacko:

Edit:

its is handy though

Edited July 16, 2006 by Paulie

RazerM · July 17, 2006

I was playing around this then had an idea. I'd also like to note I changed your functions _HoverCheck and _PressDetect to return 1 if hovered or pressed respectively and 0 otherwise, it makes more sense than "AcquiredHover".

;===============================================================================
;
; Program Name:   WMP 11 Buttons
; Description::    Copies Windows media Player's interface using functions from  marfdaman
; Requirement(s):  AutoIt beta
; Author(s):       RazerM
;
;===============================================================================
;
#include <GUIConstants.au3>
#include <_MouseHover.au3>
#include <_PressDetect.au3>

$leftpic = "left_static.bmp"

GUICreate("WMP11 Buttons", 364, 68)
$left = GUICtrlCreatePic($leftpic, 0, 0, 193, 68)
$shuffle = _GUICtrlCreatePicButton("shuffle.bmp", "hshuffle.bmp", "pshuffle.bmp", 193, 0, 37, 69)
$repeat = _GUICtrlCreatePicButton("repeat.bmp", "hrepeat.bmp", "prepeat.bmp", 230, 0, 37, 69)
$stop = _GUICtrlCreatePicButton("stop.bmp", "hstop.bmp", "pstop.bmp", 267, 0, 37, 69)
$prev = _GUICtrlCreatePicButton("prev.bmp", "hprev.bmp", "pprev.bmp", 304, 0, 60, 69)
GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _GUICtrlCreatePicButton($image, $h_image, $p_image, $x, $y, $width, $height)
 $btnID = GUICtrlCreatePic($image, $x, $y, $width, $height)
 _HoverAddCtrl($btnID)
 _PressDetectAddCtrl($btnId)
 EnvSet($btnId&"n", $image)
 EnvSet($btnId&"h", $h_image)
 EnvSet($btnId&"p", $p_image)
 AdlibEnable("_PicButtonCheck", 50)
 Return $btnID
EndFunc

Func _PicButtonCheck()
 $ControlID = _HoverCheck()
    If IsArray($ControlID) Then
        If $ControlID[0] = 1 Then
            GUICtrlSetImage($ControlID[1], EnvGet($ControlID[1]&"h"))
        Else
            GUICtrlSetImage($ControlID[1], EnvGet($ControlID[1]&"n"))
        EndIf
    EndIf
    $ControlID2 = _PressDetect()
    If IsArray($ControlID2) Then
        If $ControlID2[0] = 1 Then
            GUICtrlSetImage($ControlID2[1], EnvGet($ControlID2[1]&"p"))
        Else
            GUICtrlSetImage($ControlID2[1], EnvGet($ControlID2[1]&"n"))
        EndIf
    EndIf
EndFunc

_GUICtrlCreatePicButton is the function that does the work. The pictures:

wmp11.zip

Maybe the AdlibEnable should be outside the function

Edited July 17, 2006 by RazerM

marfdaman · July 18, 2006

I was playing around this then had an idea. I'd also like to note I changed your functions _HoverCheck and _PressDetect to return 1 if hovered or pressed respectively and 0 otherwise, it makes more sense than "AcquiredHover".
_GUICtrlCreatePicButton is the function that does the work. The pictures:

wmp11.zip

Maybe the AdlibEnable should be outside the function

Yep, well done, it makes adding those buttons alot easier!

And yes, 1 and 0 are better choices!

Only drawback as far as I can tell is that it cannot (yet?) be used with things besides buttons.

Tnx!

Edit: adlib should indeed be moved outside the func

YozY · September 20, 2006

hmmm it seems this UDF doesn't work with the new autoit (version 3.2.0.1)

or am i doing something wrong because i used this UDF before and it worked but now it doesn't

Can anyone help?

Thanks

marfdaman · September 20, 2006

Could you tell me what kind of error you're running into? I still use my udf without any problems.

_MouseHover UDF

Recommended Posts

Link to comment

Share on other sites

Top Posters In This Topic

Top Posters In This Topic

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Create an account or sign in to comment

Create an account

Sign in

Recently Browsing 0 members