Any keydown/up detection or a better solution

[Champak]

I want to activate a function based on any key up detection in an input, the function would enable/disable a button based on if the input is empty or not. The only way I can think of to do this INSTANTLY is put an if condition in the main while loop and I don't want to do that. Any other way would require some secondary interaction to enable/disable the button. Is there a better way to accomplish this?

[Danp2]

You should be able to do this by subclassing the control. Lots of prior discussions on the topic if you do a search.

[KaFu]

Register WM_COMMAND and look for the respective EN_UPDATE call.

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiEdit.au3>
#include <WinAPIConv.au3>

Global $hGUI = GUICreate("Example")
Global $c_Input = GUICtrlCreateInput("", 10, 10, 200, 20)
Global $h_Input = GUICtrlGetHandle($c_Input)
Global $c_Button = GUICtrlCreateButton("Test", 10, 50, 200, 20)
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")
GUISetState(@SW_SHOW, $hGUI)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop
    EndSwitch
WEnd

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    Local $nNotifyCode = _WinAPI_HiWord($wParam)
    Local $iId = _WinAPI_LoWord($wParam)
    Local $hCtrl = $lParam
    
    If $hCtrl = $h_Input Then
        If $nNotifyCode = $EN_UPDATE Then ; Sent when an edit control is about to redraw itself. This notification code is sent after the control has formatted the text, but before it displays the text.
            ; https://learn.microsoft.com/en-us/windows/win32/controls/en-update
            ConsoleWrite(GUICtrlRead($c_Input) & @CRLF)
            If GUICtrlRead($c_Input) Then
                GUICtrlSetState($c_Button, $GUI_DISABLE)
            Else
                GUICtrlSetState($c_Button, $GUI_ENABLE)
            EndIf
        EndIf
    EndIf

    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

 

[Champak]

Excellent, thanks. I was actually able to utilize this for another issue as well.