Getting information about active domain network

[DonChunior]

In my Network and Sharing center you can see (see screenshot) that I have an active domain network.

Is there a way to …

1. determine the active networks with AutoIt,
2. find out whether one of them is a domain network and
3. if one is found, obtain the IP address associated with it?

In my opinion, you could also go the other way round and …

1. collect the IP addresses of the macros @IPAddress1 to 4 and
2. check each address to see whether it belongs to an active domain network.

Regards,
DonChunior

Edited August 8 by DonChunior

[water]

I started here to get a list of networks.
MS information can be found here.

[DonChunior]

Hello @water,

thanks, that looks like a good starting point for further activities.

Regards,
DonChunior

[water]

I use the following script to check that the computer is connected to an AD domain:

expandcollapse popup

; #INTERNAL_USE_ONLY#============================================================================================================
; Name ..........: __NetworkCheck
; Description ...: Check if the local machine is connected to a domain.
; Syntax ........: __NetworkCheck()
; Parameters ....: None
; Return values .: Success - One of the following integer values:
;                  |0 - The local machine is not connected to a domain
;                  |1 - The local machine is connected to a domain
;                  Failure - 0 and sets @error to one of the following values:
;                  |1 = Could not create the NLM object
;                  |2 = Could not create the NetworkConnections object
;                  |3 = Could not create the Network object
; Author ........: water
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........: https://learn.microsoft.com/en-us/windows/win32/NLA/portal
;                  https://www.autoitscript.com/forum/topic/174245-get-connected-networks/?do=findComment&comment=1261045
; Example .......:
; ===============================================================================================================================
Func __NetworkCheck()
    ; NLM_DOMAIN_TYPE: The NLM_DOMAIN_TYPE enumeration is a set of flags that specify the domain type of a network.
    ; See: https://learn.microsoft.com/en-us/windows/win32/api/netlistmgr/ne-netlistmgr-nlm_domain_type
    Local Const $NLM_DOMAIN_TYPE_NON_DOMAIN_NETWORK = 0
    Local Const $NLM_DOMAIN_TYPE_DOMAIN_NETWORK = 0x1
    Local Const $NLM_DOMAIN_TYPE_DOMAIN_AUTHENTICATED = 0x2
    #forceref $NLM_DOMAIN_TYPE_NON_DOMAIN_NETWORK
    Local $bConnected2Domain = False
    Local $sNLM_ClsID = "{DCB00C01-570F-4A9B-8D69-199FDBA5723B}"
    Local $oNLM, $oNetworkConnections, $oNetwork
    $oNLM = ObjCreate($sNLM_ClsID)                                ; Create the object for the Network List Manager
    If @error Then Return SetError(1, @error, 0)
    If $oNLM.IsConnected Then                                     ; The local machine has network connectivity, check details
        $oNetworkConnections = $oNLM.GetNetworkConnections        ; Get the collection of NetworkConnections
        If @error Then Return SetError(2, @error, 0)
        For $oNetworkConnection In $oNetworkConnections           ; Check each NetworkConnection
            $oNetwork = $oNetworkConnection.GetNetwork
            If @error Then Return SetError(3, @error, 0)
            If $oNetwork.IsConnected = True And ($oNetwork.GetDomainType = $NLM_DOMAIN_TYPE_DOMAIN_NETWORK Or $oNetwork.GetDomainType = $NLM_DOMAIN_TYPE_DOMAIN_AUTHENTICATED) Then $bConnected2Domain = True
        Next
        Return ($bConnected2Domain = True) ? 1 : 0
    Else
        Return 0
    EndIf
EndFunc   ;==>__NetworkCheck