Including a line breaker in GUI title

[CYCho]

The following code works as I intended in Windows 11:  the resulting GUI title shows only the first line and the task bar tooltip shows both lines. If I run the same code in Windows 10, however, the task bar tooltip is the same but the GUI title shows concatenation of two lines. How can I make the code to behave the same way in Windows 10 as in Windows 11? Thank you in advance for your help.
 

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("AutoIt v3" & @CRLF & "A BASIC-like scripting language" , 400, 100)
GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop

    EndSwitch
WEnd

GUIDelete($hGUI)

 

Edited August 19 by CYCho

[CYCho]

How does this code behave in other Windows versions?

I could not test how this code behaves in Windows versions other than 10 and 11. I would appreciate it very much if anyone could share their experience with other versions of Windows here.

Edited August 21 by CYCho

[CYCho]

#include <GUIConstantsEx.au3>
#include <String.au3>

If @OSVersion = "WIN_11" Then
    $sTitle = "AutoIt v3" & @CRLF & "A BASIC-like scripting language"
Else
    $sTitle = "AutoIt v3" & _StringRepeat(" ", 45) & @CRLF & "A BASIC-like scripting language"
EndIf
$hGUI = GUICreate($sTitle, 400, 100)
GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop

    EndSwitch
WEnd

GUIDelete($hGUI)

This is not a perfect solution, but I can live with it. In Windows 10, the GUI title shows 3 dots(ellipses) at the end of title box, which is not so offensive to my eyes. The number in _StringRepeat() function should be adjusted to suit the GUI width. You can increase or decrease this number and see how the GUI title and taskbar tooltip change.

Edited September 3 by CYCho

[ioa747]

here is my attempt
Testet in Win10

expandcollapse popup

#include <AutoItObject.au3>
#include <WinAPI.au3>
#include <GUIConstantsEx.au3>

Global $oError = ObjEvent("AutoIt.Error", "_ErrFunc")

$hGUI = GUICreate("AutoIt v3", 400, 100)
GUISetState()

_SetThumbnailTooltip($hGUI, "AutoIt v3" & @CRLF & "A BASIC-like scripting language")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop
    EndSwitch
WEnd

GUIDelete($hGUI)

;--------------------------------------------------------------------------------------------------------------------------------
Func _SetThumbnailTooltip($hWnd, $sText)

    ; Initialize AutoItObject
    _AutoItObject_StartUp()

    ; Get CLSID and IID for ITaskbarList3
    Local $CLSID_TaskBarlist = _AutoItObject_CLSIDFromString("{56FDF344-FD6D-11D0-958A-006097C9A090}")
    Local $IID_ITaskbarList3 = _AutoItObject_CLSIDFromString("{ea1afb91-9e28-4b86-90e9-9e9f8a5eefaf}")

    ; Create the ITaskbarList3 interface instance
    Local $pTB3
    _AutoItObject_CoCreateInstance(DllStructGetPtr($CLSID_TaskBarlist), 0, 1, DllStructGetPtr($IID_ITaskbarList3), $pTB3)
    If Not $pTB3 Then
        MsgBox(16, "Error", "Failed to create ITaskbarList3 interface, exiting.")
        _AutoItObject_Shutdown()
        Exit
    EndIf

    Local $tagInterface = _
            "QueryInterface long(ptr;ptr;ptr);" & _
            "AddRef ulong();" & _
            "Release ulong();" & _
            "HrInit long();" & _
            "AddTab long(hwnd);" & _
            "DeleteTab long(hwnd);" & _
            "ActivateTab long(hwnd);" & _
            "SetActiveAlt long(hwnd);" & _
            "MarkFullscreenWindow long(hwnd;int);" & _
            "SetProgressValue long(hwnd;uint64;uint64);" & _
            "SetProgressState long(hwnd;int);" & _
            "RegisterTab long(hwnd;hwnd);" & _
            "UnregisterTab long(hwnd);" & _
            "SetTabOrder long(hwnd;hwnd);" & _
            "SetTabActive long(hwnd;hwnd;dword);" & _
            "ThumbBarAddButtons long(hwnd;uint;ptr);" & _
            "ThumbBarUpdateButtons long(hwnd;uint;ptr);" & _
            "ThumbBarSetImageList long(hwnd;ptr);" & _
            "SetOverlayIcon long(hwnd;ptr;wstr);" & _
            "SetThumbnailTooltip long(hwnd;wstr);" & _
            "SetThumbnailClip long(hwnd;ptr);"

    ; Create the AutoItObject wrapper for the interface
    Local $oTaskBar = _AutoItObject_WrapperCreate($pTB3, $tagInterface)
    If Not IsObj($oTaskBar) Then
        MsgBox(16, "Error", "Failed to create AutoItObject wrapper.")
        _AutoItObject_Shutdown()
        Exit
    EndIf

    ; Initialize the ITaskbarList3 interface
    $oTaskBar.HrInit()

    ; Set the tooltip for the taskbar thumbnail
    $oTaskBar.SetThumbnailTooltip($hWnd, $sText)

    ; Release the COM object
    $oTaskBar = 0
    _AutoItObject_Shutdown()
EndFunc   ;==>_SetThumbnailTooltip
;--------------------------------------------------------------------------------------------------------------------------------
Func _ErrFunc()
    ConsoleWrite("! COM Error !  Number: 0x" & Hex($oError.number, 8) & "   ScriptLine: " & $oError.scriptline & " - " & $oError.windescription & @CRLF)
    Return
EndFunc   ;==>_ErrFunc

 

[CYCho]

40 minutes ago, ioa747 said:

here is my attempt
Testet in Win10

You seem to have come from a different world. I don't understand your code, but the result is exactly what I wanted. Thanks a lot.

[ioa747]

At first I tried something simpler, but it didn't work  (look at -setthumbnailtooltip-the-requested-action-with-this-object-has-failed/  )
after looking for the cause I found the approach with AutoItObject.au3.
cut from here, paste from there I reached the result (I don't even understand most of them)
But I'm willing to learn

[mLipok]

1 hour ago, CYCho said:

You seem to have come from a different world.

After all, he is Merlin

 

[argumentum]

25 minutes ago, UEZ said:

Why not simply replace any CRLF char with "space"?

He's looking to see a caption of the 1st line and a "ThumbnailTooltip" of multiple lines, for the reason of his reasons.

In my Win11 (23H2), it works as expected

    

 

Edited August 26 by argumentum
added pic

[UEZ]

I misread the question but you can cut the string from CRLF

#include <GUIConstantsEx.au3>

$sTitle = "AutoIt v3" & @CRLF & "A BASIC-like scripting language" & @CRLF & "Blah"
$sNew = StringRegExp($sTitle, "(.+)\r\n", 3)
$hGUI = GUICreate(IsArray($sNew) ? $sNew[0] : $sTitle, 400, 100)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop

    EndSwitch
WEnd

GUIDelete($hGUI)

 

[ioa747]

 

Edited August 26 by ioa747

[CYCho]

I should have selected this as my Solution. This makes Windows 10 to behave like Windows 11 as far as GUI title and taskbar thumbnail tooltip go. I incorporated this in the latest version of  my zPlayer. Hooray for your learning mind!

Edited August 28 by CYCho