Special effect for the mouse cursor.

[Emerogork]

Can  I create a ring with a clear center?

[Emerogork]

Now, how does one T a TSR? I can reset the computer or go to the task manager but is there a more civilizer way to do it?

[ioa747]

esc ?

[argumentum]

Terminate and Stay Resident = TSR, is a concept from the days of DOS. One would have to code a TSR if one wanted a program not to close when using another. Single thread ?.
But since I'm that old I understood what he meant. Basically running in the background. Hence I helped but I'm not with the knowledge to code it.

Anyway, I hope that the concept of TSR is understood  

k, g'night now

Edited August 22, 2023 by argumentum
spelling

[argumentum]

..gotta catch some ZZzzz. Look, the best way to close this script is with a tray menu. Using the ESC key will close the program unwillingly, or not close it at all, with all these ESC to exit scripts. So yes, tray menu is the way to go. And if you get fancy maybe add options in the tray menu for colors and what not  

[pixelsearch]

I scripted the following, to circle the moving mouse pointer without using a GUI or GDI+
It uses GDI and the circle is not solid (hollowed in its center)

Exit the script with F10 or with system tray icon (resources should be correctly release in both cases, because of OnAutoItExitRegister)

expandcollapse popup

#include <WinAPIGdi.au3>
#include <WinAPISysWin.au3>
#include <WindowsConstants.au3>

OnAutoItExitRegister(_AutoQuit)
HotKeySet("{F10}", "_Exit")

Local $tRECT, $tRECT2, $hDesktop = _WinAPI_GetDesktopWindow()

Local $hDC = _WinAPI_GetWindowDC(0) ; 0 = retrieve the Device Context for the entire screen.
Local $hPen = _WinAPI_CreatePen($PS_SOLID, 5, 0x0000FF) ; style, width, color (BGR)
Local $h_OrigPen = _WinAPI_SelectObject($hDC, $hPen)
Local $hBrush = _WinAPI_CreateBrushIndirect($BS_HOLLOW, 0, 0) ; 2nd/3rd param. ignored when 1st is $BS_HOLLOW
Local $h_OrigBrush = _WinAPI_SelectObject($hDC, $hBrush)

Local $aPos = MouseGetPos()
Local $iX_Old = $aPos[0], $iY_Old = $aPos[1]

While 1
    $aPos = MouseGetPos()
    If $iX_Old <> $aPos[0] Or $iY_Old <> $aPos[1] Then
        _DrawCircle($aPos[0], $aPos[1])
        $iX_Old = $aPos[0]
        $iY_Old = $aPos[1]
    EndIf
    Sleep(10)
WEnd

;======================================
Func _DrawCircle($iX, $iY)
    $tRECT = _WinAPI_CreateRect($iX - 25, $iY - 25, $iX + 25, $iY + 25)
    $tRECT2 = _WinAPI_CreateRect($iX - 30, $iY - 30, $iX + 30, $iY + 30)
    _WinAPI_Ellipse($hDC, $tRECT)
    Sleep(20)

    ; _WinAPI_RedrawWindow($hDesktop, 0, 0, $RDW_INVALIDATE + $RDW_ALLCHILDREN)
    ; _WinAPI_RedrawWindow($hDesktop, $tRECT, 0, $RDW_INVALIDATE + $RDW_ALLCHILDREN)
    _WinAPI_RedrawWindow($hDesktop, $tRECT2, 0, $RDW_INVALIDATE + $RDW_ALLCHILDREN)
EndFunc

;======================================
Func _Exit() ; F10
    Exit
EndFunc

;======================================
Func _AutoQuit() ; OnAutoItExitRegister => safe to close script via system tray icon.
    _WinAPI_RedrawWindow($hDesktop, 0, 0, $RDW_INVALIDATE + $RDW_ALLCHILDREN)
    _WinAPI_SelectObject($hDC, $h_OrigBrush)
    _WinAPI_DeleteObject($hBrush)
    _WinAPI_SelectObject($hDC, $h_OrigPen)
    _WinAPI_DeleteObject($hPen)
    _WinAPI_ReleaseDC(0, $hDC)
EndFunc

If you guys have ideas to improve the script, please share your comments.
Thanks and have a great day.

[AllenAA]

56 minutes ago, pixelsearch said:

I scripted the following, to circle the moving mouse pointer without using a GUI or GDI+
It uses GDI and the circle is not solid (hollowed in its center)

