MbTcp - Modbus TCP UDF

[kurtykurtyboy]

Here is something that I have been wanting in AutoIt for years but sadly no one had created it yet. Well, I decided to hunker down and do something about it!

I present to you, MbTCP - a Modbus TCP/IP UDF.

What is Modbus? Modbus is a communications protocol commonly used to communicate with various types of PLC's, sensors, SCADA systems, and many other industrial applications. Modbus TCP is the ethernet variant (as opposed to Modbus RTU which uses a serial connection).

 

This UDF takes care of all the behind-the-scenes legwork and makes it easy to get right to the data. No need to worry about which function codes to use or how to format the data.
Modbus typically works on discrete coils and inputs (think BOOL) or 16-bit registers (think INT). However, some devices support 32-bit signed and unsigned integers and 32-bit floating point numbers. This is possible by reading or writing 2 consecutive 16-bit registers and formatting them on both ends. The UDF will take care of all that as well (although maybe not in the most sophisticated ways...😏 ). Because there is no standard for working with 32-bit numbers, it is necessary to have the option to enable or disable big-endianness. Similarly, not all devices start counting at register 1. Some of them actually start at register 0. The UDF allows you to define these parameters when creating the connection to the device.
Available data types for input and holding registers are INT16, UINT16, INT32, UINT32, and FLOAT32.

Function List:

;  _MbTcp_Connect ......................: Open a connection to a remote device
;  _MbTcp_ReadCoils ....................: Read 1 or more output coils (function code 1)
;  _MbTcp_ReadDiscreteInputs ...........: Read 1 or more discrete inputs (function code 2)
;  _MbTcp_ReadHoldingRegisters .........: Read 1 or more holding registers (function code 3)
;  _MbTcp_ReadInputRegisters ...........: Read 1 or more input registers (function code 4)
;  _MbTcp_WriteCoils ...................: Write 1 or more output coils (function code 5 and 15)
;  _MbTcp_WriteRegisters ...............: Write 1 or more holding registers (function code 6 and 16)
;  _MbTcp_Disconnect ...................: Close the connection to a device
;  _MbTcp_DisconnectAll ................: Close the connection to all connected devices

To get started, follow these easy steps:

1. Create a new connection to the device using _MbTcp_Connect
2. Call any of the available read or write functions

That's it. The program will automatically clean up any connections that are left open on exit. You may also manually disconnect from any device if needed.

The most basic example of use. Connect to a device and read one holding register starting at register 2.

#include "MbTcp.au3"

;connect to device at IP 127.0.0.1
Local $iConnection1 = _MbTcp_Connect("127.0.0.1")
If @error Then
    MsgBox(16, "Error", "Failed to connect to the Modbus device at 127.0.0.1." & @CRLF & "Error Code: " & @error)
    Exit
Else
    ConsoleWrite("Successfully connected to device at 127.0.0.1" & @CRLF)
EndIf

;read 1 holding register
Local $iReadData = _MbTcp_ReadHoldingRegisters($iConnection1, 2, 1)
If @error Then
    MsgBox(16, "Error", "Failed to read the Modbus value." & @CRLF & "Error Code: " & @error)
Else
    ConsoleWrite("Value: " & $iReadData & @CRLF)
EndIf

 

 The next example shows how we can format the data to return an unsigned integer instead of the default signed integer.

Spoiler

#include "MbTcp.au3"

;connect to device at IP 127.0.0.1
Local $iConnection1 = _MbTcp_Connect("127.0.0.1")
If @error Then
    MsgBox(16, "Error", "Failed to connect to the Modbus device at 127.0.0.1." & @CRLF & "Error Code: " & @error)
    Exit
Else
    ConsoleWrite("Successfully connected to device at 127.0.0.1" & @CRLF)
EndIf

;read 1 holding register
Local $iReadData = _MbTcp_ReadHoldingRegisters($iConnection1, 2, 1, "UINT16")
If @error Then
    MsgBox(16, "Error", "Failed to read the Modbus value." & @CRLF & "Error Code: " & @error)
