form with image background with several .png image buttons

[Netol]

Hi my friend

How can I make a form that has an image background with several .png image buttons
When you mouse over them they enlarge for a second

I need to create a form like the attached image.
Each green icon will be a .png transparent button

 

[Jos]

What exactly is that image from?

[Werty]

56 minutes ago, Jos said:

What exactly is that image from?

NEOM

https://en.wikipedia.org/wiki/Neom

So no, not a game.

Edited July 5 by Werty

[Netol]

3 hours ago, Jos said:

What exactly is that image from?

Is a Tour Virtual of any construction.

I need to create an background image and a lot of button like .png images

[Andreik]

Not really a button but something that might work well in your case.

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>

Global $Info, $ButtonHover = False

_GDIPlus_Startup()

Local $hMain = GUICreate("Image", 400, 200)
Local $cBackground = GUICtrlCreatePic(@ScriptDir & '\background.jpg', 0, 0, 400, 200)   ; Background image
GUICtrlSetState($cBackground, $GUI_DISABLE)
Local $cButton = GUICtrlCreatePic('', 50, 50, 50, 50)
ImageToCtrl(@ScriptDir & '\button.png', $cButton)
GUISetState(@SW_SHOW, $hMain)

While True
    Switch GUIGetMsg()
        Case $cButton
            MsgBox(0, '', 'You clicked me?')
        Case $GUI_EVENT_CLOSE
            _GDIPlus_Shutdown()
            Exit
    EndSwitch
    $Info = GUIGetCursorInfo($hMain)
    If Not IsArray($Info) Then ContinueLoop
    If $Info[4] = $cButton Then
        If Not $ButtonHover Then
            $ButtonHover = True
;~          You can upscale control here
            ImageToCtrl(@ScriptDir & '\hover.png', $cButton)    ; Hovered button image
        EndIf
    Else
        If $ButtonHover Then
            $ButtonHover = False
;~          You can downscale control here
            ImageToCtrl(@ScriptDir & '\button.png', $cButton)   ; Normal button image
        EndIf
    EndIf
WEnd

Func ImageToCtrl($sImage, $cCtrl)
    Local $hImage = _GDIPlus_ImageLoadFromFile($sImage)
    Local $iWidth = _GDIPlus_ImageGetWidth($hImage)
    Local $iHeight = _GDIPlus_ImageGetHeight($hImage)
    Local $hBitmap = _GDIPlus_BitmapCreateFromScan0($iWidth, $iHeight)
    Local $hGraphics = _GDIPlus_ImageGetGraphicsContext($hBitmap)
    _GDIPlus_GraphicsDrawImageRect($hGraphics, $hImage, 0, 0, $iWidth, $iHeight)
    Local $hHBITMAP = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBitmap)
    _WinAPI_DeleteObject(GUICtrlSendMsg($cCtrl, 0x0172, 0, $hHBITMAP))
    _WinAPI_DeleteObject($hHBITMAP)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_ImageDispose($hImage)
EndFunc

If you want multiple "buttons" you can create a multidimensional array to store the control ID and current hover state for each control.

Edited July 5 by Andreik

[Netol]

1 hour ago, Andreik said:

Not really a button but something that might work well in your case.

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>

Global $Info, $ButtonHover = False

_GDIPlus_Startup()

Local $hMain = GUICreate("Image", 400, 200)
Local $cBackground = GUICtrlCreatePic(@ScriptDir & '\background.jpg', 0, 0, 400, 200)   ; Background image
GUICtrlSetState($cBackground, $GUI_DISABLE)
Local $cButton = GUICtrlCreatePic('', 50, 50, 50, 50)
ImageToCtrl(@ScriptDir & '\button.png', $cButton)
GUISetState(@SW_SHOW, $hMain)

While True
    Switch GUIGetMsg()
        Case $cButton
            MsgBox(0, '', 'You clicked me?')
        Case $GUI_EVENT_CLOSE
            _GDIPlus_Shutdown()
            Exit
    EndSwitch
    $Info = GUIGetCursorInfo($hMain)
    If Not IsArray($Info) Then ContinueLoop
    If $Info[4] = $cButton Then
        If Not $ButtonHover Then
            $ButtonHover = True
;~          You can upscale control here
            ImageToCtrl(@ScriptDir & '\hover.png', $cButton)    ; Hovered button image
        EndIf
    Else
        If $ButtonHover Then
            $ButtonHover = False
;~          You can downscale control here
            ImageToCtrl(@ScriptDir & '\button.png', $cButton)   ; Normal button image
        EndIf
    EndIf
WEnd

Func ImageToCtrl($sImage, $cCtrl)
    Local $hImage = _GDIPlus_ImageLoadFromFile($sImage)
    Local $iWidth = _GDIPlus_ImageGetWidth($hImage)
    Local $iHeight = _GDIPlus_ImageGetHeight($hImage)
    Local $hBitmap = _GDIPlus_BitmapCreateFromScan0($iWidth, $iHeight)
    Local $hGraphics = _GDIPlus_ImageGetGraphicsContext($hBitmap)
    _GDIPlus_GraphicsDrawImageRect($hGraphics, $hImage, 0, 0, $iWidth, $iHeight)
    Local $hHBITMAP = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBitmap)
    _WinAPI_DeleteObject(GUICtrlSendMsg($cCtrl, 0x0172, 0, $hHBITMAP))
    _WinAPI_DeleteObject($hHBITMAP)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_ImageDispose($hImage)
EndFunc

If you want multiple "buttons" you can create a multidimensional array to store the control ID and current hover state for each control.

WOW, fantastic and you did it on the first try.

Thanks a lot