Exit the script with F10 or with system tray icon (resources should be correctly release in both cases, because of OnAutoItExitRegister)

expandcollapse popup

#include <WinAPIGdi.au3>
#include <WinAPISysWin.au3>
#include <WindowsConstants.au3>

OnAutoItExitRegister(_AutoQuit)
HotKeySet("{F10}", "_Exit")

Local $tRECT, $tRECT2, $hDesktop = _WinAPI_GetDesktopWindow()

Local $hDC = _WinAPI_GetWindowDC(0) ; 0 = retrieve the Device Context for the entire screen.
Local $hPen = _WinAPI_CreatePen($PS_SOLID, 5, 0x0000FF) ; style, width, color (BGR)
Local $h_OrigPen = _WinAPI_SelectObject($hDC, $hPen)
Local $hBrush = _WinAPI_CreateBrushIndirect($BS_HOLLOW, 0, 0) ; 2nd/3rd param. ignored when 1st is $BS_HOLLOW
Local $h_OrigBrush = _WinAPI_SelectObject($hDC, $hBrush)

Local $aPos = MouseGetPos()
Local $iX_Old = $aPos[0], $iY_Old = $aPos[1]

While 1
    $aPos = MouseGetPos()
    If $iX_Old <> $aPos[0] Or $iY_Old <> $aPos[1] Then
        _DrawCircle($aPos[0], $aPos[1])
        $iX_Old = $aPos[0]
        $iY_Old = $aPos[1]
    EndIf
    Sleep(10)
WEnd

;======================================
Func _DrawCircle($iX, $iY)
    $tRECT = _WinAPI_CreateRect($iX - 25, $iY - 25, $iX + 25, $iY + 25)
    $tRECT2 = _WinAPI_CreateRect($iX - 30, $iY - 30, $iX + 30, $iY + 30)
    _WinAPI_Ellipse($hDC, $tRECT)
    Sleep(20)

    ; _WinAPI_RedrawWindow($hDesktop, 0, 0, $RDW_INVALIDATE + $RDW_ALLCHILDREN)
    ; _WinAPI_RedrawWindow($hDesktop, $tRECT, 0, $RDW_INVALIDATE + $RDW_ALLCHILDREN)
    _WinAPI_RedrawWindow($hDesktop, $tRECT2, 0, $RDW_INVALIDATE + $RDW_ALLCHILDREN)
EndFunc

;======================================
Func _Exit() ; F10
    Exit
EndFunc

;======================================
Func _AutoQuit() ; OnAutoItExitRegister => safe to close script via system tray icon.
    _WinAPI_RedrawWindow($hDesktop, 0, 0, $RDW_INVALIDATE + $RDW_ALLCHILDREN)
    _WinAPI_SelectObject($hDC, $h_OrigBrush)
    _WinAPI_DeleteObject($hBrush)
    _WinAPI_SelectObject($hDC, $h_OrigPen)
    _WinAPI_DeleteObject($hPen)
    _WinAPI_ReleaseDC(0, $hDC)
EndFunc

If you guys have ideas to improve the script, please share your comments.
Thanks and have a great day.

The effect I tested on win7 is not ideal.

[ioa747]

5 hours ago, Emerogork said:

Can  I create a ring with a clear center?

I made an effort

expandcollapse popup

; https://www.autoitscript.com/forum/topic/209550-tray-example/

#AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w- 4 -w 5 -w 6 -w 7

#include <StringConstants.au3>
#include <TrayConstants.au3>
#include <GDIPlus.au3>
#include <GuiConstantsEx.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>
#include <Misc.au3>

Opt("TrayMenuMode", 3) ; These are options 1 and 2 for TrayMenuMode.
Opt("TrayOnEventMode", 1) ; Enable TrayOnEventMode.

Global Const $AC_SRC_ALPHA = 1
Global $g_hGUI2, $g_iTranparency, $g_hImage, $g_hImage2
Global $idExit, $idPaused, $bPaused = False

$g_iTranparency = 150 ; * <-------  here set the general ring transparency

_Example()

