AutoIt Loading Effect

[1stPK]

How can I make a green effect bar when I press a button?

 

Spoiler

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <ProgressConstants.au3>

Local $hGUI = GUICreate("Nút với thanh loading", 300, 100)

Local $btn = GUICtrlCreateButton("Bắt đầu", 110, 30, 80, 30)
Local $progress = GUICtrlCreateProgress(20, 70, 260, 20)

GUISetState(@SW_SHOW)

GUICtrlSetOnEvent($btn, "StartButton_Clicked")

While True
    $Msg = GUIGetMsg()
    Switch $Msg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func StartButton_Clicked()
    GUICtrlSetState($btn, $GUI_DISABLE)
    GUICtrlSetBkColor($progress, 0x0000FF)
    ProgressOn("Loading", "Đang thực hiện...", "0%", -1, -1, $GUI_PROGRESS_COLOR)
    
    For $i = 0 To 100 Step 10
        Sleep(500)
        If GUIGetMsg() = $GUI_EVENT_CLOSE Then ExitLoop ; Kiểm tra sự kiện GUI trong vòng lặp
        ProgressSet($i)
    Next
    
    ProgressOff()
    GUICtrlSetState($btn, $GUI_ENABLE)
EndFunc

 

 

Edited January 12, 2024 by 1stPK

[water]

Search the forum for "progressbar" or the wiki and you will find a lot of hits.

[ioa747]

50872-how-to-post-code-on-the-forum/

https://www.autoitscript.com/autoit3/docs/functions/GUISetOnEvent.htm

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <ProgressConstants.au3>

Local $hGUI = GUICreate("Nút với thanh loading", 300, 100)

Local $btn = GUICtrlCreateButton("Bắt đầu", 110, 30, 80, 30)
Local $progress = GUICtrlCreateProgress(20, 70, 260, 20)

GUISetState(@SW_SHOW)

;~ GUICtrlSetOnEvent($btn, "StartButton_Clicked")

While True
    $Msg = GUIGetMsg()
    Switch $Msg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $btn
            StartButton_Clicked()

    EndSwitch
WEnd

Func StartButton_Clicked()
    GUICtrlSetState($btn, $GUI_DISABLE)
    GUICtrlSetBkColor($progress, 0x0000FF)
;~  ProgressOn ( "title", "maintext" [, "subtext" [, x pos [, y pos [, opt]]]] )
    ProgressOn("Loading", "Đang thực hiện...", "0%", -1, -1)

    For $i = 0 To 100 Step 10
        Sleep(500)
        If GUIGetMsg() = $GUI_EVENT_CLOSE Then ExitLoop ; Kiểm tra sự kiện GUI trong vòng lặp
        ProgressSet($i)
    Next

    ProgressOff()
    GUICtrlSetState($btn, $GUI_ENABLE)
EndFunc   ;==>StartButton_Clicked

 

[Nine]

I think he meant something like this :

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <ProgressConstants.au3>

HotKeySet("{ESC}", Terminate)

Opt("GUIOnEventMode", True)

Local $hGUI = GUICreate("Nút với thanh loading", 300, 100)
GUISetOnEvent($GUI_EVENT_CLOSE, Terminate)

Local $btn = GUICtrlCreateButton("Bắt đầu", 110, 30, 80, 30)
GUICtrlSetOnEvent(-1, "StartButton_Clicked")

Local $progress = GUICtrlCreateProgress(20, 70, 260, 20)
GUISetState()

While Sleep(100)
WEnd

Func StartButton_Clicked()
  GUICtrlSetState($btn, $GUI_DISABLE)
  For $i = 0 To 100 Step 10
    GUICtrlSetData($progress, $i)
    Sleep(500)
  Next
  GUICtrlSetState($btn, $GUI_ENABLE)
EndFunc   ;==>StartButton_Clicked

Func Terminate()
  Exit
EndFunc   ;==>Terminate

ps. you cannot interrupt a secondary loop from a GUI.  Only the main GUI loop can be interrupted (unless you use a "hack" like I did)

Edited January 11, 2024 by Nine