Close|Exit a "Drive"

[mr-es335]

Good day,

I need to exit a "drives"...for example, "D:" For example...this only works when "Display the full path..." [Folder Options, View] is enabled!
• With that option disabled, the script no longer executes.

; -----------------------------------------------
Opt("MustDeclareVars", 1)
; -----------------------------------------------
ExitFolder()
; -----------------------------------------------
Func ExitFolder()
    Local $sSrcPath = "D:\"
    Local $iFileExists = FileExists($sSrcPath)
    ; -----------------------------------------------
    If $iFileExists Then
        WinClose($sSrcPath)
    EndIf
EndFunc   ;==>ExitFolder
; -----------------------------------------------

The label for the drive is: "Utilities". I have attempted numerous examples form the forum...with no success!!

"Help!!!"

[pixelsearch]

Hello, could you try to add this line to your script ?

Opt("WinTitleMatchMode", -3) ;1=start (default), 2=subStr, 3=exact, 4=advanced, -1 to -4=Nocase

 

[mr-es335]

pixelsearch,

Sorry, none of those various options "worked"!

[mr-es335]

Good day,

Hmmmm...this "worked"...

#include <MsgBoxConstants.au3>
Example()
Func Example()
    Local $sFilePath = "D:\"
    Local $iFileExists = FileExists($sFilePath)
    If WinClose("[CLASS:CabinetWClass]", "") Then
        MsgBox($MB_SYSTEMMODAL, "", "Window closed")
    Else
        MsgBox($MB_SYSTEMMODAL + $MB_ICONERROR, "Error", "Window not Found")
    EndIf
EndFunc   ;==>Example

[pixelsearch]

Just now, mr-es335 said:

Sorry, none of those various options "worked"!

Yes I wasn't sure it will work for you. Let me explain why it worked for me :
I got 2 opened windows whose names start with "C:\" , these windows are :

1) Scite : window name :

C:\Documents and Settings\Administrateur\blablabla - SciTE - blablabla

2) Explorer : window name when opened at C root :

C:\