Func _Example()
    ; Create GUI
    Local $hGUI1 = GUICreate("Alpha Blend", 1, 1, 0, 0)
    GUISetState()

    ; Create layered child window
    $g_hGUI2 = GUICreate("Mouse", 250, 250, -1, -1, -1, BitOR($WS_EX_TOOLWINDOW, $WS_EX_TRANSPARENT, $WS_EX_TOPMOST, $WS_EX_LAYERED), $hGUI1)

    ; Load layered image
    _GDIPlus_Startup()

    $g_hImage = _GDIPlus_ImageLoadFromFile(@ScriptDir & "\ring1.png")
    $g_hImage2 = _GDIPlus_ImageLoadFromFile(@ScriptDir & "\ring2.png")

    SetBitmap($g_hGUI2, $g_hImage, 255)
    GUISetState()


    GUIRegisterMsg($WM_NCHITTEST, "WM_NCHITTEST")

    Local $iMouse1, $iMouse0, $aMpos, $Rclick, $iCycle = 5
    Local $iFade = 0

    SetBitmap($g_hGUI2, $g_hImage, $g_iTranparency)

    TraySetIcon(StringLeft(@AutoItExe, StringInStr(@AutoItExe, "\", $STR_NOCASESENSEBASIC, -1) - 1) & "\Icons\MyAutoIt3_Blue.ico")

    #Region === Tray_Menu ===
    TraySetOnEvent($TRAY_EVENT_PRIMARYDOUBLE, "TogglePause")

    $idPaused = TrayCreateItem("Pause", -1, -1, $TRAY_ITEM_RADIO)
    TrayItemSetOnEvent(-1, "TogglePause")
    TrayItemSetState(-1, $TRAY_UNCHECKED)

    TrayCreateItem("") ; Create a separator line.
    $idExit = TrayCreateItem("Exit")
    TrayItemSetOnEvent(-1, "GoToExit")
    #EndRegion === Tray_Menu ===

    While 1
        $aMpos = MouseGetPos()
        $iMouse0 = $aMpos[0]
        WinMove($g_hGUI2, "", $aMpos[0] - 64, $aMpos[1] - 64)

        If Abs($iMouse1 - $iMouse0) > 30 Then
            $iMouse1 = $iMouse0
            $iCycle = 0
        Else
            $iCycle += 1
        EndIf

        If $iCycle > 40 Then
            $iFade += 1
            If $iFade * 5 > $g_iTranparency Then $iFade = $g_iTranparency / 5
            SetBitmap($g_hGUI2, $g_hImage, $g_iTranparency - ($iFade * 5))
        Else
            $iFade = 0
            SetBitmap($g_hGUI2, $g_hImage, $g_iTranparency)
        EndIf

        If _IsPressed("01") Then
            $Rclick = 5
            $iCycle = 0
        EndIf

        If $Rclick > 0 Then
            SetBitmap($g_hGUI2, $g_hImage2, 200)
            $Rclick -= 1
            $iCycle = 40
        Else
            $Rclick = 0
        EndIf
        _GetTrayStatus()
        Sleep(20)
    WEnd

    GoToExit()
EndFunc   ;==>_Example
;----------------------------------------------------------------------------------------
Func GoToExit()    ; exit
    ; Release resources
    _GDIPlus_ImageDispose($g_hImage)
    _GDIPlus_Shutdown()
    Exit
EndFunc   ;==>GoToExit
;----------------------------------------------------------------------------------------
Func _GetTrayStatus()
    While 1
        If $bPaused = False Then
            ExitLoop
        Else  ; calm down and stay
            Sleep(500)
        EndIf
    WEnd
EndFunc   ;==>_GetTrayStatus
;----------------------------------------------------------------------------------------
Func TogglePause()

    If $bPaused = False Then
        $bPaused = True
        TrayItemSetState($idPaused, $TRAY_CHECKED)    ; $TRAY_UNCHECKED, $TRAY_CHECKED
        TraySetIcon(StringLeft(@AutoItExe, StringInStr(@AutoItExe, "\", $STR_NOCASESENSEBASIC, -1) - 1) & "\Icons\MyAutoIt3_Red.ico")
        GUISetState(@SW_HIDE, $g_hGUI2)
    Else
        $bPaused = False
        TrayItemSetState($idPaused, $TRAY_UNCHECKED)    ; $TRAY_UNCHECKED, $TRAY_CHECKED
        TraySetIcon(StringLeft(@AutoItExe, StringInStr(@AutoItExe, "\", $STR_NOCASESENSEBASIC, -1) - 1) & "\Icons\MyAutoIt3_Blue.ico")
        GUISetState(@SW_SHOW, $g_hGUI2)
    EndIf

EndFunc   ;==>TogglePause
;----------------------------------------------------------------------------------------
; Handle the WM_NCHITTEST for the layered window so it can be dragged by clicking anywhere on the image.
;----------------------------------------------------------------------------------------
Func WM_NCHITTEST($hWnd, $iMsg, $iParam, $lParam)
    #forceref $hWnd, $iMsg, $iParam, $lParam
    If ($hWnd = $g_hGUI2) And ($iMsg = $WM_NCHITTEST) Then Return $HTCAPTION
EndFunc   ;==>WM_NCHITTEST

;----------------------------------------------------------------------------------------
; SetBitMap
;----------------------------------------------------------------------------------------
Func SetBitmap($hGUI, $hImage, $iOpacity)
    Local $hScrDC, $hMemDC, $hBitmap, $hOld, $pSize, $tSize, $pSource, $tSource, $pBlend, $tBlend

    $hScrDC = _WinAPI_GetDC(0)
    $hMemDC = _WinAPI_CreateCompatibleDC($hScrDC)
    $hBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImage)
    $hOld = _WinAPI_SelectObject($hMemDC, $hBitmap)
    $tSize = DllStructCreate($tagSIZE)
    $pSize = DllStructGetPtr($tSize)
    DllStructSetData($tSize, "X", _GDIPlus_ImageGetWidth($hImage))
    DllStructSetData($tSize, "Y", _GDIPlus_ImageGetHeight($hImage))
    $tSource = DllStructCreate($tagPOINT)
    $pSource = DllStructGetPtr($tSource)
    $tBlend = DllStructCreate($tagBLENDFUNCTION)
    $pBlend = DllStructGetPtr($tBlend)
    DllStructSetData($tBlend, "Alpha", $iOpacity)
    DllStructSetData($tBlend, "Format", $AC_SRC_ALPHA)
    _WinAPI_UpdateLayeredWindow($hGUI, $hScrDC, 0, $pSize, $hMemDC, $pSource, 0, $pBlend, $ULW_ALPHA)
    _WinAPI_ReleaseDC(0, $hScrDC)
    _WinAPI_SelectObject($hMemDC, $hOld)
    _WinAPI_DeleteObject($hBitmap)
    _WinAPI_DeleteDC($hMemDC)
EndFunc   ;==>SetBitmap
;----------------------------------------------------------------------------------------

 

ring1.png   

 

ring2.png   

Edited August 22, 2023 by ioa747

[pixelsearch]

@AllenAA thanks for testing. I can't replicate it on my computer (XP) . Could you please try this, replacing this line...

$tRECT2 = _WinAPI_CreateRect($iX - 30, $iY - 30, $iX + 30, $iY + 30) ; ok XP, not ok W7 (AllenAA)

...with that one...

$tRECT2 = _WinAPI_CreateRect($iX - 40, $iY - 40, $iX + 40, $iY + 40)

...and if the issue persists, with that one :

$tRECT2 = _WinAPI_CreateRect($iX - 50, $iY - 50, $iX + 50, $iY + 50)

Thanks
Edited August 22, 2023 by pixelsearch

[Nine]

Another way with pretty much the same original script :

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPIGdi.au3>

Opt("MustDeclareVars", True)

HotKeySet("^!{ESC}", _Exit) ; ctrl-alt Esc
Local $hGui = GUICreate("", 100, 100, 0, 0, $WS_POPUp, $WS_EX_TRANSPARENT + $WS_EX_TOPMOST)
GUISetBkColor(0xFFEA00) ;       * <-- set the color
GUISetState()

Local $aPos = WinGetPos($hGui)

Local $hRgn = _WinAPI_CreateRoundRectRgn(0, 0, $aPos[2], $aPos[3], $aPos[2], $aPos[3])
Local $hRgn2 = _WinAPI_CreateRoundRectRgn(5, 5, $aPos[2]-5, $aPos[3]-5, $aPos[2]-5, $aPos[3]-5)
_WinAPI_CombineRgn($hRgn, $hRgn, $hRgn2, $RGN_DIFF)
_WinAPI_SetWindowRgn($hGui, $hRgn)
_WinAPI_DeleteObject($hRgn2)

Local $iX = $aPos[0], $iY = $aPos[1], $iCount = 0
While Sleep(20)
  $aPos = MouseGetPos()
  If $iX <> $aPos[0] Or $iY <> $aPos[1] Then
    WinMove($hGui, "", $aPos[0] - 50, $aPos[1] - 50)
    WinSetTrans($hGui, '', 100)
    $iX = $aPos[0]
    $iY = $aPos[1]
    $iCount = 0
  Else
    If $iCount = 10 Then ContinueLoop
    $iCount += 0.5  ; set speep of vanishing here
    WinSetTrans($hGui, '', 100 - ($iCount * 10))
  EndIf
WEnd

Func _Exit()
  Exit
EndFunc   ;==>_Exit

 

Edited August 22, 2023 by Nine

[AllenAA]

3 hours ago, pixelsearch said:

@AllenAA thanks for testing. I can't replicate it on my computer (XP) . Could you please try this, replacing this line...

The problem still persists.

 

 

$tRECT2 = _WinAPI_CreateRect($iX - 30, $iY - 30, $iX + 30, $iY + 30) ; ok XP, not ok W7 (AllenAA)

 

...with that one...

 

 

 

 

$tRECT2 = _WinAPI_CreateRect($iX - 40, $iY - 40, $iX + 40, $iY + 40)

 

...and if the issue persists, with that one :

 

 

 

 

$tRECT2 = _WinAPI_CreateRect($iX - 50, $iY - 50, $iX + 50, $iY + 50)

 

Thanks

 

 

[Emerogork]

ioa747, I hit Compile/Build/GO and nothing happening. Is there a way to activate it?

[Jos]

Did you save it with an .au3 suffix?

[argumentum]

Spoiler

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPIGdi.au3>
#include <Misc.au3>
#include <TrayConstants.au3>

Opt("MustDeclareVars", True) ;;; https://www.autoitscript.com/forum/topic/210715-special-effect-for-the-mouse-cursor/?do=findComment&comment=1523224
Opt("TrayMenuMode", 3) ; These are options 1 and 2 for TrayMenuMode.
Opt("TrayOnEventMode", 1) ; Enable TrayOnEventMode.

HotKeySet("^!{ESC}", _Exit) ; ctrl-alt Esc ; ..and/or use the tray
HotKeySet("^!{F1}", TogglePause) ; ctrl-alt F1 to pause/unpause ; ..and/or use the tray

Global $ColorDefault = 0xFF9900
Global $ColorLClick = 0x0099FF
Global $ColorRClick = 0x99FF99
Global $nFadeAway = 1.5
Global $iTranparency = 200 ; * <-------  here set the general ring transparency
Global $iCircleSize = 85
Global $iCircleThickness = 3
Global $iCircleOffCenter = 3

Global $hGui = GUICreate("TheCircleOfMouse", $iCircleSize, $iCircleSize, 0, 0, $WS_POPUP, $WS_EX_TRANSPARENT + $WS_EX_TOPMOST + $WS_EX_TOOLWINDOW)
GUISetBkColor($ColorDefault) ;       * <-- set the color
GUISetState()

Global $hDLL_user32 = DllOpen("user32.dll")
Global $aPos = WinGetPos($hGui), $iWasPressed, $iIsPressed

Global $hRgn = _WinAPI_CreateRoundRectRgn(0, 0, $aPos[2], $aPos[3], $aPos[2], $aPos[3])
Global $hRgn2 = _WinAPI_CreateRoundRectRgn($iCircleThickness, $iCircleThickness, $aPos[2] - $iCircleThickness, $aPos[3] - $iCircleThickness, $aPos[2] - $iCircleThickness, $aPos[3] - $iCircleThickness)
_WinAPI_CombineRgn($hRgn, $hRgn, $hRgn2, $RGN_DIFF)
_WinAPI_SetWindowRgn($hGui, $hRgn)
_WinAPI_DeleteObject($hRgn2)

Global $iX = $aPos[0], $iY = $aPos[1], $iCount = 0, $hTimer = TimerInit()

#Region === Tray_Menu ===
TraySetIcon(StringLeft(@AutoItExe, StringInStr(@AutoItExe, "\", $STR_NOCASESENSEBASIC, -1) - 1) & "\Icons\MyAutoIt3_Blue.ico")
Global $idExit, $idPaused, $bPaused = False
TraySetOnEvent($TRAY_EVENT_PRIMARYUP, TogglePause)
$idPaused = TrayCreateItem("Pause", -1, -1, $TRAY_ITEM_RADIO)
TrayItemSetOnEvent(-1, TogglePause)
TrayItemSetState(-1, $TRAY_UNCHECKED)
TrayCreateItem("") ; Create a separator line.
$idExit = TrayCreateItem("Exit")
TrayItemSetOnEvent(-1, _Exit)
TraySetClick($TRAY_CLICK_SECONDARYUP)
#EndRegion === Tray_Menu ===
Func TogglePause()
    If $bPaused = False Then
        $bPaused = True
        TrayItemSetState($idPaused, $TRAY_CHECKED)    ; $TRAY_UNCHECKED, $TRAY_CHECKED
        TraySetIcon(StringLeft(@AutoItExe, StringInStr(@AutoItExe, "\", $STR_NOCASESENSEBASIC, -1) - 1) & "\Icons\MyAutoIt3_Red.ico")
        GUISetState(@SW_HIDE, $hGui)
    Else
        $bPaused = False
        TrayItemSetState($idPaused, $TRAY_UNCHECKED)    ; $TRAY_UNCHECKED, $TRAY_CHECKED
        TraySetIcon(StringLeft(@AutoItExe, StringInStr(@AutoItExe, "\", $STR_NOCASESENSEBASIC, -1) - 1) & "\Icons\MyAutoIt3_Blue.ico")
        GUISetState(@SW_SHOW, $hGui)
    EndIf
EndFunc   ;==>TogglePause

While Sleep(20)

    If $bPaused Then ContinueLoop

    $iIsPressed = (_IsPressed("01", $hDLL_user32) ? 1 : (_IsPressed("02", $hDLL_user32) ? 2 : 0))
    If $iWasPressed <> $iIsPressed Then
        $hTimer = TimerInit()
        $iWasPressed = $iIsPressed
        Switch $iIsPressed
            Case 1
                GUISetBkColor($ColorLClick) ; left click
            Case 2
                GUISetBkColor($ColorRClick) ; right click
            Case Else
                GUISetBkColor($ColorDefault) ; no click / default
        EndSwitch
    EndIf

    $aPos = MouseGetPos()
    If $iX <> $aPos[0] Or $iY <> $aPos[1] Or TimerDiff($hTimer) < 500 Then
        WinMove($hGui, "", $aPos[0] - $iCircleSize / 2 + $iCircleOffCenter, $aPos[1] - $iCircleSize / 2 + $iCircleOffCenter)
        WinSetTrans($hGui, '', $iTranparency)
        $iX = $aPos[0]
        $iY = $aPos[1]
        $iCount = 0
    Else
        If Not ($iTranparency - ($iCount * 10) > 0 ? $iTranparency - ($iCount * 10) : 0) Then ContinueLoop
        $iCount += $nFadeAway ; 0.5  ; set speed of vanishing here
        WinSetTrans($hGui, '', ($iTranparency - ($iCount * 10) > 0 ? $iTranparency - ($iCount * 10) : 0))
    EndIf
WEnd

Func _Exit()
    GUIDelete()
    Exit
EndFunc   ;==>_Exit

 

..I liked the fading and the tray and added right/left click colors and ... I mixed'em all up    ( like mashed potatoes but with code )

I see that you wanna compile it. Then the icons are not going to be there as when running as a script. Do change those if you are to use the above script.

Edited August 22, 2023 by argumentum
mashed potatoes

[Emerogork]

Difficult to see if these comments are directed to me.

Jos, Yes, au3. I guess I should see some sort of control panel or menu...
argumentum: Do I not need to compile/run?  How do I run it as a script?

Edited August 22, 2023 by Emerogork

[UEZ]

Here another version:

 

[argumentum]

9 minutes ago, Emerogork said:

Do I not need to compile/run?  How do I run it as a script?

If you have a standard setup, when you click-click the file it will play/run via AutoIt. If you right-click the file you have options to edit the file, or compile, or what not.
I have no idea of how long you've been away from coding with AutoIt or your setup.

If you feel like it, I can look for an icon and compile it for you. Save you from the hassle. I'll add an ini file for the settings too

[ioa747]

 

1 hour ago, Emerogork said:

ioa747, I hit Compile/Build/GO and nothing happening. Is there a way to activate it?

 

sorry my mistake , I thought it was self-explanatory.
you have to put the  ring1 png,  ring2.png  files in the same folder as the script, before run them , or compile it

Edited August 22, 2023 by ioa747
Correction

[argumentum]

1 minute ago, ioa747 said:

before run them - compile it

...I've run your code without compile and works just fine.

[ioa747]

 

12 minutes ago, argumentum said:

..I've run your code without compile and works just fine.

I also tried it with compilation,  (nothing unexpected)

but it  need the .png  files 

with the correct name  ring1.png  ,  ring2.png

Edited August 22, 2023 by ioa747