copying info from another window using autoit

[manit]

hi ,

I am using windows 11 OS .

My aim is to get text from another window and save it in a file.

Here is my target window (see xirrus.png)

I want to capture ssid , bssid , channel and signal data of wireless section in it .

I ran autoit info tool on that area and I got following details (see window-info.png)

I want to save all data in a text file so that a batch file will extract values from text file . 

How can I accomplish this ?

 

Thanks. 

 

 

 

[Nine]

Depends if the 4 fields are readable controls.  Check Control tab of au3info.exe tool for each of the 4 fields.  If available use ControlGetText (see help file).

[manit]

Thanks Nine

I wrote following code to get expected results

expandcollapse popup

#include <MsgBoxConstants.au3>
#include <FileConstants.au3>

Example()
Exit(0)
Func Example()

        ; Wait 10 seconds for the xirrus window to appear.
        Local $hWnd = WinWait("Xir", "", 10)
        If $hWnd = 0 Then
                MsgBox($MB_SYSTEMMODAL, "", "Window with title Xir not found")
                Exit(1)
        EndIf
        ; Get data from window
        Local $signal_value = ControlGetText($hWnd, "", "[NAME:labelSignalValue]")
        If $signal_value = "" Then
                MsgBox($MB_SYSTEMMODAL, "", "Signal value not found in Xir window")
                Exit(3)
        EndIf
        Local $BSSID_value = ControlGetText($hWnd, "", "[NAME:labelBSSIDValue]")
        If $BSSID_value = "" Then
                MsgBox($MB_SYSTEMMODAL, "", "BSSID value not found in Xir window")
                Exit(4)
        EndIf
        Local $channel_value = ControlGetText($hWnd, "", "[NAME:labelChannelValue]")
        If $channel_value = "" Then
                MsgBox($MB_SYSTEMMODAL, "", "Signal value not found in Xir window")
                Exit(5)
        EndIf
        ; Show data obtained from window
        MsgBox($MB_SYSTEMMODAL, "", "Signal: " & $signal_value & @CRLF & "BSSID: " & $BSSID_value & @CRLF & "channel: " & $channel_value)
        ; Open file for overwriting
        Local $hFileOpen = FileOpen("signal-bssid-channel-data.txt", $FO_OVERWRITE)
        If $hFileOpen = -1 Then
                MsgBox($MB_SYSTEMMODAL, "", "An error occurred when writing the file.")
                Exit(2)
        EndIf
        ; Write data shown to file
        FileWrite($hFileOpen, "Signal: " & $signal_value & @CRLF & "BSSID: " & $BSSID_value & @CRLF & "channel: " & $channel_value)
        ; Close the handle returned by FileOpen.
        FileClose($hFileOpen)
EndFunc   ;==>Example

 

I compiled au3 to exe file then relevant part of my batch file is

@echo off
get-data-from-xir-window-x86.exe
if %errorlevel%==0 (
   echo "SUCCESS"
   echo "Data in signal-bssid-channel-data.txt"
) else if %errorlevel%==1 (
   echo "ERROR"
   echo "Xir window not found"
) else if %errorlevel%==2 (
   echo "ERROR"
   echo "Cannot open data file for writing signal bssid channel values"
) else (
   echo "ERROR"
   echo "signal or bssid or channel Values not found in Xir window"
)

Let me know if there is better coding practice I should follow . 

 

Thanks.

Edited August 19, 2024 by manit
quote replaced by code tag

[Nine]

When you post code, please use the method shown in the link.  It makes easier for us to read a script (with color and all)

As per your code, it looks good.  You made a strong error handling, I like that.

[manit]

20 hours ago, Nine said:

When you post code, please use the method shown in the link.  It makes easier for us to read a script (with color and all)

As per your code, it looks good.  You made a strong error handling, I like that.

Edited my post with code tag (Also, i will remember in future).

Thanks.