Eval() with Array Variables

[kjpolker]

Is there a reason I cannot get my script to Evaluate a function with arrays? I have tried assigning the full function in a variable and evaluating that variable...

#include <AutoItConstants.au3>
#include <GUIConstants.au3>

HotKeySet("^{NUMPAD1}", "test")
HotKeySet("^{NUMPAD2}", "test")

gui()
Func gui()
    Global $hGUI = GUICreate("Test", 100, 100)
    GUISetState()
    While GUIGetMsg() <> $GUI_EVENT_CLOSE
    WEnd
    GUIDelete()
EndFunc

Func test()
    Local $test1[2] = ["Text 1", "Text 2"]
    Local $test2[2] = ["Text 3", "Text 4"]
    ConsoleWrite(Eval("$test" & StringRegExpReplace(@HotKeyPressed, "\D+", "")[0]) & @CRLF & Eval("$test" & StringRegExpReplace(@HotKeyPressed, "\D+", "")[1]) & @CRLF)
EndFunc

Note that the hotkeys are with CTRL. Regular expression is to extract the numeric value out of the @HotKeyPressed. I have tested the entire string and it is being built accurately, it just won't display the values. It simply closes, and with previous tweaking it was evaluating to an empty string.

Edited July 2, 2023 by kjpolker

[mikell]

In Eval don't put the '$' before the variable name

#include <AutoItConstants.au3>
#include <GUIConstants.au3>

HotKeySet("^{NUMPAD1}", "test")
HotKeySet("^{NUMPAD2}", "test")

gui()
Func gui()
    Global $hGUI = GUICreate("Test", 100, 100)
    GUISetState()
    While GUIGetMsg() <> $GUI_EVENT_CLOSE
    WEnd
    GUIDelete()
EndFunc

Func test()
    Local $test1[2] = ["Text 1", "Text 2"]
    Local $test2[2] = ["Text 3", "Text 4"]
    $n = StringRegExpReplace(@HotKeyPressed, "\D+", "")
    $a = Eval("test" & $n)[0]
    $b = Eval("test" & $n)[1]
    Msgbox(0,"", $a & @CRLF & $b)
EndFunc

Edit
and if you absolutely want to use a one-liner then take care of the parenthesis

ConsoleWrite((Eval("test" & StringRegExpReplace(@HotKeyPressed, "\D+", ""))[0]) & @CRLF & (Eval("test" & StringRegExpReplace(@HotKeyPressed, "\D+", ""))[1]) & @CRLF)

 

Edited July 2, 2023 by mikell

[water]

N.B. And because Eval evaluates a variable by Name you have to access the variable/array content by index after the evaluation.

[mikell]

4 minutes ago, water said:

you have to access the variable/array content by index after the evaluation

That's it. Parenthesis are very helpful keys

[kjpolker]

Wow I really appreciate it. I was loosing hair from scratching my head so much  not sure how I missed the '$' not being required, probably because most links and help file don't use a literal string  but rather a variable which does require the prefix. Also great to know about the array index being after Eval! I wasn't sure on that one and I kept flipping it around every time I tweaked it, not a ton of clarification available (at least provided by my search words).