function keyboard idle

[LucianoCruz]

Hello, does anyone have a script that checks if the keyboard is idle for 5 minutes, if it is then it sends ESC. I want to use it to implement a code that I have in my arcade. Grateful

[Andreik]

Welcome to the forum! Maybe you didn't noticed but you posted in the wrong section of the forum and this is a forum where people get help after they tried something and didn't work. Since it's a simple script I will give you an example but please keep these things in mind when you ask for more help.

#include <WinAPIConstants.au3>
#include <WinAPISys.au3>
#include <WindowsConstants.au3>

Global $hProc, $hHook, $nTimer, $bExit = False

$hProc = DllCallbackRegister('KeyboardProc', 'long', 'int;wparam;lparam')
$hHook = _WinAPI_SetWindowsHookEx($WH_KEYBOARD_LL, DllCallbackGetPtr($hProc), _WinAPI_GetModuleHandle(0))

$nTimer = TimerInit()

Do
    If Int(TimerDiff($nTimer) / 1000) >= 300 Then Send('{ESC}')     ; 5 Minutes
    Sleep(10)
Until $bExit

_WinAPI_UnhookWindowsHookEx($hHook)
DllCallbackFree($hProc)

Func KeyboardProc($nCode, $wParam, $lParam)
    If $nCode < 0 Then Return _WinAPI_CallNextHookEx($hHook, $nCode, $wParam, $lParam)
    If $wParam = $WM_KEYDOWN Then
        Local $tKBDLLHOOKSTRUCT = DllStructCreate($tagKBDLLHOOKSTRUCT, $lParam)
        ; Press HOME key to exit
        If DllStructGetData($tKBDLLHOOKSTRUCT, "vkCode") = 0x24 Then $bExit = True
        ConsoleWrite('Keyboard was idle for ' & Int(TimerDiff($nTimer) / 1000) & ' seconds.' & @CRLF)
        $nTimer = TimerInit()
    EndIf
    Return _WinAPI_CallNextHookEx($hHook, $nCode, $wParam, $lParam)
EndFunc

 

Edited June 29, 2023 by Andreik

[Melba23]

LucianoCruz,

Take a look at the _WinAPI_GetIdleTime and _Timer_GetIdleTime functions - they might be a bit easier to use than subclassing!

M23

[Andreik]

As I understand he is interested to get just the keyboard idle time. If he's looking also for mouse idle time _WinAPI_GetIdleTime() it's definitely better.

[LucianoCruz]

 

Hello, guys, I looked for it but I didn't find it, I need a script that detects keyboard inactivity, if the keyboard stays for 1 minute without any user action, then it sends ESC and is paused, if there is any user activity then it goes back to monitoring again the activity

[Andreik]

Why would you post the same question twice? You got some answers there. If it doesn't fit your needs you can ask more questions in the same thread.

[Jos]

Topics merged: Please stick to one for here on.  

[LucianoCruz]

Thanks! I got confused, and ended up posting 2 times, I'm going to test the Script, and sorry for my carelessness, it won't be repeated