How to make adquate function to: Visual Basic Syntax: Object.BackgroundColor=RGB(255,0,0)

[mLipok]

I have some Object which VB examles uses:
 

Quote

Object.BackgroundColor=RGB(255,0,0)

How I should pass RGB(255,0,0) in AutoIt ?

Edited October 26, 2023 by mLipok

[ioa747]

If that helps

$col = HexToRGB("0x84ACF0")

$col2 = RGBToHex($col[0], $col[1], $col[2])
ConsoleWrite("$col2=" & $col2 & @CRLF)

;----------------------------------------------------------------------------------------
Func HexToRGB($HexColor)

    Local $aSplit = StringSplit($HexColor, "")
    Local $RGB[3]

    If $aSplit[0] = 8 Then
        $RGB[0] = Dec($aSplit[3] & $aSplit[4], 0)
        $RGB[1] = Dec($aSplit[5] & $aSplit[6], 0)
        $RGB[2] = Dec($aSplit[7] & $aSplit[8], 0)
        ;ConsoleWrite("RGB(" & $RGB[0] & "," & $RGB[1] & "," & $RGB[2] & ")" & @CRLF)
        Return $RGB
    Else
        ConsoleWrite("Something wrong $aSplit[0]=" & $aSplit[0] & @CRLF)
    EndIf
EndFunc   ;==>HexToRGB
;----------------------------------------------------------------------------------------
Func RGBToHex($R, $G, $B)
    $sColor = "0x"
    $sColor &= Hex($R, 2)
    $sColor &= Hex($G, 2)
    $sColor &= Hex($B, 2)
    ;ConsoleWrite("$sColor=" & $sColor & @CRLF)
    Return $sColor
EndFunc
;----------------------------------------------------------------------------------------

 

Edited October 26, 2023 by ioa747

[Andreik]

The question is a little bit vague. RGB function in VB returns a long number representing an RGB color value. Basically you don't have to do anything special in order to pass RGB(255,0,0) unless you don't know how each channel value is represented as hex value. If your question is simply about passing data, in your specific case you can simply pass the value 0xFF0000 and you are fine but if you don't know how each channel is combined to get the final RGB value then @ioa747's example is your answer.

[mLipok]

Hey guys thanks for help.
I hit other problem:

 

According to CHM documentation
This property is Read/Write.

Reading that I was expecting that it will let me Write/Set the value but then I try to Read/Get the value  and then I hit the same issue.

according to CHM documentation
This property is Read/Write.

Reading that I was expecting that it will let me Write/Set the value but then I try to Read/Get the value  and then I hit the same issue.

Then I check TLBViewer and I notice that OCZ internally has typo.
When I use
$oPDFViewer1.BackgroudColor
instead
$oPDFViewer1.BackgroundColor

And after I use this misspeled property name all works fine.

 

btw.
Finally I stick with such solution:
 

$oPDFViewer1.BackgroudColor = _ColorSetRGB(StringSplit('111,100,200', ',', $STR_NOCOUNT))

 

[Andreik]

4 minutes ago, mLipok said:

Then I check TLBViewer and I notice that OCZ internally has typo.

This kind of issues can drive someone crazy.

[UEZ]

What about this?

;Coded by UEZ build 2023-10-30

ConsoleWrite(Hex(RGB(255,0,0)) & @CRLF)
ConsoleWrite(Hex(ARGB(128,80,120,240)) & @CRLF)


Func RGB($r, $g, $b)
    Return BitOR(BitShift(Max(0, Min(255, $r)), -16), BitShift(Max(0, Min(255, $g)), -8), Int(Max(0, Min(255, $b))))
EndFunc

Func ARGB($a, $r, $g, $b)
    Return BitOR(BitShift(Max(0, Min(255, $a)), -24), BitShift(Max(0, Min(255, $r)), -16), BitShift(Max(0, Min(255, $g)), -8), Int(Max(0, Min(255, $b))))
EndFunc

Func Min($a, $b)
    Return $a < $b ? $a : $b
EndFunc

Func Max($a, $b)
    Return $a > $b ? $a : $b
EndFunc

 

Edited October 30, 2023 by UEZ
Added check for numbers outside valid range (0 - 255)