Automated File Management: Using AUTOIT to Prevent Desktop Clutter by Moving New Files to a Specific Folder - (Moved)

[Ilounah]

Can an AUTOIT program automatically move newly saved files from the Desktop to a specific folder to avoid dumping on the Desktop, while leaving old applications and necessary folder icon links?

[argumentum]

Well yes !. If a file of extension .whatever is created, your script could move it to a folder of your choosing.
I believe in you !. You can do it !.

[Jos]

Moved to the appropriate AutoIt General Help and Support forum, as the Developer General Discussion forum very clearly states:

Quote

General development and scripting discussions.

---

Do not create AutoIt-related topics here, use the AutoIt General Help and Support or AutoIt Technical Discussion forums.

Moderation Team

[Nine]

Oh well, there you go...

#include <File.au3>

HotKeySet("!{ESC}", _Exit)
Main(@DesktopDir, "C:\Apps\Temp")

Func Main($sSourceDir, $sTargetDir)
  Local $aBase = _FileListToArray($sSourceDir)
  ;_ArrayDisplay ($aBase)
  Local $aList

  While Sleep(5 * 1000) ; check every 5 secs
    $aList = _FileListToArray($sSourceDir)
    For $i = 1 To $aList[0]
      _ArraySearch($aBase, $aList[$i], 1)
      If @error Then
        ; do not use FileMove : under some circumstances it may not work properly
        FileCopy($sSourceDir & "\" & $aList[$i], $sTargetDir & "\" & $aList[$i], $FC_OVERWRITE)
        FileDelete($sSourceDir & "\" & $aList[$i])
      EndIf
    Next
  WEnd
EndFunc   ;==>Main

Func _Exit()
  Exit
EndFunc   ;==>_Exit

 

Edited Friday at 12:58 PM by Nine

[ioa747]

@Nine  directory friendly

#include <File.au3>

HotKeySet("!{ESC}", _Exit)
Main(@DesktopDir, "C:\Apps\Temp")

Func Main($sSourceDir, $sTargetDir)
    Local $aBase = _FileListToArray($sSourceDir)
;~   _ArrayDisplay ($aBase)
    Local $aList
    While Sleep(10 * 1000) ; check every 10 secs
        $aList = _FileListToArray($sSourceDir)
        For $i = 1 To $aList[0]
            _ArraySearch($aBase, $aList[$i], 1)
            If @error Then
                ; do not use FileMove : under some circumstances it may not work properly
                If StringInStr(FileGetAttrib($sSourceDir & "\" & $aList[$i]), "D") = 0 Then
                    FileCopy($sSourceDir & "\" & $aList[$i], $sTargetDir & "\" & $aList[$i], $FC_OVERWRITE)
                    FileDelete($sSourceDir & "\" & $aList[$i])
                Else
                    DirCopy($sSourceDir & "\" & $aList[$i], $sTargetDir & "\" & $aList[$i], $FC_OVERWRITE)
                    DirRemove($sSourceDir & "\" & $aList[$i], 1)
                EndIf
            EndIf
        Next
    WEnd
EndFunc   ;==>Main

Func _Exit()
    Exit
EndFunc   ;==>_Exit