Menu possible without submenus?

[TheAutomator]

simple example:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Form1 = GUICreate("Form1", 615, 437, 192, 124)
$menu1 = GUICtrlCreateMenu("click me")
GUISetState(@SW_SHOW)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $menu1
            MsgBox(64,'yes!','it works') ; not
    EndSwitch
WEnd

To make this work without submenus/empty menu tricks seems to be difficult 

Not possible without dummy's / extensive UDF's or submenus?

TheAutomator

Edited May 8, 2024 by TheAutomator

[Nine]

Here one way :

#include <GUIConstants.au3>
#include <WindowsConstants.au3>
#include <GuiMenu.au3>

Opt("MustDeclareVars", True)

Global $hGUI = GUICreate("Form1", 625, 442, 370, 232)
Global $idMenu = GUICtrlCreateMenu("Click me")
Global $hMenu = _GUICtrlMenu_GetMenu($hGUI)
Global $idChoice = GUICtrlCreateDummy()

GUISetState()
GUIRegisterMsg($WM_MENUSELECT, WM_MENUSELECT)

While True
  Switch GUIGetMsg()
    Case $GUI_EVENT_CLOSE
      Exit
    Case $idChoice
      ConsoleWrite("Menu clicked " & GUICtrlRead($idChoice) & @CRLF)
  EndSwitch
WEnd

Func WM_MENUSELECT($hWnd, $iMsg, $wParam, $lParam)
  Local $iIndex = _WinAPI_LoWord($wParam)
  Local $iFlag = _WinAPI_HiWord($wParam)
  If $iIndex = 0 And BitAND($iFlag, $MF_MOUSESELECT) And $lParam = $hMenu Then
    GUICtrlSendToDummy($idChoice, $iIndex)
    EndMenu()
  EndIf
  Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_MENUSELECT

Func EndMenu()
  DllCall("user32.dll", "bool", "EndMenu")
EndFunc

 

[Melba23]

TheAutomator,

The trick I have used in the past only works when you to have an initial "normal" menu entry - so how about this:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Form1 = GUICreate("Form1", 615, 437, 192, 124)

$mDummymenu = GUICtrlCreateMenu("")

$menu1 = GUICtrlCreateMenuItem("click me", -1)

GUISetState(@SW_SHOW)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $menu1
            MsgBox(64,'yes!','it works') ; does!
    EndSwitch
WEnd

M23

[Nine]

Nice trick M23, to make it more like modern menu how about using this character (instead of null) :

$mDummymenu = GUICtrlCreateMenu("≡")

 

[TheAutomator]

I guess the short answer is "nope",
I tend to use the one from Melba32 for simplicity (and marked it as solution to close the topic), but you have to have a clickable empty menu in your gui..
The one Nine posted was a little more complicated and used a dummy and udf's, but it looks the way it should when used..
I can't really call any reply's the right 'solution' because the question was "possible without dummy's, udf's or submenu/second menu tricks?".

But I wanna thank you all for coming up with workarounds, now at least I know I'm not doing anything wrong in my code 

TheAutomator

Edited May 8, 2024 by TheAutomator

[Nine]

Can you show us YOUR solution without dummy, udf, menu/submenu, etc ?  I am really curious to see how you got it working, and community sure would appreciate to learn from it too... 

[pixelsearch]

@Melba23 & @Nine

Deleting the menu control seems to do the job. It will position to the very left of the GUI all existing menuitem(s) control(s) . Does this work for you ?

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

$Form1 = GUICreate("Form1", 615, 437, 192, 124)

$mDummymenu = GUICtrlCreateMenu("this menu control will be deleted")
$menu1 = GUICtrlCreateMenuItem("click me", -1)
$menu2 = GUICtrlCreateMenuItem("click me again", -1)

GUICtrlDelete($mDummymenu) ; <======================

GUISetState(@SW_SHOW)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $menu1
            MsgBox($MB_TOPMOST ,'yes!', 'it works')
        Case $menu2
            MsgBox($MB_TOPMOST,'yes!', 'it works again')
    EndSwitch
WEnd

 

[Melba23]

pixelsearch,

Nice one!

M23

[TheAutomator]

Dear Nine,

On 5/9/2024 at 2:27 AM, Nine said:

Can you show us YOUR solution without dummy, udf, menu/submenu, etc ?  I am really curious to see how you got it working, and community sure would appreciate to learn from it too... 

I think you misunderstood the question.. I wanted to know if it was possible, I'm not saying it is possible 

The solution seems to be to do it like Melba32 or pixelsearch or you
The answer to my question would be "sorry, not possible" do you know what I mean?

Edited May 15, 2024 by TheAutomator

[TheAutomator]

And now here we can even reuse the variable, gonna do it like this.

Thanks pixelsearch!

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

$Form1 = GUICreate("Form1", 615, 437, 192, 124)

$menu2 = GUICtrlCreateMenu("this menu control will be deleted")
$menu1 = GUICtrlCreateMenuItem("click me", -1)
GUICtrlDelete($menu2) ; <======================
$menu2 = GUICtrlCreateMenuItem("click me again", -1)


GUISetState(@SW_SHOW)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $menu1
            MsgBox($MB_TOPMOST ,'yes!', 'it works')
        Case $menu2
            MsgBox($MB_TOPMOST,'yes!', 'it works again')
    EndSwitch
WEnd

 

Edited May 15, 2024 by TheAutomator

[TheAutomator]

On 5/9/2024 at 3:32 PM, pixelsearch said:

@Melba23 & @Nine

Deleting the menu control seems to do the job. It will position to the very left of the GUI all existing menuitem(s) control(s) . Does this work for you ?

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

$Form1 = GUICreate("Form1", 615, 437, 192, 124)

$mDummymenu = GUICtrlCreateMenu("this menu control will be deleted")
$menu1 = GUICtrlCreateMenuItem("click me", -1)
$menu2 = GUICtrlCreateMenuItem("click me again", -1)

GUICtrlDelete($mDummymenu) ; <======================

GUISetState(@SW_SHOW)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $menu1
            MsgBox($MB_TOPMOST ,'yes!', 'it works')
        Case $menu2
            MsgBox($MB_TOPMOST,'yes!', 'it works again')
    EndSwitch
WEnd

 

This is an awesome hack btw 

Edited May 15, 2024 by TheAutomator