I try to run _GUICtrlComboBox_AutoComplete example, but error opening the file <Extras\WM_NOTIFY.au3>

[HezzelQuartz]

I try to run _GUICtrlComboBox_AutoComplete example, but error opening the file <Extras\WM_NOTIFY.au3>

It seems that there is no WM_NOTIFY.au3 file exist in my Extras folder

How can I get WM_NOTIFY.au3?

What mistake I do?

Thank You

[SOLVE-SMART]

Hi @HezzelQuartz,

I guess the documentation (help file) is out-of-date. I also don't have a ...\Extras\WM_NOTIFY.au3 file. In the ...\Include folder is also no "_WM_NOTIFY_DebugInfo" function which is probably a custom one.

Simply get rid of the include and the usage of "_WM_NOTIFY_DebugInfo" and use a MsgBox (or maybe better ConsoleWrite) instead.
The example with MsgBox would look like this:

expandcollapse popup

#AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7
#AutoIt3Wrapper_AU3Check_Stop_OnWarning=y

#include-once
#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idCombo

Example()

Func Example()
    ; Create GUI
    GUICreate("ComboBox Auto Complete (v" & @AutoItVersion & ")", 400, 296)
    $g_idCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Add files
    _GUICtrlComboBox_BeginUpdate($g_idCombo)
    _GUICtrlComboBox_AddDir($g_idCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($g_idCombo)

    GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

Func _Edit_Changed()
    _GUICtrlComboBox_AutoComplete($g_idCombo)
EndFunc   ;==>_Edit_Changed

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg
    Local $hWndCombo = $g_idCombo
    If Not IsHWnd($g_idCombo) Then $hWndCombo = GUICtrlGetHandle($g_idCombo)
    Local $hWndFrom = $lParam
    Local $iIDFrom = BitAND($wParam, 0xFFFF)         ; Low Word
    Local $iCode = BitShift($wParam, 16)         ; Hi Word
    Switch $hWndFrom
        Case $g_idCombo, $hWndCombo
            Switch $iCode
                Case $CBN_CLOSEUP ; Sent when the list box of a combo box has been closed
                    MsgBox('', '$CBN_CLOSEUP', 'hWndFrom,IDFrom' & @CRLF & $hWndFrom & @CRLF & $iIDFrom)
                    ; no return value
                Case $CBN_DBLCLK ; Sent when the user double-clicks a string in the list box of a combo box
                    MsgBox('', '$CBN_DBLCLK', 'hWndFrom,IDFrom' & @CRLF & $hWndFrom & @CRLF & $iIDFrom)
                    ; no return value
                Case $CBN_DROPDOWN ; Sent when the list box of a combo box is about to be made visible
                    MsgBox('', '$CBN_DROPDOWN', 'hWndFrom,IDFrom' & @CRLF & $hWndFrom & @CRLF & $iIDFrom)
                    ; no return value
                Case $CBN_EDITCHANGE ; Sent after the user has taken an action that may have altered the text in the edit control portion of a combo box
                    MsgBox('', '$CBN_EDITCHANGE', 'hWndFrom,IDFrom' & @CRLF & $hWndFrom & @CRLF & $iIDFrom)
                    _Edit_Changed()
                    ; no return value
                Case $CBN_EDITUPDATE ; Sent when the edit control portion of a combo box is about to display altered text
                    MsgBox('', '$CBN_EDITUPDATE', 'hWndFrom,IDFrom' & @CRLF & $hWndFrom & @CRLF & $iIDFrom)
                    ; no return value
                Case $CBN_ERRSPACE ; Sent when a combo box cannot allocate enough memory to meet a specific request
                    MsgBox('', '$CBN_ERRSPACE', 'hWndFrom,IDFrom' & @CRLF & $hWndFrom & @CRLF & $iIDFrom)
                    ; no return value
                Case $CBN_KILLFOCUS ; Sent when a combo box loses the keyboard focus
                    MsgBox('', '$CBN_KILLFOCUS', 'hWndFrom,IDFrom' & @CRLF & $hWndFrom & @CRLF & $iIDFrom)
                    ; no return value
                Case $CBN_SELCHANGE ; Sent when the user changes the current selection in the list box of a combo box
                    MsgBox('', '$CBN_SELCHANGE', 'hWndFrom,IDFrom' & @CRLF & $hWndFrom & @CRLF & $iIDFrom)
                    ; no return value
                Case $CBN_SELENDCANCEL ; Sent when the user selects an item, but then selects another control or closes the dialog box
                    MsgBox('', '$CBN_SELENDCANCEL', 'hWndFrom,IDFrom' & @CRLF & $hWndFrom & @CRLF & $iIDFrom)
                    ; no return value
                Case $CBN_SELENDOK ; Sent when the user selects a list item, or selects an item and then closes the list
                    MsgBox('', '$CBN_SELENDOK', 'hWndFrom,IDFrom' & @CRLF & $hWndFrom & @CRLF & $iIDFrom)
                    ; no return value
                Case $CBN_SETFOCUS ; Sent when a combo box receives the keyboard focus
                    MsgBox('', '$CBN_SETFOCUS', 'hWndFrom,IDFrom' & @CRLF & $hWndFrom & @CRLF & $iIDFrom)
                    ; no return value
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

Try ConsoleWrite() too.

Best regards
Sven

[water]

The subject has been discussed here.
A ticket has been created as well.

[Nine]

See other topic, I have put an example of what the winproc should/could be...

Edited 2 hours ago by Nine

[argumentum]

7 hours ago, HezzelQuartz said:

It seems that there is no WM_NOTIFY.au3 file exist in my Extras folder

What version of AutoIt are you using and where did you get the example from ?
Because I don't see a way for the examples not working from its help file.

On the other hand, I do find prior version examples much friendlier to copy and paste to my script.

[Nine]

There is a number of Extras folders.  Make sure you are looking in the right directory...