LibreOffice/Writer get page orientation and page size

[Heiko]

Hi,

I need to read the page orientation (portrait or landscape) and the page size (e.g. DIN A4) of a .docx file with Writer from LibreOffice.

I can open the file with Writer, but I don't get the needed information. Can anyone help me?

[mLipok]

start here:

and here

and here:

 

specifically here:

 

[water]

Welcome to AutoIt and the forum!

What have you tried so far?
Maybe this site helps? https://wiki.documentfoundation.org/Documentation/BASIC_Guide#Formatting

[Heiko]

Hello and thanks for your help so far.

I only have this code to open a docx so far. Now I just need the info which format the page has and which orientation. And I have absolutely no idea how to implement this.

Global $ServiceManager
Local $Desktop
$ServiceManager = ObjCreate("com.sun.star.ServiceManager")

$MSword = $ServiceManager.createInstance("com.sun.star.frame.Desktop")

$source = "C:\test.docx"
$source2 = Convert2URL($source)

Global $args[3]
$args[0] = MakePropertyValue("ReadOnly", False)
$args[1] = MakePropertyValue("Password", "")
$args[2] = MakePropertyValue("Hidden", False)

$doc1 = $MSword.loadComponentFromURL($source2, "_blank", 0, $args)


Func MakePropertyValue($cName, $uValue)
   Local $Pstruc
   $Pstruc = $ServiceManager.Bridge_GetStruct("com.sun.star.beans.PropertyValue")
   $Pstruc.Name = $cName
   $Pstruc.Value = $uValue
   Return $Pstruc
EndFunc


