MsgBox window position not in the middle of the screen

[antai]

Can I specify where the MsgBox appears on the screen?

It appears at the center both x and y. Can I let it appear in the top of the screen?

[Melba23]

antai,

Take a look at my ExtMsgBox UDF (link is in my sig - it allows you to specify the location of the dialog, as well as its colour, font, button text, etc, etc, etc.

M23

[Nine]

Another way :

#include <Constants.au3>
#include <WinAPISysWin.au3>

Global $sTitle, $iPosX, $iPosY

Local $iRet = MsgBoxEx($MB_OKCANCEL, "Test", "Text here", 200, 60)
ConsoleWrite("Test response " & $iRet & @CRLF)
$iRet = MsgBoxEx($MB_YESNO, "New Test", "New text here", 300, 0)
ConsoleWrite("New Test response " & $iRet & @CRLF)

Func MsgBoxEx($iFlag, $sWin, $sText, $iX, $iY)
  Local $hTimerProc = DllCallbackRegister(TimerProc, 'none', 'hwnd;uint;uint_ptr;dword')
  Local $iTimerID = _WinAPI_SetTimer(0, 0, 10, DllCallbackGetPtr($hTimerProc))
  $sTitle = $sWin
  $iPosX = $iX
  $iPosY = $iY
  Local $iResp = MsgBox($iFlag, $sWin, $sText)
  DllCallbackFree($hTimerProc)
  Return $iResp
EndFunc   ;==>MsgBoxEx

Func TimerProc($hWnd, $iMsg, $iTimerID, $iTime)
  If WinActive($sTitle) Then
    _WinAPI_KillTimer(0, $iTimerID)
    WinMove($sTitle, "", $iPosX, $iPosY)
  EndIf
EndFunc   ;==>_TimerProc

 

Edited Monday at 07:37 PM by Nine
better code

[Danyfirex]

Hello, Another alternative.

expandcollapse popup

#include <WinAPIProc.au3>
#include <WinAPI.au3>
#include <GUIConstants.au3>



Global $hGUI = GUICreate("GUI")
Global $idbtnOK = GUICtrlCreateButton("OK", 310, 370, 85, 25)
GUISetState(@SW_SHOW, $hGUI)
GUIRegisterMsg(_WinAPI_RegisterWindowMessage('SHELLHOOK'), 'WM_SHELLHOOK')
_WinAPI_RegisterShellHookWindow($hGUI)



Local $nMsg = 0
While 1
    $nMsg = GUIGetMsg()
    Select
        Case $nMsg = $GUI_EVENT_CLOSE
            ExitLoop
        Case $nMsg = $idbtnOK
            _MsgBox(0, "", "Hello I'm an AutoIt Msgbox at Default Position :-)")
            _MsgBox(0, "", "Hello I'm an AutoIt Msgbox at 10,10 Position :-)", 10, 10)
            _MsgBox(0, "", "Hello I'm an AutoIt Msgbox at " &  @DesktopWidth - 300 & "," & @DesktopHeight - 300 & " Position :-)", @DesktopWidth - 300, @DesktopHeight - 300)
            _MsgBox(0, "", "Hello I'm an AutoIt Msgbox at 0,0 Position :-)", 0, 0)
    EndSelect

WEnd

_WinAPI_DeregisterShellHookWindow($hGUI)
Exit

Func _MsgBoxPostition($X = Default, $Y = Default)
    Local Static $aPos[] = [Default, Default]
    If $X = Default Or $Y = Default Then
        Return $aPos
    EndIf
    $aPos[0] = $X
    $aPos[1] = $Y
EndFunc   ;==>_MsgBoxPostition

Func _MsgBox($iFlag, $Title, $Text, $X = Default, $Y = Default, $iTimeout = Default, $hWnd = Default)
    _MsgBoxPostition($X, $Y)
    MsgBox($iFlag, $Title, $Text, $iTimeout, $hWnd)
EndFunc   ;==>_MsgBox

Func WM_SHELLHOOK($hWnd, $iMsg, $wParam, $lParam)
    #forceref $iMsg
    Switch $wParam
        Case $HSHELL_WINDOWCREATED
            If WinGetProcess($lParam) = @AutoItPID And _WinAPI_GetClassName($lParam) = "#32770" Then
                Local $aPos = _MsgBoxPostition()
                If $aPos[0] <> Default And $aPos[1] <> Default Then
                    WinMove($lParam, "", $aPos[0], $aPos[1])
                EndIf
            EndIf
    EndSwitch
EndFunc   ;==>WM_SHELLHOOK

Saludos

[argumentum]

MsgBox_Extn() UDF for MsgBox() move/position and/or click button delay.