Which Debugger do you use?

[noellarkin]

So far, I've stuck to MsgBox and ConsoleWrite to debug scripts (+some SciTE Syntax Checks), but looking for something a little better.

It seems both Heron's Debugger: http://www.autoitscript.com/forum/index.php?showtopic=103142

and "Another Debugger for Autoit"

have been abandoned. I'm curious what tools forum members are using to debug scripts?

[Andreik]

ConsoleWrite() works just fine for me. I never used something else.

[water]

+ _ArrayDisplay
+ FileWriteLine to write some info to a log file

[Melba23]

noellarkin,

ConsoleWrite, MsgBox (or ExtMsgBox  ) and (Debug)ArrayDisplay have always been sufficient to date.

M23

[TheDcoder]

The full version of SciTE also has a very useful trace feature with ConsoleLog, I've used it several times to track tricky bugs.

[Musashi]

9 hours ago, noellarkin said:

I'm curious what tools forum members are using to debug scripts?

There are some beneficial keyboard shortcuts for debugging.

Example : 

Local $iCount = 0
For $i = 1 To 5
     $iCount += $i * 2
Next

Place the mouse cursor on the $iCount variable in the loop.

Now use ALT-D (without the - character, of course ). This will automatically insert a ConsoleWrite statement.

With CTRL-SHIFT-D a MsgBox is inserted analogously.

With CTRL-ALT-Z all lines inserted in this way can be removed.

 

[AGlassman]

I sprinkle my code with calls to this func. Disable/enable with a Ctrl-Q as needed. Shows me the Function , step, and multiple variable names and values on one line.  (All of my Func have a "Local Const $ThisFunc = "Func Name" line right after the Func definition).
 

expandcollapse popup

#include-once

; =====================================================================
;
;   #include "HotRod\hr_Debug_Print.au3"
;
;   Example Calls:
;
;   hr_Debug_Print( $ThisFunc, "StepName", "MsgText", "$P1Name", $P1Value, ... )
;   hr_Debug_Print( $ThisFunc, "StepName", Default, "$P1Name", $P1Value, ... )
;   hr_Debug_Print( $ThisFunc, Default, Default, "$P1Name", $P1Value, ... )
;
;   hr_Debug_Print( $ThisFunc, "StepName", _
;       "MsgText", _
;       "$P1Name", $P1Value, ... )
;
; =====================================================================

Func hr_Debug_Print( _
    Const $FuncName = Default, _
    $StepName = Default, _
    $MsgText = Default, _
    $P1Name = Default, $P1Value = Default, _
    $P2Name = Default, $P2Value = Default, _
    $P3Name = Default, $P3Value = Default, _
    $P4Name = Default, $P4Value = Default, _
    $P5Name = Default, $P5Value = Default, _
    $P6Name = Default, $P6Value = Default, _
    $P7Name = Default, $P7Value = Default, _
    $P8Name = Default, $P8Value = Default, _
    $P9Name = Default, $P9Value = Default _
    )

    Local $MsgStrg = "DEBUG_PRINT"

    If NOT ( ( $FuncName = Default ) OR ( $FuncName = "")  ) Then
        $MsgStrg = $MsgStrg & " | " & $FuncName
    EndIf

    If NOT ( ( $StepName = Default ) OR ( $StepName = "")  ) Then
        $MsgStrg = $MsgStrg & " | " & $StepName
    EndIf

    If NOT ( ( $MsgText = Default ) OR ( $MsgText = "")  ) Then
        $MsgStrg = $MsgStrg & " | " & $MsgText
    EndIf

    If $P1Name <> Default Then $MsgStrg = $MsgStrg & " | " & $P1Name & ": '" & $P1Value & "'"
    If $P2Name <> Default Then $MsgStrg = $MsgStrg & " | " & $P2Name & ": '" & $P2Value & "'"
    If $P3Name <> Default Then $MsgStrg = $MsgStrg & " | " & $P3Name & ": '" & $P3Value & "'"
    If $P4Name <> Default Then $MsgStrg = $MsgStrg & " | " & $P4Name & ": '" & $P4Value & "'"
    If $P5Name <> Default Then $MsgStrg = $MsgStrg & " | " & $P5Name & ": '" & $P5Value & "'"
    If $P6Name <> Default Then $MsgStrg = $MsgStrg & " | " & $P6Name & ": '" & $P6Value & "'"
    If $P7Name <> Default Then $MsgStrg = $MsgStrg & " | " & $P7Name & ": '" & $P7Value & "'"
    If $P8Name <> Default Then $MsgStrg = $MsgStrg & " | " & $P8Name & ": '" & $P8Value & "'"
    If $P9Name <> Default Then $MsgStrg = $MsgStrg & " | " & $P9Name & ": '" & $P9Value & "'"

    ConsoleWrite( $MsgStrg & @CRLF )

EndFunc

 

[seadoggie01]

I've written a couple of functions that I use everywhere, saved them as "CustomDebugging.au3" in my includes folder, and included them in every script. The basic idea was:

; Calls Debug with a custom message. Uses '!' as a prefix to make the text red in the debugger.
; I set mine up to let SciTE jump to the right line... like you see with a compile error
Func ErrMsg($sMsg = "", $iError = @error, $iExtended = @extended, $iScriptLineNum = @ScriptLineNumber)
    ; If there is an error, then write the error message
    If $iError Then
        ; I also added this later to simplify the function call
        If IsFunc($sMsg) Then $sMsg = FuncName($sMsg)
        Local $sText = '"' & @ScriptFullPath & '" (' & $iScriptLineNum & ',5) : (See below for message)' & @CRLF
        $sText &= "! Error: " & $iError & " - "
        If $iExtended <> 0 Then $sText &= "Extended: " & $iExtended & " - "
        Debug($sText & $sMsg, "")
    EndIf
    ; Preserve the error
    Return SetError($iError, $iExtended, $iError)
    
EndFunc

; a wrapper around ConsoleWrite... mostly because I always forget to add a newline
Func Debug($sMsg, $sPrefix = "+")
    If $sPrefix <> "" Then $sPrefix &= " "
    ConsoleWrite($sPrefix & $sMsg & @CRLF)
EndFunc

Func Examples()
    Local $aFiles = _FileListToArray(@UserProfileDir)
    If ErrMsg(_FileListToArray) Then Exit
    
    Debug("Found " & $aFiles[0]  & " files")
    
EndFunc

I (even) later added options to write messages to a log file (the name of the log and if it should write).

I did a few things right and more than a couple wrong and it's a bit of a mess now because of my refusal to fix all my old scripts. I'd suggest writing your own and making it work for you.

One thing I wish I'd done differently would be to use best practices in naming my functions: _<name of include>_<function name>  I'd be much easier for me to fix some of my mistakes if I'd done that. So I would've named the include Debug.au3 and renamed the functions _Debug_Debug and _Debug_ErrMsg, but with the time I saved from not writing _Debug_ so many times, I wrote this post