Find Duplicates in an array

[blumi]

I have a folder with movies in it.

I read this folder and add the filenames into an array.

Now I want to find the duplicates, I have a function that works but not exactly as needed.

In the folder are for example some names like this

Rambo I

Rambo II

Rambo III

The problem, the result lists me Rambo II as a duplicate, cause it exitsts in the name Rambo III

How to modify the function that only exact the same names are recognized as duplicates and not the ones that are contained in a filename?

Func FindeDuplikate( $aArray )
  Local $oTst = ObjCreate( "Scripting.Dictionary" )
  Local $oRes = ObjCreate( "Scripting.Dictionary" )

  For $i = 0 To UBound( $aArray ) - 1
    If Not $oTst.Exists( $aArray[$i] ) Then
      $oTst( $aArray[$i] ) = 1
    ElseIf Not $oRes.Exists( $aArray[$i] ) Then
      $oRes( $aArray[$i] ) = 1
    EndIf
  Next

  Return $oRes.Keys()
EndFunc

 

[water]

You can query and modify the compare mode of the Scripting.Dictionary as described here.

[Nine]

Scripting.Dictionary will not mix "Rambo II" with "Rambo III".  I believe you got another problem somewhere.  Here a simple way to test it :

#include <Array.au3>

Local $aList = ["Rambo I", "Rambo II", "Rambo III", "RAMBO I", "Rambo ii"]
Local $aDup = FindeDuplikate($aList)
_ArrayDisplay($aDup)

Func FindeDuplikate( $aArray )
  Local $oTst = ObjCreate( "Scripting.Dictionary" )
  Local $oRes = ObjCreate( "Scripting.Dictionary" )
  ;$oTst.CompareMode = 1

  For $i = 0 To UBound( $aArray ) - 1
    If Not $oTst.Exists( $aArray[$i] ) Then
      $oTst( $aArray[$i] ) = 1
    ElseIf Not $oRes.Exists( $aArray[$i] ) Then
      $oRes( $aArray[$i] ) = 1
    EndIf
  Next

  Return $oRes.Keys()
EndFunc

As you can see none is duplicate, but if you uncomment the line of CompareMode, then comparaison will be non-case-sensitive, so last two will be flagged as duplicates.

[UEZ]

Something like this here?

#include <Array.au3>
Global $aFilms[] = ["Rambo", "Rambo II", "Rambo III", "Rocky", "Rocky II", "Rocky III", "Rocky IV", "Possessed", "Edge of Tomorrow", "The Ghost Writer", "rocky ii", "RAMBO iii"]

Global $aDuplicates[UBound($aFilms) * 2], $j = 0
For $i = 0 To UBound($aFilms) - 1
    $aDuplicates[$j] = $aFilms[$i]
    $j += 1
    If Random() < 0.3333333 Then
        $aDuplicates[$j] = $aFilms[$i]
        $j += 1
    EndIf
Next
ReDim $aDuplicates[$j - 1]
;_ArrayShuffle($aDuplicates)
_ArraySort($aDuplicates)
ConsoleWrite("All " & UBound($aDuplicates) & " films:" & @CRLF)
For $i = 0 To UBound($aDuplicates) - 1
    ConsoleWrite($i + 1 & ": " & $aDuplicates[$i] & @CRLF)
Next

ConsoleWrite(@CRLF)
ConsoleWrite("Duplicates:" & @CRLF)
$i = -1
$j = 1
While $i < UBound($aDuplicates) - 2
    $i += 1
    If StringLower($aDuplicates[$i]) == StringLower($aDuplicates[$i + 1]) Then
        ConsoleWrite($j & ". duplicate: " & $aDuplicates[$i] & @CRLF)
        $j += 1
        $i += 1
    EndIf
WEnd

 

Edited March 7 by UEZ

[ioa747]

look at the Reveal hidden content
in the link below
https://www.autoitscript.com/forum/topic/198175-zplayer-my-own-little-audiovideo-player/page/8/#comment-1528675

I believe it would help
$aFileInfo = _PropertiesListToArray("F:\Movies\_New\_New films", "*.mp4;*.mkv;*.avi;*.flv", "1, 27, 196, 316, 314, 315, 320, 349, 355", 1)

 

[ioa747]

better late than never

211972-get-the-duplicates-value-of-array/

Edited June 14 by ioa747