Transparent Clock With Opaque Buttons

[NassauSky]

Hi all,

First I want to thank @UEZ for the below demo code to create a clock in an old topic which has a nice transparent background for the GUI and the BG of the label.
How can I add an opaque button and keep the GUI and Time background transparent.  Actually it's extra points if I can set the transparency of the button while keeping it clickable.

For example:
 

Global $hButton = GUICtrlCreateButton("Test", $iW - 30, 10, 30, 20) 
GUICtrlSetBkColor($hButton, 0x000000) ; Set opaque background color
GUICtrlSetColor($hButton, 0x00FF00) ; Set text color

When I add it, it doesn't show up.
 

expandcollapse popup

#include <WinAPISysWin.au3>
#include <WinAPIConstants.au3>
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global Const $SC_DRAGMOVE = 0xF012
Global $iW = 300, $iH = 100, $hHBitmap
Global $hGUI = GUICreate("Parent", $iW, $iH, -1, -1, $WS_POPUP, BitOR($WS_EX_LAYERED, $WS_EX_TOPMOST))
GUISetState(@SW_SHOW, $hGUI)

_GDIPlus_Startup()

Global $hBrush = _GDIPlus_BrushCreateSolid(0xD80000A0)
Global $hFormat = _GDIPlus_StringFormatCreate()
Global $hFamily = _GDIPlus_FontFamilyCreate("Impact")
Global $hFont = _GDIPlus_FontCreate($hFamily, 60)
Global $tLayout = _GDIPlus_RectFCreate(0, 0, $iW, $iH)
_GDIPlus_StringFormatSetAlign($hFormat, 0)
Global $hImage = _GDIPlus_BitmapCreateFromScan0($iW, $iH)
Global $hGfx = _GDIPlus_ImageGetGraphicsContext($hImage)
_GDIPlus_GraphicsSetTextRenderingHint($hGfx, 4)
_GDIPlus_GraphicsSetSmoothingMode($hGfx, 4)

GUIRegisterMsg($WM_LBUTTONDOWN, "_WM_LBUTTONDOWN")

_ShowTime()
AdlibRegister("_ShowTime", 1000)

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

AdlibUnRegister("_ShowTime")
_WinAPI_DeleteObject($hHBitmap)
_GDIPlus_FontDispose($hFont)
_GDIPlus_FontFamilyDispose($hFamily)
_GDIPlus_StringFormatDispose($hFormat)
_GDIPlus_BrushDispose($hBrush)
_GDIPlus_GraphicsDispose($hGfx)
_GDIPlus_ImageDispose($hImage)
_GDIPlus_Shutdown()
GUIDelete()


Func _ShowTime()
    _GDIPlus_GraphicsClear($hGfx, 0x00000000)
    _GDIPlus_GraphicsDrawStringEx($hGfx, @HOUR & ":" & @MIN & ":" & @SEC, $hFont, $tLayout, $hFormat, $hBrush)
    $hHBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImage)
    _WinAPI_BitmapDisplayTransparentInGUI($hHBitmap, $hGUI)
    _WinAPI_DeleteObject($hHBitmap)
EndFunc

Func _WinAPI_BitmapDisplayTransparentInGUI(ByRef $hHBitmap, ByRef $hGUI, $iOpacity = 0xFF, $bReleaseGDI = True)
    If Not BitAND(GUIGetStyle($hGUI)[1], $WS_EX_LAYERED) = $WS_EX_LAYERED Then Return SetError(1, 0, 0)
    Local $tDim = DllStructCreate($tagBITMAP)
    If Not _WinAPI_GetObject($hHBitmap, DllStructGetSize($tDim), DllStructGetPtr($tDim)) Then Return SetError(2, 0, 0)
    Local $tSize = DllStructCreate($tagSIZE), $tSource = DllStructCreate($tagPOINT), $tBlend = DllStructCreate($tagBLENDFUNCTION)
    Local Const $hScrDC = _WinAPI_GetDC(0), $hMemDC = _WinAPI_CreateCompatibleDC($hScrDC), $hOld = _WinAPI_SelectObject($hMemDC, $hHBitmap)
    $tSize.X = $tDim.bmWidth
    $tSize.Y = $tDim.bmHeight
    $tBlend.Alpha = $iOpacity
    $tBlend.Format = 1
    _WinAPI_UpdateLayeredWindow($hGUI, $hScrDC, 0, DllStructGetPtr($tSize), $hMemDC, DllStructGetPtr($tSource), 0, DllStructGetPtr($tBlend), $ULW_ALPHA)
    _WinAPI_ReleaseDC(0, $hScrDC)
    _WinAPI_SelectObject($hMemDC, $hOld)
    _WinAPI_DeleteDC($hMemDC)
    If $bReleaseGDI Then _WinAPI_DeleteObject($hHBitmap)
    Return True