Else
    ConsoleWrite("Value: " & $iReadData & @CRLF)
EndIf

 

In the following example, we connect to a device that uses big-endian word order and starts at register 0 instead of 1. Then we read and write a group of registers.

Spoiler

First we create the connection.
Then we read 5 holding registers.
Then we write to the first 2 holding registers.
Then we read the 5 registers again and marvel at the changed values.

expandcollapse popup

#include "MbTcp.au3"

;connect to device at IP 127.0.0.1
Local $iFirstRef = 0      ; First address is 0 instead of 1
Local $iBigEndian = True  ; Slave operates on big-endian 32-bit numbers
Local $iConnection1 = _MbTcp_Connect("127.0.0.1", $iFirstRef, $iBigEndian)
If @error Then
    MsgBox(16, "Error", "Failed to connect to the Modbus device at 127.0.0.1." & @CRLF & "Error Code: " & @error)
    Exit
Else
    ConsoleWrite("Successfully connected to device at 127.0.0.1" & @CRLF)
EndIf

;read 5 holding registers
Local $register = 0
Local $count = 5
Local $aReadData = _MbTcp_ReadHoldingRegisters($iConnection1, $register, $count)
If @error Then
    MsgBox(16, "Error", "Failed to read the Modbus value." & @CRLF & "Error Code: " & @error)
Else
    ConsoleWrite("Read Data Before:" & @CRLF)
    For $value In $aReadData
        ConsoleWrite("Value: " & $value & @CRLF)
    Next
EndIf
ConsoleWrite(@CRLF)

;write 2 holding registers
ConsoleWrite("Writing Data..." & @CRLF)
$register = 0
$count = 2
Local $aWriteData[10] = [1, 2, 3, 4, 5, 6, 7, 8, 9, 10]
Local $iReturn = _MbTcp_WriteHoldingRegisters($iConnection1, $register, $count, $aWriteData)
If @error Then
    MsgBox(16, "Error", "Failed to write the Modbus value." & @CRLF & "Error Code: " & @error)
EndIf
ConsoleWrite(@CRLF)

;read 5 holding registers again
Local $register = 0
Local $count = 5
Local $aReadData = _MbTcp_ReadHoldingRegisters($iConnection1, $register, $count)
If @error Then
    MsgBox(16, "Error", "Failed to read the Modbus value." & @CRLF & "Error Code: " & @error)
Else
    ConsoleWrite("Read Data After:" & @CRLF)
    For $value In $aReadData
        ConsoleWrite("Value: " & $value & @CRLF)
    Next
EndIf
ConsoleWrite(@CRLF)


;disconnect from the device (optional) - this will be cleaned up automatically if not performed here
_MbTcp_Disconnect($iConnection1)

I may add more examples here if needed.

There are a number of Modbus simulators out there if you want to test locally on your computer. But I really like a tool named Mod_RSsim link.

Let me know if you find any issues. I know I will probably end up needing to add a timeout option.

MbTcp_20230620.zip

[funkey]

I have at least one Modbus TCP UDF for over 10 years... 😝😅

[kurtykurtyboy]

@funkey don't tell me you've been holding out on us for over 10 years!

Think of all the people who could benefit from it... At least 5 people - maybe 6! 😁

 

[funkey]

Sorry....

I have once made two different version of native implementation  of Modbus TCP and I also used two different libraries for this task. This is long time ago.

 

Here are two links that originated from my work:

modbus - Projekte - AutoIt.de - Das deutschsprachige Forum.

ModBus & libmodbus.dll - Funktion "0x10" (modbus_write_registers) integrieren - Hilfe & Unterstützung - AutoIt.de - Das deutschsprachige Forum.

 

BR

funkey

 

[mLipok]

Interestning:
Some articles about:

https://www.shemeck.pl/artykuly/71_protokol-modbus-tcp-ip-co-to-jest.html

https://ntronic.pl/modbus-tcp/

[kurtykurtyboy]

Nice! I wish I would have seen that sooner. I guess Google doesn't show me the non-english results. Maybe I should start expanding my horizons.. 🤔