Func Convert2URL($fname)
   $fname = StringReplace($fname, ":", "|")
   $fname = StringReplace($fname, " ", "%20")
   $fname = "file:///" & StringReplace($fname, "\", "/")
   Return $fname
EndFunc

 

Edited June 3, 2023 by Heiko

[water]

I haven't worked a second with LibreOffice but I think it should be possible.

I suggest to have a look at the document I pointed you to and search for "Page Format".
There you'll find function "IsLandscape" and the example code below sets the page size. You may need to translate the returned values from mm to DIN format.

[Heiko]

But the example code is VBA and not AutoIt and I can't translate it to AutoIt. And I don't want to change the page size. I just want to read the existing page format.

[mLipok]

@Heiko

please read:

* How to post code on the forum *

[water]

Don't know if this works. Add this to your code and gibve it a try.

$StyleFamilies = $Doc1.StyleFamilies
$PageStyles = $StyleFamilies.getByName("PageStyles")
$DefPage = $PageStyles.getByName("Default")

ConsoleWrite($DefPage.IsLandscape & @CRLF)
ConsoleWrite($DefPage.Width & @CRLF)
ConsoleWrite($DefPage.Height & @CRLF)

[Heiko]

@water Thank you, but sorry, that doesn't work. I have asked ChatGPT in the meantime and got this code:

; Get the page size
Local $oPageProperties = $oDocument.getPageProperties()
Local $nPageWidth = $oPageProperties.Width
Local $nPageHeight = $oPageProperties.Height

; Get the page orientation
Local $bLandscape = $oPageProperties.IsLandscape

; Display the page size and orientation
MsgBox($MB_OK, "Document Information", "Page Size: " & $nPageWidth & " x " & $nPageHeight & @CRLF & "Page Orientation: " & ($bLandscape ? "Landscape" : "Portrait"))

Unfortunately it does not work either.

[mLipok]

27 minutes ago, Heiko said:

I have asked ChatGPT in the meantime... Unfortunately it does not work either.

it didn't surprise me at all.
You're asking quarter intelligence about things that require full intelligence.

Would you be so nice and share the question you ask ChatGPT ?

btw. take a look on my post here:

 

Edited June 6, 2023 by mLipok

[water]

@Heiko What does "it does not work" mean. Do you get an error message, no result,a wrong result ...? Please elaborate.

As you are working with COM objects I suggest to add a COM error handler to your script. So we get a more detailed error description. Please check "ObjEvent" in the AutoIt help file.

BTW: If you are going to reply to mLipok's ChatGPT post, please do so in the ChatGPT thread in the Chat forum.
I am afraid that a thread that already contains the answer in the title ("AI is BS") does not offer any special insights.

[mLipok]

7 minutes ago, water said:

If you are going to reply to mLipok's ChatGPT post, please do so in the ChatGPT thread in the Chat forum.

I agree.
Sorry to forgot mention about this.

[Heiko]

@mLipok Yes, I asked ChatGPT, because I am now absolutely desperate, because I have been trying for over 1 week and can't find a solution.

I asked ChatGPT something like this: "Create an AutoIt script to open a docx file with Writer and read out page size and page orientation". 

I do not have permissions to see the content you posted.

[Heiko]

@water The console output with your code is:

[80020009] com.sun.star.container.NoSuchElementException: Default

[water]

Can you please post

• the full code you run. There is no reference to com.sun.star.container in the code I have seen so far
• the full output from the SciTE output pane? We need the line number so we can tell where the error happens
• the full output of the COM error handler. The example provided with ObjEvent writes more lines to the console. We need this information as 0x80020009 is ageneral exception. Windows tells us that there was an error but doesn't know exactly what happened

[Heiko]

@water Sure, here is the complete code with your code snipet:

expandcollapse popup

Global $extensions[3] = ["doc","docx","odt"]
Global $ServiceManager
Local $Desktop
$ServiceManager = ObjCreate("com.sun.star.ServiceManager")

$MSword = $ServiceManager.createInstance("com.sun.star.frame.Desktop")

$source = "C:\test.docx"
$source2 = Convert2URL($source)

Global $args[3]
$args[0] = MakePropertyValue("ReadOnly", False)
$args[1] = MakePropertyValue("Password", "")
$args[2] = MakePropertyValue("Hidden", False)

$doc1 = $MSword.loadComponentFromURL($source2, "_blank", 0, $args)

$StyleFamilies = $doc1.StyleFamilies
$PageStyles = $StyleFamilies.getByName("PageStyles")
$DefPage = $PageStyles.getByName("Default")

ConsoleWrite($DefPage.IsLandscape & @CRLF)
ConsoleWrite($DefPage.Width & @CRLF)
ConsoleWrite($DefPage.Height & @CRLF)



Func MakePropertyValue($cName, $uValue)
   Local $Pstruc
   $Pstruc = $ServiceManager.Bridge_GetStruct("com.sun.star.beans.PropertyValue")
   $Pstruc.Name = $cName
   $Pstruc.Value = $uValue
   Return $Pstruc
EndFunc

Func Convert2URL($fname)
   $fname = StringReplace($fname, ":", "|")
   $fname = StringReplace($fname, " ", "%20")
   $fname = "file:///" & StringReplace($fname, "\", "/")
   Return $fname
EndFunc

 

[Mehomic]

Does this do what ya want?

expandcollapse popup

#include <MsgBoxConstants.au3>

$fname = "full/path/to/your/filename/with.Extension"

$cURL = Convert2URL($fname)

$oServiceManager = ObjCreate("com.sun.star.ServiceManager") ;< create the service manager

$oDesktop = $oServiceManager.createInstance("com.sun.star.frame.Desktop") ;< create the desktop object

Global $args[3] ;< set the array of properties
$args[0] = MakePropertyValue("ReadOnly", False)
$args[1] = MakePropertyValue("Password", "")
$args[2] = MakePropertyValue("Hidden", False)

$oDoc = $oDesktop.loadComponentFromURL($cURL, "_blank", 0, $args) ;< open an existing document

$StyleFamilies = $oDoc.StyleFamilies ;< select the style families from the open document
$PageStyles = $StyleFamilies.getByName("PageStyles") ;< get the page styles
$DefPage = $PageStyles.getByName("Default") ;< return default page styles

MsgBox($MB_SYSTEMMODAL, "RESULTS", "Is Landscape: " & $DefPage.IsLandscape & @CRLF & _
                                   "Page Width: "   & $DefPage.Width       & @CRLF & _
                                   "Page Height: "  & $DefPage.Height      & @CRLF)

if @error or Not IsObj($oDoc) then
      SetError(1, 0, 0)
 EndIf

Func MakePropertyValue($cName, $uValue)
   Local $Pstruc
   $Pstruc = $oServiceManager.Bridge_GetStruct("com.sun.star.beans.PropertyValue")
   $Pstruc.Name = $cName
   $Pstruc.Value = $uValue
   Return $Pstruc
EndFunc

Func Convert2URL($fname)
   $fname = StringReplace($fname, ":", "|")
   $fname = StringReplace($fname, " ", "%20")
   $fname = "file:///" & StringReplace($fname, "\", "/")
   Return $fname
EndFunc

code Mehomic

Edited June 13, 2023 by Mehomic
changed typo's

[Heiko]

@Mehomic I see no difference to the idea from @water but I tested it. It doesn't work:

I get:

The requested action with this object has failed.:
$DefPage = $PageStyles.getByName("Default")
$DefPage = $PageStyles^ ERROR

[Heiko]

I found a VBA code and could change it, so it works now  

$ViewCursor = $doc1.CurrentController.getViewCursor()
$PageStyle = $ViewCursor.PageStyleName
$Style = $doc1.StyleFamilies.getByName("PageStyles").getByName($PageStyle)
$PageHeight = $Style.height/100
$PageWidth = $Style.width/100
$PageOrientation = $Style.isLandscape
ConsoleWrite($PageHeight & " x " & $PageWidth &@LF)
ConsoleWrite("Page is landscape: " & $PageOrientation &@LF)

The result is e.g.:

210.01 x 297
Page is landscape: True

[mLipok]

Complete working snippet please