EndFunc

Func _WM_LBUTTONDOWN($hWnd, $iMsg, $wParam, $lParam)
    Switch $hWnd
        Case $hGUI
            _SendMessage($hWnd, $WM_SYSCOMMAND, $SC_DRAGMOVE, 0)
    EndSwitch
EndFunc   ;==>_WM_LBUTTONDOWN

Func WM_NCHITTEST($hWnd, $iMsg, $iwParam, $ilParam)
    If ($iMsg = $WM_NCHITTEST) Then Return $HTCAPTION
EndFunc

 

 

Edited March 21 by NassauSky

[UEZ]

Use child GUI:

...
Global Const $SC_DRAGMOVE = 0xF012
Global $iW = 300, $iH = 100, $hHBitmap
Global $hGUI = GUICreate("Parent", $iW, $iH, -1, -1, $WS_POPUP, BitOR($WS_EX_LAYERED, $WS_EX_TOPMOST)), _
        $hGUI_Child = GUICreate("", 30, 20, 0, 0, $WS_POPUP, BitOR($WS_EX_LAYERED, $WS_EX_MDICHILD), $hGUI)
Global $hButton = GUICtrlCreateButton("Test", 0, 0, 30, 20)
GUICtrlSetBkColor($hButton, 0x000000)
GUICtrlSetColor($hButton, 0x00FF00)
GUISetBkColor(0x123456, $hGUI_Child)
_WinAPI_SetLayeredWindowAttributes($hGUI_Child, 0x123456)
GUISetState(@SW_SHOW, $hGUI_Child)
GUISetState(@SW_SHOW, $hGUI)
...

 

[Nine]

Another way to skin the cat :

#include <WinAPISysWin.au3>
#include <GUIConstants.au3>

Global $hGUI = GUICreate("Parent", 350, 300, -1, -1, $WS_POPUP, BitOR($WS_EX_LAYERED, $WS_EX_TOPMOST, $WS_EX_COMPOSITED))
GUISetBkColor(0xC0FFEE)
Global $idTime = GUICtrlCreateLabel("", 0, 0, 350, 100, $SS_CENTER + $SS_CENTERIMAGE, $GUI_WS_EX_PARENTDRAG)
GUICtrlSetColor(-1, 0xA0)
GUICtrlSetFont(-1, 60, 800)
GUISetState()
_WinAPI_SetLayeredWindowAttributes($hGUI, 0xC0FFEE)

Global $hGUI2 = GUICreate("Child", 100, 30, 125, 100, $WS_POPUP, $WS_EX_MDICHILD, $hGUI)
Global $idButton = GUICtrlCreateButton("Test", 0, 0, 100, 30)
WinSetTrans($hGUI2, "", 120)
GUISetState()

ShowTime()
AdlibRegister(ShowTime, 1000)

While True
  Switch GUIGetMsg()
    Case $GUI_EVENT_CLOSE
      ExitLoop
    Case $idButton
      ConsoleWrite("button was pressed" & @CRLF)
  EndSwitch
WEnd

Func ShowTime()
  GUICtrlSetData($idTime, @HOUR & ":" & @MIN & ":" & @SEC)
EndFunc   ;==>_ShowTime

And make the button partially transparent...

Edited March 21 by Nine

[NassauSky]

That poor cat has no more skin left  🤣

Thanks @UEZ and @Nine !

Now I have 2 solutions that are looking real good.  Though @UEZ had what I thought I was looking for but at first glance I think you get some extra points @Nine since my clock might use that transparent button.

But we won't count your chickens before they hatch.

[UEZ]

Skinning the cat makes it ugly. 😉 

_WinAPI_SetLayeredWindowAttributes($hGUI_Child, 0x123456, 0x60)

makes the child GUI transparent, too.