Aut2Exe - no program description details?

[Jos]

It is pretty simple:

• When you like to ONLY use aut2exe you ONLY use Commandline options or #PRAGMA directives in your source ode.
• When you want to use AutoIt3Wrapper, you can use either #PRAGMA and/or #AutoIt3Wrapper directives in the source and run the same command line as generated by full version of the SciTE4AutoIt3 package. so simply run the compile one time from SciTE and copy&paste the shown command line in the outputpane.

Using the INI for setting the AutoIt3Wrapper is something I would not recommend as that is only there for backwards compatibility and #AutoIt3Wrapper directives are so much clearer!

 

 

Edited November 24, 2023 by Jos

[Jos]

3 minutes ago, web2win said:

To compile au3 to exe ... these are the details I want to set from the command line 

You have now been given 3 options to do what you want to do so your next post WILL contain the information about what you have tried and isn't working as we seem to be going around in circles.  

[donnyh13]

12 hours ago, Nine said:

In anyway, it might be of use to know the params of Aut2exe.

No problem, It does actually, you solved a problem for me as well. Thank you.

6 hours ago, Jos said:

Correct...  So hence my whole answer! 😏

Right. Sorry Jos.

@web2win, based on the picture Nine provided, here is a basic example (this is just an autoit example, as I am unlearned in run or cmd prompt commands.

RunWait('"C:\Program Files (x86)\AutoIt3\aut2exe\aut2exe.exe"  /in "' & @DesktopDir & '\Test.au3' & '" /out "' & @DesktopDir & '\Test.exe" /fileversion 1.0.0.0"')

Which produced this

You can keep adding params from the list Nine posted on the first page, such as /companyname or /legalcopyright etc. Just change the Paths PATH_TO_AU2EXE,  PATH_TO_SCRIPT_TO_COMPILE and OUTPUT_PATH to your needs.

RunWait('"PATH_TOAU2EXE"  /in "' & 'PATH_TO_SCRIPT_TO_COMPILE' & '" /out "' &OUTPUT_PATH" /fileversion 1.0.0.0"')

But make sure you keep the double quotes.

 

Edited November 24, 2023 by donnyh13

[Jos]

Not sure why you like to use the commandline versus the available directives? is the info coming from an external process?

Edited November 24, 2023 by Jos

[web2win]

I made some progress...

First I compiled AutoIt3Wrapper.au3 to exe (using Aut2exe.exe)

Then I added these lines to MyApp.au3

#AutoIt3Wrapper_Run_SciTE_Minimized=Y
#AutoIt3Wrapper_Run_SciTE_OutputPane_Minimized=Y
#AutoIt3Wrapper_Aut2exe=Y
#AutoIt3Wrapper_AutoIt3=Y

#AutoIt3Wrapper_Res_Comment=this is a comment
#AutoIt3Wrapper_Res_Description=MyApp
#AutoIt3Wrapper_Res_Fileversion=1
#AutoIt3Wrapper_Res_FileVersion_AutoIncrement=
#AutoIt3Wrapper_Res_ProductName=the name
#AutoIt3Wrapper_Res_ProductVersion=22
#AutoIt3Wrapper_Res_Language=1032
#AutoIt3Wrapper_Res_LegalCopyright=2023
#AutoIt3Wrapper_res_requestedExecutionLevel=
#AutoIt3Wrapper_res_Compatibility=
#AutoIt3Wrapper_Res_SaveSource=

 

And this command line does exactly what I want:

AutoIt3Wrapper.exe /in MyApp.au3

BUT There is still one glitch I have to resolve... It only works from a subfolder of SciTE. 
(although I have uninstalled both AutoIt and SciTE from my system registry)

Does anyone know why it won't run from another folder?

.

[web2win]

RE: is the info coming from an external process?

 

Yes, I am making a utility that compiles HTML web content into Windows exe apps.

And AutoIt seems to be the best tool for it...

(90% finished)

[Jos]

It need the aut2exe in the directory one level up by default. Add the directive for the autoitdirecory to hardcode that and things should work.

Edited November 24, 2023 by Jos

[web2win]

26 minutes ago, Jos said:

It need the aut2exe in the directory one level up by default. Add the directive for the autoitdirecory to hardcode that and things should work.

What is the directive for the autoitdirecory ? A line of code in my au3 -  or an included file? (I am still learning) ...

[Jos]

1 hour ago, web2win said:

Then I added these lines to MyApp.au3

#AutoIt3Wrapper_Run_SciTE_Minimized=Y
#AutoIt3Wrapper_Run_SciTE_OutputPane_Minimized=Y
#AutoIt3Wrapper_Aut2exe=Y
#AutoIt3Wrapper_AutoIt3=Y

Well i mean these directives, but filled in correctly. the proper syntax is in the helpfile that comes with the full SciTE4Autoit3 installer/zip file.

Those last 2 lines in the quoted part are wrong and should point to the proper full path&exe name for those programs.

You also find the proper directive for the autoit directory in the helpfile, and that is really all you need. Check the console output in case there are still issues as that will explain what is going wrong.

 

Edited November 24, 2023 by Jos

[web2win]

All of these #pragma directives work with my Aut2Exe project

#pragma compile(FileDescription, App)
#pragma compile(ProductName, HTML executable)
#pragma compile(ProductVersion, 1.0)
#pragma compile(FileVersion, 1.0.0.0)
#pragma compile(LegalCopyright, © Copyright)
#pragma compile(LegalTrademarks, 'CompanyTrademark')
#pragma compile(CompanyName, 'myApp & Co')

But this one does not work

#pragma compile(Language, 1033)

I keep getting 1032, English UK - regardless of what value I enter.

language 1031 =German
language 1033 =English US
language 1036 =French

Am I missing an include or something?

 

[Danp2]

What gives you the impression that Language is a valid option for #pragma compile?

[Nine]

And what would you expect from this Language pragma ?  All messages would be in that language ?

[web2win]

All of these #pragma directives work with my Aut2Exe project

#pragma compile(FileDescription, App)
#pragma compile(ProductName, HTML executable)
#pragma compile(ProductVersion, 1.0)
#pragma compile(FileVersion, 1.0.0.0)
#pragma compile(LegalCopyright, © Copyright)
#pragma compile(LegalTrademarks, 'CompanyTrademark')
#pragma compile(CompanyName, 'myApp & Co')

But this one does not work

#pragma compile(Language, 1033)

I keep getting 1032, English UK - regardless of what value I enter.

language 1031 =German
language 1033 =English US
language 1036 =French

Am I missing an include or something?

..............................

but this can change Aut2Exe language resource

#AutoIt3Wrapper_Res_Language

I thought #pragma could too...

 

[Jos]

8 hours ago, web2win said:

but this can change Aut2Exe language resource

#AutoIt3Wrapper_Res_Language

Correct

8 hours ago, web2win said:

I thought #pragma could too...

Nope...

[ioa747]

after some experimentation 

Get/Set Wrapper Directive, and compile  from console

to wok property compile  to CUI

Help How to use: ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2Wrapper -Compile "$ScriptFullPath"
2Wrapper -Compile "D:\005_Test\Test.au3"

2Wrapper -Directive "$ScriptFullPath, $Directive[, $sNewData]"
2Wrapper -Directive "D:\005_Test\Test.au3, Res_Fileversion"
2Wrapper -Directive "D:\005_Test\Test.au3, Res_Fileversion, 0.0.0.10"
2Wrapper -Directive "D:\005_Test\Test.au3, Res_Fileversion;Res_ProductName;Icon"
2Wrapper -Directive "D:\005_Test\Test.au3, Res_Fileversion;Res_ProductName;Icon, 0.0.0.10;Test;shell32-135.ico"

2Wrapper    $CmdLine[1]    $CmdLine[2]

$CmdLine[1] = function e.g.: -Compile ,  -Directive
$CmdLine[2] = "param1[,  param2[,  param3]]"  ;a string separated into parameters by ', '

param1   $ScriptFullPath  e.g.: D:\005_Test\Test.au3
param2   can accept multiple value with ';' delimiters e.g.: Res_Fileversion;Res_ProductName;Icon
param3   can accept multiple value with ';' delimiters e.g.: 0.0.0.10;Test;shell32-135.ico

Edit:
Added special key '*' to the function -Directive

Get value with:
2Wrapper -Directive "D:\005_Test\Test.au3, *"
will export all Directive with value in format  Directive1=value1;Directive2=value2
e.g.: Icon=shell32-134.ico;Res_Description=Open the link from curent line;Res_Fileversion=0.0.0.1;Res_ProductName=Test.au3;Res_Language=1032;Res_Field=fild1|1;Res_Field=fild2|2;Res_Field=fild3|3;AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4

Set value with:
2Wrapper -Directive "D:\005_Test\Test.au3, *, Icon=shell32-134.ico;Res_Description=Open the link from curent line;Res_Fileversion=0.0.0.1;Res_ProductName=Test.au3;Res_Language=1032;Res_Field=fild1|1;Res_Field=fild2|2;Res_Field=fild3|3;AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4"
wipe out the existing directives and add the new

in this way  (special key '*')  he overcomes the weakness  with multiple references with the same name in Res_Field as described below

 

2Wrapper.au3

expandcollapse popup

; https://www.autoitscript.com/forum/topic/211150-aut2exe-no-program-description-details/page/2/#comment-1527481
#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Outfile=2Wrapper.exe
#AutoIt3Wrapper_Change2CUI=y
#AutoIt3Wrapper_Res_Description=Get/Set Wrapper Directive from cmd
#AutoIt3Wrapper_Res_Fileversion=0.0.3.20231202
#AutoIt3Wrapper_Res_ProductName=2Wrapper.au3
#AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

#include <Array.au3>
#include <File.au3>
#include <Process.au3>

; for debug replace ;ConsoleWrite(@ScriptLineNumber & ") " &
; with               ConsoleWrite(@ScriptLineNumber & ") " &
;*************************************************************
If $CmdLine[0] > 1 Then ; examle if no parameters
    ;ConsoleWrite(@ScriptLineNumber & ") " & "$CmdLine[0]=" & $CmdLine[0] & @CRLF)
    ;ConsoleWrite(@ScriptLineNumber & ") " & "$CmdLine[1]=" & $CmdLine[1] & @CRLF)
    ;ConsoleWrite(@ScriptLineNumber & ") " & "$CmdLine[2]=" & $CmdLine[2] & @CRLF)

    Global $aParams = StringSplit($CmdLine[2], ", ", 1)
    ;ConsoleWrite(@ScriptLineNumber & ") " & "$aParams[0]=" & $aParams[0] & @CRLF)

    Global $ScriptFullPath, $Return

    Switch $CmdLine[1]
        Case "-Compile"
            $Return = Wrapper_Compile($aParams[1])
            If $Return = 1 Then
                ConsoleWrite("Success -Compile Wrapper" & @CRLF)
            Else
                ConsoleWrite("Failure -Compile Wrapper" & @CRLF)
            EndIf

        Case "-Directive"
            If $aParams[0] = 3 Then
                $Return = Wrapper_Directive($aParams[1], $aParams[2], $aParams[3])
                ConsoleWrite($Return)
            ElseIf $aParams[0] = 2 Then
                $Return = Wrapper_Directive($aParams[1], $aParams[2])
                ConsoleWrite($Return)
            Else
                ConsoleWrite("-> wrong number of parameters <-" & @CRLF)
            EndIf

    EndSwitch
Else
    ConsoleWrite("-> without command line parameters <-" & @CRLF)
    ConsoleWrite("" & @CRLF)
    Global $sTxt = ""
    $sTxt &= "Help How to use: ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~" & @CRLF
    $sTxt &= '2Wrapper -Compile "$ScriptFullPath"' & @CRLF
    $sTxt &= '2Wrapper -Compile "D:\005_Test\Test.au3"' & @CRLF
    $sTxt &= "" & @CRLF
    $sTxt &= '2Wrapper -Directive "$ScriptFullPath, $Directive[, $sNewData]"' & @CRLF
    $sTxt &= '2Wrapper -Directive "D:\005_Test\Test.au3, Res_Fileversion"' & @CRLF
    $sTxt &= '2Wrapper -Directive "D:\005_Test\Test.au3, Res_Fileversion, 0.0.0.10"' & @CRLF
    $sTxt &= '2Wrapper -Directive "D:\005_Test\Test.au3, Res_Fileversion;Res_ProductName;Icon"' & @CRLF
    $sTxt &= '2Wrapper -Directive "D:\005_Test\Test.au3, Res_Fileversion;Res_ProductName;Icon, 0.0.0.10;Test;shell32-135.ico"' & @CRLF
    $sTxt &= "" & @CRLF
    $sTxt &= "2Wrapper $CmdLine[1] $CmdLine[2]" & @CRLF
    $sTxt &= "" & @CRLF
    $sTxt &= "$CmdLine[1] = function e.g.: -Compile ,  -Directive" & @CRLF
    $sTxt &= "$CmdLine[2] = ""param1[, param2[, param3]]""  ;a string separated into parameters by ', '" & @CRLF
    $sTxt &= "" & @CRLF
    $sTxt &= "param1  $ScriptFullPath  e.g.: D:\005_Test\Test.au3" & @CRLF
    $sTxt &= "param2  can accept multiple value with ';' delimiters e.g.: Res_Fileversion;Res_ProductName;Icon" & @CRLF
    $sTxt &= "param3  can accept multiple value with ';' delimiters e.g.: 0.0.0.10;Test;shell32-135.ico " & @CRLF
    $sTxt &= "" & @CRLF
    $sTxt &= "Special key '*' to the function -Directive" & @CRLF
    $sTxt &= "" & @CRLF
    $sTxt &= "Get value with:" & @CRLF
    $sTxt &= "2Wrapper -Directive ""D:\005_Test\Test.au3, *""" & @CRLF
    $sTxt &= "will export all Directive with value in format  Directive1=value1;Directive2=value2" & @CRLF
    $sTxt &= "e.g.: Icon=shell32-134.ico;Res_Description=Open the link from curent line;Res_Fileversion=0.0.0.1;Res_ProductName=Test.au3;Res_Language=1032;Res_Field=fild1|1;Res_Field=fild2|2;Res_Field=fild3|3;AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4" & @CRLF
    $sTxt &= "" & @CRLF
    $sTxt &= "Set value with:" & @CRLF
    $sTxt &= "2Wrapper -Directive ""D:\005_Test\Test.au3, *, Icon=shell32-134.ico;Res_Description=Open the link from curent line;Res_Fileversion=0.0.0.1;Res_ProductName=Test.au3;Res_Language=1032;Res_Field=fild1|1;Res_Field=fild2|2;Res_Field=fild3|3;AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4""" & @CRLF
    $sTxt &= "wipe out the existing directives and add the new " & @CRLF

    ConsoleWrite($sTxt & @CRLF)


EndIf
;*************************************************************
Exit


;----------------------------------------------------------------------------------------
Func Wrapper_Compile($ScriptFullPath)
    ;"C:\Program Files (x86)\AutoIt3\SciTE\..\AutoIt3.exe" "C:\Program Files (x86)\AutoIt3\SciTE\AutoIt3Wrapper\AutoIt3Wrapper.au3" /ShowGui /in "%l"
    Local $Cmd = '"' & @AutoItExe & '" "' & StringTrimRight(@AutoItExe, 12) & '\SciTE\AutoIt3Wrapper\AutoIt3Wrapper.au3" /in "' & $ScriptFullPath & '"'
    ConsoleWrite("$Cmd=" & $Cmd & @CRLF)

    RunWait($Cmd)
    If @error Then Return SetError(@error, @extended, 0)
    Return 1
EndFunc   ;==>Wrapper_Compile
;----------------------------------------------------------------------------------------
Func Wrapper_Directive($ScriptFullPath, $Directive, $sNewData = "")

    Local $aScriptFile = FileReadToArray($ScriptFullPath)
    Local $iLineCount = @extended
    Local $aWrapper[1][3], $index ;= 0
    Local $sWrap, $aSplit, $sResult, $sNewLine, $aDrctv, $aData, $SET_MODE, $DirectiveExist, $WrapperLastLine, $iRgStart

    $aWrapper[0][0] = 0         ; Name
    $aWrapper[0][1] = "Value:"  ; Value
    $aWrapper[0][2] = "Line:"   ; Line

    If @error Then
        ConsoleWrite("There was an error reading the file. @error: " & @error & @CRLF) ; An error occurred reading the current script file.
    Else
        ;_ArrayDisplay($aScriptFile, "$aScriptFile")
        For $i = 0 To $iLineCount - 1
            If $i > 20 Then ExitLoop ; check only the first 20 line <-----
            Select
                Case $aScriptFile[$i] = "#Region ;**** Directives created by AutoIt3Wrapper_GUI ****"
                    $iRgStart = $i
                    ContinueLoop

                Case StringLeft($aScriptFile[$i], 16) = "#AutoIt3Wrapper_"
                    $aSplit = StringSplit($aScriptFile[$i], "=", 1)

                    If $aSplit[0] > 1 Then
                        $sWrap = ""
                        For $x = 2 To $aSplit[0]
                            $sWrap &= $aSplit[$x] & "="
                        Next

                        $sWrap = StringTrimRight($sWrap, 1)
                        ;ConsoleWrite(@ScriptLineNumber & ") " & "line=" & $i + 1 & @TAB & $aSplit[1] & " == " & $sWrap & @CRLF)

                        $index = UBound($aWrapper)
                        ReDim $aWrapper[$index + 1][3]
                        $aWrapper[0][0] = $index
                        $aWrapper[$index][0] = StringTrimLeft($aSplit[1], 16) ; Name
                        $aWrapper[$index][1] = $sWrap ; Value
                        $aWrapper[$index][2] = $i ; Line
                    EndIf

                    ;Case Else ; If nothing matches then execute the following.

            EndSelect

        Next ;line

        ;ConsoleWrite(@ScriptLineNumber & ") " & "$aWrapper[0][0]=" & $aWrapper[0][0] & @CRLF)
        ;_ArrayDisplay($aWrapper, "#AutoIt3Wrapper_")

        $aDrctv = StringSplit($Directive, ";", 1)
        $aData = StringSplit($sNewData, ";", 1)
        If StringLen($sNewData) > 0 Then $SET_MODE = 1

        For $x = 1 To $aDrctv[0]

            If $SET_MODE = 1 Then
                ;"--- SET_MODE ---"

                If $aDrctv[$x] = "*" Then ; * <- Special to get all Directive
                    If $aWrapper[0][0] > 0 Then
                        _ArrayDelete($aScriptFile, $aWrapper[1][2] & '-' & $aWrapper[$aWrapper[0][0]][2])
                        _ArrayDelete($aWrapper, '1-' & $aWrapper[0][0])
                        $aWrapper[0][0] = 0
                    Else
                        $iRgStart = -1
                    EndIf
                    Local $aTmp = $aData
                    For $i = 1 To $aTmp[0]
                        $aData = StringSplit($aTmp[$i], "=", 1)

                        $index = UBound($aWrapper)
                        ReDim $aWrapper[$index + 1][3]
                        $aWrapper[0][0] = $index
                        $aWrapper[$index][0] = $aData[1]     ; Name
                        $aWrapper[$index][1] = $aData[2]     ; Value
                        $aWrapper[$index][2] = $index     ; Line

                        $sNewLine = "#AutoIt3Wrapper_" & $aData[1] & "=" & $aData[2]
                        _ArrayInsert($aScriptFile, $iRgStart + $i, $sNewLine)
                        $sResult &= $aWrapper[$i][0] & "=" & $aWrapper[$i][1] & @LF
                    Next
                    $sResult &= ";"
                    _FileWriteFromArray($ScriptFullPath, $aScriptFile, 0)
                    ExitLoop
                Else
                    $sNewLine = "#AutoIt3Wrapper_" & $aDrctv[$x] & "=" & $aData[$x]
                    ;ConsoleWrite(@ScriptLineNumber & ") " & "$sNewLine=" & $sNewLine & @CRLF)
                    $WrapperLastLine = 0
                    $DirectiveExist = 0
                    For $i = 1 To $aWrapper[0][0]
                        ;ConsoleWrite(@ScriptLineNumber & ") " & $i & ") $aWrapper=" & $aWrapper[$i][0] & @CRLF)
                        If $aWrapper[$i][0] = $aDrctv[$x] Then
                            $DirectiveExist = 1
                            ExitLoop
                        EndIf
                    Next

                    If $aWrapper[0][0] > 0 Then
                        ;*** Update Wrapper
                        If $DirectiveExist = 1 Then
                            $aWrapper[$i][1] = $aData[$x]
                            $aScriptFile[$aWrapper[$i][2]] = $sNewLine
                        Else
                            $WrapperLastLine = _ArrayMax($aWrapper, 1, 0, -1, 2)
                            ;ConsoleWrite(@ScriptLineNumber & ") " & "$WrapperLastLine=" & $WrapperLastLine & @CRLF)
                            _ArrayInsert($aScriptFile, $WrapperLastLine + 1, $sNewLine)

                            $index = UBound($aWrapper)
                            ReDim $aWrapper[$index + 1][3]
                            $aWrapper[0][0] = $index
                            $aWrapper[$index][0] = $aDrctv[$x] ; Name
                            $aWrapper[$index][1] = $aData[$x] ; Value
                            $aWrapper[$index][2] = $WrapperLastLine + 1 ; Line
                        EndIf
                    Else
                        ;*** New Wrapper
                        _ArrayInsert($aScriptFile, $WrapperLastLine, $sNewLine)
                        $index = UBound($aWrapper)
                        ReDim $aWrapper[$index + 1][3]
                        $aWrapper[0][0] = $index
                        $aWrapper[$index][0] = $aDrctv[$x] ; Name
                        $aWrapper[$index][1] = $aData[$x] ; Value
                        $aWrapper[$index][2] = $WrapperLastLine + 1 ; Line
                    EndIf
                    ; Write array to Script file
                    _FileWriteFromArray($ScriptFullPath, $aScriptFile, 0)
                EndIf
            EndIf

            ;"--- GET_MODE ---"
            If $aDrctv[$x] = "*" Then ; * <- Special to get all Directive
                For $i = 1 To $aWrapper[0][0]
                    ;ConsoleWrite(@ScriptLineNumber & ") " & $i & ") $aWrapper=" & $aWrapper[$i][0] & @CRLF)
                    $sResult &= $aWrapper[$i][0] & "=" & $aWrapper[$i][1] & ";"
                Next
            Else
                For $i = 1 To $aWrapper[0][0]
                    ;ConsoleWrite(@ScriptLineNumber & ") " & $i & ") $aWrapper=" & $aWrapper[$i][0] & @CRLF)
                    If $aWrapper[$i][0] = $aDrctv[$x] Then
                        $sResult &= $aWrapper[$i][1] & ";"
                        ExitLoop
                    EndIf
                Next
            EndIf
        Next
        $sResult = StringTrimRight($sResult, 1)
        ;ConsoleWrite(@ScriptLineNumber & ") " & "$sResult=" & $sResult & @CRLF)
        Return $sResult
    EndIf

    Return SetError(1, 0, "")
EndFunc   ;==>Wrapper_Directive

 

the script has a weakness  with multiple references with the same name in Res_Field like:
#AutoIt3Wrapper_Res_Field=fild1|1
#AutoIt3Wrapper_Res_Field=fild2|2
#AutoIt3Wrapper_Res_Field=fild3|3
only the first is accepted
 

Edited December 2, 2023 by ioa747
Added special key '*' to the function -Directive

[Jos]

8 hours ago, ioa747 said:

there is a bug with multiple references with the same name in Res_Field like:
#AutoIt3Wrapper_Res_Field=fild1|1
#AutoIt3Wrapper_Res_Field=fild2|2
#AutoIt3Wrapper_Res_Field=fild3|3
only the first is accepted
Perhaps in the future

Can't find an reproducer in your post, so could you post one or did I miss it?

[ioa747]

8 minutes ago, Jos said:

Can't find an reproducer in your post

What do you mean, how does it start?

in cmd console

2Wrapper.exe    $CmdLine[1]    $CmdLine[2]

[Jos]

I quoted the part where you state that there is a problem with the res_field not updating with the same name but next you post something with different names, hence my question. Post an simple reproducer so I can check and understand.  

Edited December 1, 2023 by Jos

[ioa747]

The BUG is mine it's an inability to be able to update the array

Edit:
I reworded it

Edited December 1, 2023 by ioa747