How to do StringRegExpReplace or StringReplace Incrementally?

[HezzelQuartz]

If I have a txt file containing text below

X0  00112233
X1  AABBCCDD
X2  22446688
X3  BBDDFF00
X4  11335577
X5  AACCEEFF
X6  11AA22BB
X7  CC33DD44
X8  55EE66FF
X9  ABCD9988
X10 8800AADD
X11 EEFF3344
X12 6622AAEE
X13 5599CCFF
X14 AAFF2200
X15 0099AACC

Then, I want to change it to be below

X0  00112033
X1  AABBC1DD
X2  22446288
X3  BBDDF300
X4  11335477
X5  AACCE5FF
X6  11AA26BB
X7  CC33D744
X8  55EE68FF
X9  ABCD9988
X10 8800AADD
X11 EEFF3B44
X12 6622ACEE
X13 5599CDFF
X14 AAFF2E00
X15 0099AFCC

So I want to change the third hex character from right incrementally like these:

1st line: 0

2nd Line: 1

15th line: F

16th line: 0 (back to 0)

How can I do that?

I try to create script like this:

$text = FileRead(@ScriptDir & "\" & "example.txt")
$hex = StringRegExpReplace($text, 'X\d+\h[[:xdigit:]]{5}\K([[:xdigit:]]{1})', 'F')
FileWrite($locscript & "newexample.txt", $hex)

I just confused what to do to change the replaced string in every line

Thank You

Sorry for bad explanation

[ioa747]

old school without regexp

#include <Array.au3>

Local $text = FileRead(@ScriptDir & "\example.txt")
Local $aList = StringSplit($text, @CRLF, 1)
;~ _ArrayDisplay($aList)
Local $Newtext
Local $idx = 16
For $i = 1 To $aList[0]

    ConsoleWrite($i & ") " & $aList[$i] & " -> ")

    Local $front = StringTrimRight($aList[$i], 3)
    Local $back = Hex($idx, 1) & StringRight($aList[$i], 2)

    ConsoleWrite($front & $back & @CRLF)

    $Newtext &= $front & $back & @CRLF
    $idx += 1
    If $idx = 17 Then $idx = 1
Next

$Newtext = StringTrimRight($Newtext, 2)

$newexample = @ScriptDir & "\newexample.txt"
If FileExists($newexample) Then FileDelete($newexample)
FileWrite($newexample, $Newtext)

 

Edited yesterday at 07:02 AM by ioa747
correction

[jchd]

Regex school:

Local $text = FileRead(@ScriptDir & "\" & "source.txt")
Local $hex = Execute('"' & StringRegExpReplace($text, '(?m)(?<=[[:xdigit:]]{5})([[:xdigit:]])(?=[[:xdigit:]]{2})', '" & _IncHex() & "') & '"')
ConsoleWrite($hex)

Func _IncHex()
    Local Static $Inc = 15
    $Inc += 1
    Return Hex(Mod($Inc, 16), 1)
EndFunc

I added two extra line in the source file, yielding:
 

X0  00112033
X1  AABBC1DD
X2  22446288
X3  BBDDF300
X4  11335477
X5  AACCE5FF
X6  11AA26BB
X7  CC33D744
X8  55EE68FF
X9  ABCD9988
X10 8800AADD
X11 EEFF3B44
X12 6622ACEE
X13 5599CDFF
X14 AAFF2E00
X15 0099AFCC
X16 FD5A00B6
X17 10E51194

 

[HezzelQuartz]

4 hours ago, ioa747 said:

old school without regexp

#include <Array.au3>

Local $text = FileRead(@ScriptDir & "\example.txt")
Local $aList = StringSplit($text, @CRLF, 1)
;~ _ArrayDisplay($aList)
Local $Newtext
Local $idx = 16
For $i = 1 To $aList[0]

    ConsoleWrite($i & ") " & $aList[$i] & " -> ")

    Local $front = StringTrimRight($aList[$i], 3)
    Local $back = Hex($idx, 1) & StringRight($aList[$i], 2)

    ConsoleWrite($front & $back & @CRLF)

    $Newtext &= $front & $back & @CRLF
    $idx += 1
    If $idx = 17 Then $idx = 1
Next

$Newtext = StringTrimRight($Newtext, 2)

$newexample = @ScriptDir & "\newexample.txt"
If FileExists($newexample) Then FileDelete($newexample)
FileWrite($newexample, $Newtext)

 

Thank You..

I tried and I think it works well

[HezzelQuartz]

2 hours ago, jchd said:

Regex school:

Local $text = FileRead(@ScriptDir & "\" & "source.txt")
Local $hex = Execute('"' & StringRegExpReplace($text, '(?m)(?<=[[:xdigit:]]{5})([[:xdigit:]])(?=[[:xdigit:]]{2})', '" & _IncHex() & "') & '"')
ConsoleWrite($hex)

Func _IncHex()
    Local Static $Inc = 15
    $Inc += 1
    Return Hex(Mod($Inc, 16), 1)
EndFunc

I added two extra line in the source file, yielding:
 

X0  00112033
X1  AABBC1DD
X2  22446288
X3  BBDDF300
X4  11335477
X5  AACCE5FF
X6  11AA26BB
X7  CC33D744
X8  55EE68FF
X9  ABCD9988
X10 8800AADD
X11 EEFF3B44
X12 6622ACEE
X13 5599CDFF
X14 AAFF2E00
X15 0099AFCC
X16 FD5A00B6
X17 10E51194

 

Thank You

I tried and I think it works well

But

Could you please explain what is the function of execute?

I read in the help file but I'm still confused...

I just saw execute: "Execute an expression."

Thank You

[jchd]

The string supplied to Execute is AutoIt code, which is then executed. This is the way to execute dynamically created code.

[Nine]

Or from the hybrid school :

#include <Array.au3>

$aText = FileReadToArray("Test.txt")
For $i = 0 To UBound($aText) - 1
  $aText[$i] = StringRegExpReplace($aText[$i], "(?<=[[:xdigit:]]{5})([[:xdigit:]])(?=[[:xdigit:]]{2})", Hex(Mod(Number(StringRegExp($aText[$i], "X(\d+)", 1)[0]), 16), 1))
Next
ConsoleWrite(_ArrayToString($aText, @CRLF) & @CRLF) ; or _FileWriteFromArray

[ioa747]

I found the Mod() function very useful

old school with hybrid influences

#include <Array.au3>

$aList = FileReadToArray("example.txt")
For $i = 0 To UBound($aList) - 1
    $aList[$i] = StringTrimRight($aList[$i], 3) & Hex(Mod($i + 16, 16), 1) & StringRight($aList[$i], 2)
Next
ConsoleWrite(_ArrayToString($aList, @CRLF) & @CRLF) ; or _FileWriteFromArray

 

Edited yesterday at 06:33 PM by ioa747

[Werty]

From the simple school:

FileCopy("example.txt", "newexample.txt", 1)
$file = FileOpen("newexample.txt", 1 + 16)
FileSetpos($file, 9, 0)
For $loop = 0 To 15
    FileWrite($file, Hex($loop, 1))
    FileSetpos($file, 13, 1)
Next
FileClose($file)

 

Edited 23 hours ago by Werty
added filecopy