So when I run your script (with of course $sSrcPath = "C:\") it's like I'm running it using this default line :

Opt("WinTitleMatchMode", 1) ;1=start (default), 2=subStr, 3=exact, 4=advanced, -1 to -4=Nocase

As the default is 1 (start) then... my Scite window closes instead of my Explorer window, because the 1st
window retrieved was unfortunately the Scite window, whose name starts with C:\

But when I run your script with this line :

Opt("WinTitleMatchMode", -3) ;1=start (default), 2=subStr, 3=exact, 4=advanced, -1 to -4=Nocase

Then the correct Explorer window is closed because I asked for an exact match (3 or -3)

So even if the solution I indicated in my preceding post didn't make it in your case, it's good to know what to do in case one day you face the same situation that just happened to me.

Edit: glad to see you made it using CLASS

Edited Tuesday at 03:08 PM by pixelsearch

[ioa747]

2 hours ago, mr-es335 said:

The label for the drive is: "Utilities". I have attempted numerous examples form the forum...with no success!!

to me where the drive D:\  is label 'Data' , the title is Data (D:)

; -----------------------------------------------
Opt("MustDeclareVars", 1)
; -----------------------------------------------
ExitFolderWnd("(D:)")
; -----------------------------------------------
Func ExitFolderWnd($sTitle)
    Local $hWnd = WinGetHandle("[CLASS:CabinetWClass; REGEXPTITLE:(?i)(.*" & $sTitle & ".*)]")
    If WinExists($hWnd) Then Return WinClose($hWnd)
EndFunc   ;==>ExitFolder
; -----------------------------------------------

if Windows Explorer and the  title contains the string '(D:)'

Edited Tuesday at 04:15 PM by ioa747

[mr-es335]

Good day,

Well...this works...

expandcollapse popup

; -----------------------------------------------
Opt("MustDeclareVars", 1)
; -----------------------------------------------
UpdateDtIP()
; -----------------------------------------------
Func UpdateDtIP()
    ExitFolder()
    LaunchFolder()
    LaunchTxt()
EndFunc   ;==>UpdateDtIP
; -----------------------------------------------
Func ExitFolder()
    Local $sFilePath = "D:\"
    Local $iFileExists = FileExists($sFilePath)
    ; -----------------------------------------------
    If $iFileExists Then
        WinClose("[CLASS:CabinetWClass]", "")
    EndIf
EndFunc   ;==>ExitFolder
; -----------------------------------------------
Func LaunchFolder()
    Local $sSrcPath = "D:\Initial_Prep"
    ; -----------------------------------------------
    ShellExecute($sSrcPath)
    Sleep(150)
;~  WinMove($sSrcPath, "", 406, 100, 550, 650)
    WinMove("[CLASS:CabinetWClass]", "", 406, 100, 550, 650)
EndFunc   ;==>LaunchFolder
; -----------------------------------------------
Func LaunchTxt()
    Local $sSrcPath = "D:\Initial_Prep\Procedure_Initial_Prep.txt"
    ; -----------------------------------------------
    ShellExecute($sSrcPath)
    Sleep(150)
    WinMove($sSrcPath, "", 964, 100, 550, 650)
EndFunc   ;==>LaunchTxt
; -----------------------------------------------

 

[Nine]

@ioa747  If you go one level down, D:\ does not show anymore unless you got full path displayed.

To know if you are inside the D:\ drive you need to read the toolbar :

#include <Constants.au3>

Local $hWnd = WinGetHandle("[CLASS:CabinetWClass]")
If Not $hWnd Then Exit MsgBox($MB_OK, "Error", "Unable to find Explorer")

Local $sPath = ControlGetText($hWnd, "", "ToolbarWindow323")
If StringInStr($sPath, "D:\") Then MsgBox($MB_OK, "Info", "You are in D: drive")

 

Edited Tuesday at 04:34 PM by Nine

[ioa747]

7 minutes ago, Nine said:

If you go one level down, D:\ does not show anymore unless you got full path displayed.

I don't have full path displayed enabled.

what is the level below?
(D:) is only displayed at the 1st level

otherwise the window title is displayed
e.g. in D:\Documents the title is Documents
or D:\Documents if full path enabled.

[Nine]

That's what I meant D:\Documents shows Documents (without any reference to D:).  Unless you got full path displayed.

To know if you are on D:\ drive (when not full path) you need to read the toolbar.  No stress here.  Just wanted to make a precision. 

[ioa747]

@mr-es335  The ExitFolder()

Func ExitFolder()
    Local $sFilePath = "D:\"
    Local $iFileExists = FileExists($sFilePath)
    ; -----------------------------------------------
    If $iFileExists Then
        WinClose("[CLASS:CabinetWClass]", "")
    EndIf
EndFunc   ;==>ExitFolder

may not work as you expect
e.g. if instead of the d: window you have any Explorer window open
then that is what will close

 

[ioa747]

 This function works even when not full path displayed
e.g. If the window 'D:\Documents' exists and the title is 'Documents'
ExitFolderWnd("D:\Documents") closes the Documents window

it catches 'D:\Documents' without catching 'D:\Documents\something'

Local $iRet = ExitFolderWnd("D:\")
ConsoleWrite("ExitFolderWnd=" & $iRet & @CRLF)

; -----------------------------------------------
Func ExitFolderWnd($sPath)
    Local $aList = WinList("[CLASS:CabinetWClass]")
    For $i = 1 To $aList[0][0]
        If $aList[$i][0] <> "" And BitAND(WinGetState($aList[$i][1]), 2) Then
            Local $aPart = StringSplit(WinGetText($aList[$i][1]), @LF)
            For $j = 1 To $aPart[0]
                If StringLeft($aPart[$j], 9) = "Address: " Then
                    Local $sAddress = StringTrimLeft($aPart[$j], 9)
                    ConsoleWrite("$sAddress=" & $sAddress & @CRLF)
                    If $sAddress = $sPath Then Return WinClose($aList[$i][1])
                EndIf
            Next
        EndIf
    Next
    Return 0
EndFunc   ;==>ExitFolderWnd
; -----------------------------------------------